[gentoo-commits] gentoo-x86 commit in net-irc/quassel: ChangeLog quassel-0.3.0.1.ebuild

[Markus Ullmann (jokey)]

jokey       08/09/03 20:43:21

  Modified:             ChangeLog
  Added:                quassel-0.3.0.1.ebuild
  Log:
  Version bump, thanks for notification on IRC and billie for providing the ebuild
  (Portage version: 2.2_rc8/cvs/Linux 2.6.26-gentoo i686)

Revision  Changes    Path
1.29                 net-irc/quassel/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/quassel/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	1 Sep 2008 18:51:57 -0000	1.28
+++ ChangeLog	3 Sep 2008 20:43:21 -0000	1.29
@@ -1,6 +1,12 @@
 # ChangeLog for net-irc/quassel
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/quassel/ChangeLog,v 1.28 2008/09/01 18:51:57 jokey Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/quassel/ChangeLog,v 1.29 2008/09/03 20:43:21 jokey Exp $
+
+*quassel-0.3.0.1 (03 Sep 2008)
+
+  03 Sep 2008; Markus Ullmann <jokey@g.o> +quassel-0.3.0.1.ebuild:
+  Version bump, thanks for notification on IRC and billie for providing the
+  ebuild
 
   01 Sep 2008; Markus Ullmann <jokey@g.o> quassel-9999.ebuild:
   Add new useflags and some style improvements to live ebuild, thanks to



1.1                  net-irc/quassel/quassel-0.3.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/quassel-0.3.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/quassel/quassel-0.3.0.1.ebuild?rev=1.1&content-type=text/plain

Index: quassel-0.3.0.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/quassel/quassel-0.3.0.1.ebuild,v 1.1 2008/09/03 20:43:21 jokey Exp $

EAPI=1

inherit cmake-utils eutils

MY_P="${P/_/-}"

DESCRIPTION="Core/client IRC client."
HOMEPAGE="http://quassel-irc.org/"
SRC_URI="http://quassel-irc.org/pub/${MY_P}.tar.bz2"

LICENSE="GPL-3"
KEYWORDS="~amd64 ~sparc ~x86"
SLOT="0"
IUSE="+dbus debug +server +ssl +X"

RDEPEND="x11-libs/qt-core:4
		server? (
			x11-libs/qt-sql:4
			x11-libs/qt-script:4
		)
		X? ( x11-libs/qt-gui:4 )
		dbus? ( x11-libs/qt-dbus )
		ssl? ( dev-libs/openssl )"
DEPEND="${RDEPEND}
	>=dev-util/cmake-2.4.7"

DOCS="ChangeLog README README.Qtopia"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	if ! use server && ! use X; then
		eerror "You have to build one or both of quassel client or server."
		die "Both server and X USE flags unset."
	fi

	if use server && ! built_with_use x11-libs/qt-sql sqlite ; then
		eerror "Please rebuild x11-libs/qt-sql:4 with sqlite USE flag enabled."
		die "Missing sqlite support in x11-libs/qt-sql:4"
	fi

	if use ssl && ! built_with_use x11-libs/qt-core ssl ; then
		eerror "Please rebuild x11-libs/qt-core:4 with ssl USE flag enabled."
		die "Missing ssl support in x11-libs/qt-core:4"
	fi
}

src_compile() {
	local mycmakeargs="
		$(cmake-utils_use_want server CORE)
		$(cmake-utils_use_want X QTCLIENT)
		$(cmake-utils_use_with dbus DBUS)
		$(cmake-utils_use_with ssl OPENSSL)
		-DWANT_MONO=OFF"

	cmake-utils_src_compile
}

src_install() {
	cmake-utils_src_install

	# Only install the icons if the X client was installed
	if use X; then
		insinto /usr/share/icons/hicolor
		# avoid the connected/ directory, get only the ${size}x${size}
		doins -r "${S}"/src/icons/quassel/*x* || die "installing icons failed"
	fi

	if use server; then
		newinitd "${FILESDIR}"/quasselcore.init quasselcore || die "newinitd failed"
		newconfd "${FILESDIR}"/quasselcore.conf quasselcore || die "newconfd failed"
	fi
}

pkg_postinst() {
	if use server; then
		ewarn "In order to use the quassel init script you must set the"
		ewarn "QUASSEL_USER variable in /etc/conf.d/quasselcore to your username."
	fi
}