[gentoo-commits] gentoo-x86 commit in games-emulation/advancemame: advancemame-0.106.1.ebuild ChangeLog

[Michael Sterrett (mr_bones_)]

mr_bones_    09/09/08 15:39:43

  Modified:             ChangeLog
  Added:                advancemame-0.106.1.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.47                 games-emulation/advancemame/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/advancemame/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/advancemame/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/advancemame/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-emulation/advancemame/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	5 Dec 2008 16:19:25 -0000	1.46
+++ ChangeLog	8 Sep 2009 15:39:42 -0000	1.47
@@ -1,6 +1,12 @@
 # ChangeLog for games-emulation/advancemame
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/advancemame/ChangeLog,v 1.46 2008/12/05 16:19:25 nyhm Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/advancemame/ChangeLog,v 1.47 2009/09/08 15:39:42 mr_bones_ Exp $
+
+*advancemame-0.106.1 (08 Sep 2009)
+
+  08 Sep 2009; Michael Sterrett <mr_bones_@g.o>
+  +advancemame-0.106.1.ebuild, +files/advancemame-0.106.1-pic.patch:
+  version bump
 
   05 Dec 2008; Tristan Heaven <nyhm@g.o> advancemame-0.106.0.ebuild:
   Remove expat and zlib USE flags, bug #249459



1.1                  games-emulation/advancemame/advancemame-0.106.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/advancemame/advancemame-0.106.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/advancemame/advancemame-0.106.1.ebuild?rev=1.1&content-type=text/plain

Index: advancemame-0.106.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/advancemame/advancemame-0.106.1.ebuild,v 1.1 2009/09/08 15:39:42 mr_bones_ Exp $

EAPI=2
inherit eutils flag-o-matic games

DESCRIPTION="GNU/Linux port of the MAME emulator with GUI menu"
HOMEPAGE="http://advancemame.sourceforge.net/"
SRC_URI="mirror://sourceforge/advancemame/${P}.tar.gz"

LICENSE="GPL-2 XMAME"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="alsa fbcon oss sdl static svga truetype"

# sdl is required (bug #158417)
RDEPEND="app-arch/unzip
	app-arch/zip
	media-libs/libsdl
	dev-libs/expat
	alsa? ( media-libs/alsa-lib )
	truetype? ( media-libs/freetype )
	svga? ( >=media-libs/svgalib-1.9 )"
DEPEND="${RDEPEND}
	x86? ( >=dev-lang/nasm-0.98 )
	virtual/os-headers"

src_prepare() {
	epatch "${FILESDIR}/${P}-pic.patch"
	sed -i \
		-e 's/"-s"//' \
		configure \
		|| die "sed failed"

	use x86 && \
		ln -s $(type -P nasm) "${T}/${CHOST}-nasm"
	ln -s $(type -P sdl-config) "${T}/${CHOST}-sdl-config"
	use truetype && \
		ln -s $(type -P freetype-config) "${T}/${CHOST}-freetype-config"
}

src_configure() {
	# Fix for bug #78030
	if use ppc; then
		append-ldflags "-Wl,--relax"
	fi

	PATH="${PATH}:${T}"
	egamesconf \
		--enable-expat \
		--enable-sdl \
		--enable-zlib \
		--disable-slang \
		$(use_enable alsa) \
		$(use_enable fbcon fb) \
		$(use_enable oss) \
		$(use_enable static) \
		$(use_enable svga svgalib) \
		$(use_enable truetype freetype) \
		$(use_enable x86 asm) \
		--with-emu=${PN/advance}
}

src_compile() {
	STRIPPROG=true emake || die "emake failed"
}

src_install() {
	local f

	for f in adv* ; do
		if [[ -L "${f}" ]] ; then
			dogamesbin "${f}" || die "dogamesbin failed"
		fi
	done

	insinto "${GAMES_DATADIR}/advance"
	doins support/event.dat
	keepdir "${GAMES_DATADIR}/advance/"{artwork,diff,image,rom,sample,snap}

	dodoc HISTORY README RELEASE
	cd doc
	dodoc *.txt
	dohtml *.html
	for f in *.1 ; do
		newman ${f} ${f/1/6}
	done

	prepgamesdirs
}