[gentoo-commits] repo/gentoo:master commit in: app-admin/yaala/

[Andreas Hüttel]

commit:     7d1a41e3457fd915821d4121461dac92f03577a8
Author:     Andreas K. Huettel (dilfridge) <dilfridge <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 22 22:35:50 2015 +0000
Commit:     Andreas Hüttel <dilfridge <AT> gentoo <DOT> org>
CommitDate: Sun Nov 22 22:35:50 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7d1a41e3

app-admin/yaala: Major QA cleanup, includes the fix for bug 565428

Package-Manager: portage-2.2.25

 app-admin/yaala/yaala-0.7.3-r2.ebuild | 73 +++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

diff --git a/app-admin/yaala/yaala-0.7.3-r2.ebuild b/app-admin/yaala/yaala-0.7.3-r2.ebuild
new file mode 100644
index 0000000..6028584
--- /dev/null
+++ b/app-admin/yaala/yaala-0.7.3-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PERL_EXPORT_PHASE_FUNCTIONS=no
+inherit eutils perl-module
+
+DESCRIPTION="Yet Another Log Analyzer"
+HOMEPAGE="http://www.yaala.org/"
+SRC_URI="http://www.${PN}.org/files/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="gd"
+
+RDEPEND="
+	dev-lang/perl
+	virtual/perl-Storable
+	gd? ( dev-perl/GDGraph )
+"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.7.3-r1-correct-paths.patch
+
+	sed -i "s:/var/lib/${PN}:/usr/bin:g" packaging/${PN}.cron || die 'Failed to correct path in cron file.'
+}
+
+src_install() {
+	dobin ${PN}
+
+	# Switch to ^y when we switch to EAPI=6.
+	local mod="Y${PN:1}"
+
+	perl_set_version
+
+	insinto "${VENDOR_LIB}/${mod}/"
+	doins lib/${mod}/*.pm
+
+	insinto "${VENDOR_LIB}/${mod}/Data/"
+	doins lib/${mod}/Data/*.pm
+
+	insinto "${VENDOR_LIB}/${mod}/Parser/"
+	doins lib/${mod}/Parser/*.pm
+
+	insinto "${VENDOR_LIB}/${mod}/Report/"
+	doins lib/${mod}/Report/*.pm
+
+	dodoc AUTHORS CHANGELOG README{,.persistency,.selections}
+
+	insinto /usr/share/${PN}
+	doins -r reports
+	doins -r sample_configs
+
+	insinto /etc/${PN}
+	doins {,webserver.}config
+
+	insinto /etc/logrotate.d
+	doins packaging/${PN}.cron
+
+	keepdir /var/lib/${PN}
+	fperms 777 /var/lib/${PN}
+}
+
+pkg_postinst() {
+	ewarn "It is required that you change the configuration files in /etc/${PN}"
+	ewarn "before you run \`yaala ...\`, otherwise it will refuse to execute because"
+	ewarn "Setup.pm checks whether the variable 'select' has been unquoted and set."
+	echo ""
+	elog "Example configuration files can be found in /usr/share/${PN}."
+}