[gentoo-commits] repo/gentoo:master commit in: app-emulation/86Box/

[Conrad Kostecki]

commit:     8d4ede21dbdb27b08d29072a56f7d8f22470f4a7
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 28 21:10:26 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Mon Nov 28 21:51:44 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8d4ede21

app-emulation/86Box: add 3.11

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-emulation/86Box/86Box-3.11.ebuild | 77 +++++++++++++++++++++++++++++++++++
 app-emulation/86Box/Manifest          |  1 +
 2 files changed, 78 insertions(+)

diff --git a/app-emulation/86Box/86Box-3.11.ebuild b/app-emulation/86Box/86Box-3.11.ebuild
new file mode 100644
index 000000000000..d4296a2489e3
--- /dev/null
+++ b/app-emulation/86Box/86Box-3.11.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Emulator of x86-based machines based on PCem"
+HOMEPAGE="https://github.com/86Box/86Box"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dinput +dynarec experimental +fluidsynth +munt new-dynarec +openal +qt5 +threads"
+
+DEPEND="
+	app-emulation/faudio
+	dev-libs/libevdev
+	media-libs/freetype:2=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/openal
+	media-libs/rtmidi
+	net-libs/libslirp
+	sys-libs/zlib
+	qt5? ( x11-libs/libXi )
+"
+
+RDEPEND="
+	${DEPEND}
+	fluidsynth? ( media-sound/fluidsynth )
+	munt? ( media-libs/munt-mt32emu )
+	openal? ( media-libs/openal )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qttranslations:5
+		dev-qt/qtwidgets:5
+		kde-frameworks/extra-cmake-modules
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	# LTO needs to be filtered
+	# See https://bugs.gentoo.org/854507
+	filter-lto
+	append-flags -fno-strict-aliasing
+
+	local mycmakeargs=(
+		-DCPPTHREADS="$(usex threads)"
+		-DDEV_BRANCH="$(usex experimental)"
+		-DDINPUT="$(usex dinput)"
+		-DDYNAREC="$(usex dynarec)"
+		-DSLIRP_EXTERNAL="ON"
+		-DMUNT_EXTERNAL="$(usex munt)"
+		-DFLUIDSYNTH="$(usex fluidsynth)"
+		-DMINITRACE="OFF"
+		-DMUNT="$(usex munt)"
+		-DNEW_DYNAREC="$(usex new-dynarec)"
+		-DOPENAL="$(usex openal)"
+		-DPREFER_STATIC="OFF"
+		-DQT="$(usex qt5)"
+		-DRELEASE="ON"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "In order to use 86Box, you will need some roms for various emulated systems."
+	elog "See https://github.com/86Box/roms for more information."
+}

diff --git a/app-emulation/86Box/Manifest b/app-emulation/86Box/Manifest
index 307e39504eee..462ba58d2cfe 100644
--- a/app-emulation/86Box/Manifest
+++ b/app-emulation/86Box/Manifest
@@ -1 +1,2 @@
+DIST 86Box-3.11.tar.gz 4593971 BLAKE2B 0b2771492910f0c11835104e5ef7495ca052414a959e27732ec0d72bc6a6f4cb46c386f0642042425cfd4c4aa1b16e24e027e53034ffae618d9c51aff282cdf7 SHA512 4705f0bb7186a19b8a74450132a73c01e9fae80809e7cebf2ef0294100081ff6a27e0f81dbc661596a8d1cd7b04afc5dddb3e990dd10951a37a48de338c49a77
 DIST 86Box-3.7.1.tar.gz 4454288 BLAKE2B cd2678b1b0beb6fc37145cd38139a27f7789af8fc98bcb6d98644d60642edf618be6aa5509085826539a6146042f14bec59aabd5f1b38725b41d630390d23b11 SHA512 38abe254ea24eb6430eb87eca517bf7b318188df0f0f6d6dec5a04fefac143d591cea303398b7179fe72dc80cd0393778f9c64012b6183a6c8a6e615d40340e7