[gentoo-commits] gentoo-x86 commit in dev-libs/icu: icu-4.8.1-r3.ebuild icu-4.8.1.1-r1.ebuild ChangeLog icu-4.8.1-r1.ebuild icu-4.8.ebuild icu-4.8.1.1.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    12/02/27 16:19:35

  Modified:             ChangeLog
  Added:                icu-4.8.1-r3.ebuild icu-4.8.1.1-r1.ebuild
  Removed:              icu-4.8.1-r1.ebuild icu-4.8.ebuild
                        icu-4.8.1.1.ebuild
  Log:
  Add patch to fix ltr ligatures issue. Wrt bug#405143.
  
  (Portage version: 2.2.0_alpha89/cvs/Linux x86_64)

Revision  Changes    Path
1.169                dev-libs/icu/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/icu/ChangeLog?rev=1.169&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/icu/ChangeLog?rev=1.169&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/icu/ChangeLog?r1=1.168&r2=1.169

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/icu/ChangeLog,v
retrieving revision 1.168
retrieving revision 1.169
diff -u -r1.168 -r1.169
--- ChangeLog	28 Dec 2011 19:14:10 -0000	1.168
+++ ChangeLog	27 Feb 2012 16:19:35 -0000	1.169
@@ -1,6 +1,14 @@
 # ChangeLog for dev-libs/icu
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/ChangeLog,v 1.168 2011/12/28 19:14:10 halcy0n Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/ChangeLog,v 1.169 2012/02/27 16:19:35 scarabeus Exp $
+
+*icu-4.8.1.1-r1 (27 Feb 2012)
+*icu-4.8.1-r3 (27 Feb 2012)
+
+  27 Feb 2012; Tomáš Chvátal <scarabeus@g.o>
+  +files/icu-4.8.1-fix_ltr.patch, +icu-4.8.1-r3.ebuild, +icu-4.8.1.1-r1.ebuild,
+  -icu-4.8.1-r1.ebuild, -icu-4.8.1.1.ebuild, -icu-4.8.ebuild:
+  Add patch to fix ltr ligatures issue. Wrt bug#405143.
 
   28 Dec 2011; Mark Loeser <halcy0n@g.o> icu-4.8.1-r2.ebuild:
   Stable for ppc/ppc64; bug #387259



1.1                  dev-libs/icu/icu-4.8.1-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/icu/icu-4.8.1-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/icu/icu-4.8.1-r3.ebuild?rev=1.1&content-type=text/plain

Index: icu-4.8.1-r3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/icu-4.8.1-r3.ebuild,v 1.1 2012/02/27 16:19:35 scarabeus Exp $

EAPI="3"

inherit versionator

MAJOR_VERSION="$(get_version_component_range 1)"
MINOR_VERSION="$(get_version_component_range 2)"
if [[ "${PV}" =~ ^[[:digit:]]+\.[[:digit:]]+(_rc[[:digit:]]*)?$ ]]; then
	MICRO_VERSION="0"
else
	MICRO_VERSION="$(get_version_component_range 3)"
fi

DESCRIPTION="International Components for Unicode"
HOMEPAGE="http://www.icu-project.org/"

BASE_URI="http://download.icu-project.org/files/icu4c/${PV/_/}"
SRC_ARCHIVE="icu4c-${PV//./_}-src.tgz"
DOCS_ARCHIVE="icu4c-${PV//./_}-docs.zip"

SRC_URI="${BASE_URI}/${SRC_ARCHIVE}
	doc? ( ${BASE_URI}/${DOCS_ARCHIVE} )"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc examples static-libs"

DEPEND="doc? ( app-arch/unzip )"
RDEPEND=""

S="${WORKDIR}/${PN}/source"

QA_DT_NEEDED="/usr/lib.*/libicudata\.so\.${MAJOR_VERSION}${MINOR_VERSION}\.${MICRO_VERSION}"

src_unpack() {
	unpack "${SRC_ARCHIVE}"
	if use doc; then
		mkdir docs
		pushd docs > /dev/null
		unpack "${DOCS_ARCHIVE}"
		popd > /dev/null
	fi
}

