[gentoo-commits] repo/gentoo:master commit in: sci-libs/Shapely/

[Aaron Bauman]

commit:     1ed8a5f919e3df02f8600e860cc82a575776edd4
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Dec  1 20:34:54 2019 +0000
Commit:     Aaron Bauman <bman <AT> gentoo <DOT> org>
CommitDate: Tue Dec  3 04:17:51 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1ed8a5f9

sci-libs/Shapely: python3_8, EAPI-7 bump

Tests passed.
Dropping python2_7 for dev-python/numpy dependency.

Closes: https://bugs.gentoo.org/701746
Package-Manager: Portage-2.3.80, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
Signed-off-by: Aaron Bauman <bman <AT> gentoo.org>

 sci-libs/Shapely/Shapely-1.6.4_p2-r1.ebuild | 55 +++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/sci-libs/Shapely/Shapely-1.6.4_p2-r1.ebuild b/sci-libs/Shapely/Shapely-1.6.4_p2-r1.ebuild
new file mode 100644
index 00000000000..488e7c29a06
--- /dev/null
+++ b/sci-libs/Shapely/Shapely-1.6.4_p2-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Geometric objects, predicates, and operations"
+HOMEPAGE="https://pypi.org/project/Shapely/"
+
+MY_PV="$(ver_cut 1-3).post$(ver_cut 5)"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/Toblerity/${PN}.git"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${PN}-${MY_PV}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="test"
+
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]
+	>=sci-libs/geos-3.3"
+DEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=( "${FILESDIR}/${P}-test_operations.patch" ) # bug 701624
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+python_prepare_all() {
+	# fix install path for Cython definition file
+	sed -i \
+		-e "s|\(data_files.*\)'shapely'|\1'share/shapely'|" \
+		setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}/lib" || die
+	cp -r "${S}/tests" . || die
+	py.test tests || die
+}