[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-contacts/

[Mart Raudsepp]

commit:     23b250e7fca0844fed467fa0a77e27fcc51835f5
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Sep  7 20:23:25 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Sep  7 22:08:54 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23b250e7

gnome-extra/gnome-contacts: bump to 3.32.1

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/gnome-contacts/Manifest                |  1 +
 .../gnome-contacts/gnome-contacts-3.32.1.ebuild    | 72 ++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index e50b19e4bad..5198f380b3f 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1 +1,2 @@
 DIST gnome-contacts-3.30.2.tar.xz 368476 BLAKE2B 502170e327eb63a6d026af94a09949f6b973dba0c59079a23c7f37dfde2a391ffa13d905452741c403ada8e6f1101f7a5620ad9b59eb4c5341e96d357d8fe99b SHA512 cf6ab33ef6147bceb5a4681b83830828fd4caa47d83fa9f71e01db3caf710f7f09fe60d2956565a2b9bd124356e100b31d6372ac4d4d231718230915a135e79d
+DIST gnome-contacts-3.32.1.tar.xz 358800 BLAKE2B a3cdc58948b994868a18e74dd2ab1a1ffea04b84da95347f19b79b49a7eb9363589e08e11e8fa2f588c5833592be3149ea435b6036a376d4c9e1477d0d308e96 SHA512 25fc4835c61bd5f195512fd304955058e1178cbafaff09a6bbfffc58840876f514ebc3119247925266a9c10f8fc452511a055d84aa1e815571188aba7212fe71

diff --git a/gnome-extra/gnome-contacts/gnome-contacts-3.32.1.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-3.32.1.ebuild
new file mode 100644
index 00000000000..297ca628309
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-3.32.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="telepathy v4l"
+KEYWORDS="~amd64 ~arm64"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-1.54
+	dev-libs/folks[vala(+)]
+	net-libs/gnome-online-accounts[vala]
+	gnome-extra/evolution-data-server[vala]
+	telepathy? ( net-libs/telepathy-glib[vala] )
+	gui-libs/libhandy:0.0[vala]
+"
+# Configure is wrong; it needs cheese-3.5.91, not 3.3.91
+RDEPEND="
+	>=gnome-extra/evolution-data-server-3.13.90:=[gnome-online-accounts]
+	>=dev-libs/folks-0.11.4:=[eds,telepathy?]
+	>=dev-libs/glib-2.44:2
+	>=dev-libs/libgee-0.10:0.8
+	>=gnome-base/gnome-desktop-3.0:3=
+	net-libs/gnome-online-accounts:=
+	>=x11-libs/gtk+-3.23.1:3
+	v4l? ( >=media-video/cheese-3.5.91:= )
+	telepathy? ( >=net-libs/telepathy-glib-0.22 )
+	>=gui-libs/libhandy-0.0.9:0.0=
+"
+DEPEND="${RDEPEND}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use v4l cheese)
+		$(meson_use telepathy)
+		-Dmanpage=true
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}