src_prepare() {
	# Do not hardcode flags into icu-config.
	# https://ssl.icu-project.org/trac/ticket/6102
	local variable
	for variable in CFLAGS CPPFLAGS CXXFLAGS FFLAGS LDFLAGS; do
		sed -i -e "/^${variable} =.*/s:@${variable}@::" config/Makefile.inc.in || die "sed failed"
	done

	epatch \
		"${FILESDIR}/icu-4.8.1-fix_binformat_fonts.patch" \
		"${FILESDIR}/icu-4.8.1-fix_nan.patch" \
		"${FILESDIR}/icu-4.8.1-fix_ltr.patch"
}

src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable examples samples) \
		$(use_enable static-libs static)
}

src_test() {
	# INTLTEST_OPTS: intltest options
	#   -e: Exhaustive testing
	#   -l: Reporting of memory leaks
	#   -v: Increased verbosity
	# IOTEST_OPTS: iotest options
	#   -e: Exhaustive testing
	#   -v: Increased verbosity
	# CINTLTST_OPTS: cintltst options
	#   -e: Exhaustive testing
	#   -v: Increased verbosity
	emake -j1 check || die "emake check failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dohtml ../readme.html
	dodoc ../unicode-license.txt
	if use doc; then
		insinto /usr/share/doc/${PF}/html/api
		doins -r "${WORKDIR}/docs/"* || die "doins failed"
	fi
}



1.1                  dev-libs/icu/icu-4.8.1.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/icu/icu-4.8.1.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/icu/icu-4.8.1.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: icu-4.8.1.1-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/icu-4.8.1.1-r1.ebuild,v 1.1 2012/02/27 16:19:35 scarabeus Exp $

EAPI="4"

inherit versionator

MAJOR_VERSION="$(get_version_component_range 1)"
MINOR_VERSION="$(get_version_component_range 2)"
if [[ "${PV}" =~ ^[[:digit:]]+\.[[:digit:]]+(_rc[[:digit:]]*)?$ ]]; then
	MICRO_VERSION="0"
else
	MICRO_VERSION="$(get_version_component_range 3)"
fi

DESCRIPTION="International Components for Unicode"
HOMEPAGE="http://www.icu-project.org/"

BASE_URI="http://download.icu-project.org/files/icu4c/${PV/_/}"
SRC_ARCHIVE="icu4c-${PV//./_}-src.tgz"
DOCS_ARCHIVE="icu4c-${PV//./_}-docs.zip"

SRC_URI="${BASE_URI}/${SRC_ARCHIVE}
	doc? ( ${BASE_URI}/${DOCS_ARCHIVE} )"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc examples static-libs"

DEPEND="doc? ( app-arch/unzip )"
RDEPEND=""

S="${WORKDIR}/${PN}/source"

QA_DT_NEEDED="/usr/lib.*/libicudata\.so\.${MAJOR_VERSION}${MINOR_VERSION}\.${MICRO_VERSION}.*"

src_unpack() {
	unpack "${SRC_ARCHIVE}"
	if use doc; then
		mkdir docs
		pushd docs > /dev/null
		unpack "${DOCS_ARCHIVE}"
		popd > /dev/null
	fi
}

src_prepare() {
	# Do not hardcode flags into icu-config.
	# https://ssl.icu-project.org/trac/ticket/6102
	local variable
	for variable in CFLAGS CPPFLAGS CXXFLAGS FFLAGS LDFLAGS; do
		sed -i -e "/^${variable} =.*/s:@${variable}@::" config/Makefile.inc.in || die "sed failed"
	done

	epatch \
		"${FILESDIR}/icu-4.8.1-fix_binformat_fonts.patch" \
		"${FILESDIR}/icu-4.8.1-fix_nan.patch" \
		"${FILESDIR}/icu-4.8.1-fix_ltr.patch"
}

src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable examples samples) \
		$(use_enable static-libs static)
}

src_test() {
	# INTLTEST_OPTS: intltest options
	#   -e: Exhaustive testing
	#   -l: Reporting of memory leaks
	#   -v: Increased verbosity
	# IOTEST_OPTS: iotest options
	#   -e: Exhaustive testing
	#   -v: Increased verbosity
	# CINTLTST_OPTS: cintltst options
	#   -e: Exhaustive testing
	#   -v: Increased verbosity
	emake -j1 check
}

src_install() {
	emake DESTDIR="${D}" install

	dohtml ../readme.html
	dodoc ../unicode-license.txt
	if use doc; then
		insinto /usr/share/doc/${PF}/html/api
		doins -r "${WORKDIR}/docs/"*
	fi
}