[gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-settings-daemon/

[Mart Raudsepp]

commit:     6f0abde48b4d343491c2beff0c0d43000e86c744
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 14 08:07:41 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Thu Mar 14 09:34:37 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6f0abde4

gnome-base/gnome-settings-daemon: bump to 3.30.2

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-base/gnome-settings-daemon/Manifest          |   2 +
 .../gnome-settings-daemon-3.30.2.ebuild            | 130 +++++++++++++++++++++
 2 files changed, 132 insertions(+)

diff --git a/gnome-base/gnome-settings-daemon/Manifest b/gnome-base/gnome-settings-daemon/Manifest
index d3741516231..150fea5e155 100644
--- a/gnome-base/gnome-settings-daemon/Manifest
+++ b/gnome-base/gnome-settings-daemon/Manifest
@@ -4,3 +4,5 @@ DIST gnome-settings-daemon-3.26.2-patchset.tar.xz 42408 BLAKE2B 3b54dd1b161f4137
 DIST gnome-settings-daemon-3.26.2.tar.xz 1589696 BLAKE2B f1fd18e80caf5badb0da1f07cbe994b73a99ace004bf3b568114d6cd6110ebd092ee3a023a1ec818f3946f6f7cdb7ee21417782e271c8aa9ebd9d1d4c35ea286 SHA512 7785ebcb7df466c50557b75a3092f568e375adcf5a40f73e31d5cc69fa63bc556a4447a96e6e612c3bf523735e67168afae0b9c1fab32912d41014436d33b7ff
 DIST gnome-settings-daemon-3.28.1-patchset.tar.xz 5216 BLAKE2B eab85f6475c1da9c8beb1dea7d7d79bdaf2e57ac82e90a4ab877e5ffbd8423df8ed5dbd03ac6586a3aadf2be16b89e2955267be24af71db8c89cc407241e0bc9 SHA512 f56a5d62ba45976a01c8fcab63c4d7afd21dbe7a4c75158cc54fc60552faf875b0ca1be7a882c11d814566e7a4ded63ce52d10d214bd1f7926c2d7b0dbaf1590
 DIST gnome-settings-daemon-3.28.1.tar.xz 1362420 BLAKE2B d809696ea7a2df3b89b1e2badbd015623e624c38f44a087e26d167c7ba9a5499a33e6e4ebb12448f69d8aa645154bc176a156f1b9e4a749684e5a497a7be6fc6 SHA512 22e42ce92a6f3ad67a0ef7d1676a6dd3d533b0bc91193d8b2a19a51d7c9601c87caf391c233bb1b96e8a1270d610aca52523d0ae12a38b0e3911065c3a67e10f
+DIST gnome-settings-daemon-3.30.2-patchset.tar.xz 20132 BLAKE2B b8f2573e806ee5aedcc1476de3550cdc39933c869d64c9d13e463cdf27fa7695e69e57612738fa5438988eda78ae998808508c94fbf841ec037eb1f103921458 SHA512 7318029f4145379b05f7a95686917b4ea7623fd0059559930072350db12170d6083d75c170578516bcede5282da677013086c343abe779b9d1696bd882b7e34d
+DIST gnome-settings-daemon-3.30.2.tar.xz 1376776 BLAKE2B a7cf276c5a802b7d9a6f738048b5bc34d97f79723c6f4cfb4f29ac3ed0f43e307cbdd6793e8d8115f51981ee576737d75c58531dcd5d0779d9f3670b68523a60 SHA512 517cb6bab3da10d5d47ab9c9690da3fa23e64d023d01b7cc101441f6b65639f3b6c8d0a0d19da80b22924b3dbe6430b2573fb861060f02fda248b24f00be5d84

diff --git a/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.30.2.ebuild b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.30.2.ebuild
new file mode 100644
index 00000000000..17007e2d274
--- /dev/null
+++ b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.30.2.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_4,3_5,3_6,3_7} )
+
+inherit gnome.org gnome2-utils python-any-r1 meson udev virtualx xdg
+
+DESCRIPTION="Gnome Settings Daemon"
+HOMEPAGE="https://git.gnome.org/browse/gnome-settings-daemon"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="+colord +cups debug elogind input_devices_wacom networkmanager smartcard systemd test +udev wayland"
+REQUIRED_USE="
+	^^ ( elogind systemd )
+	input_devices_wacom? ( udev )
+	wayland? ( udev )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+
+# >=polkit-0.114 for ITS translation rules of .policy files
+COMMON_DEPEND="
+	>=sci-geosciences/geocode-glib-3.10
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gnome-desktop-3.11.1:3=
+	>=gnome-base/gsettings-desktop-schemas-3.27.90
+	>=x11-libs/gtk+-3.15.3:3[X,wayland?]
+	>=dev-libs/libgweather-3.9.5:2=
+	colord? (
+		>=x11-misc/colord-1.0.2:=
+		>=media-libs/lcms-2.2:2 )
+	media-libs/libcanberra[gtk3]
+	>=app-misc/geoclue-2.3.1:2.0
+	>=x11-libs/libnotify-0.7.3
+	>=media-sound/pulseaudio-2[glib]
+	>=sys-auth/polkit-0.114
+	>=sys-power/upower-0.99:=
+	x11-libs/libX11
+	x11-libs/libXtst
+	udev? ( virtual/libgudev:= )
+	wayland? ( dev-libs/wayland )
+	input_devices_wacom? ( >=dev-libs/libwacom-0.7
+		>=x11-libs/pango-1.20.0
+		x11-libs/gdk-pixbuf:2 )
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	cups? ( >=net-print/cups-1.4[dbus] )
+	networkmanager? ( >=net-misc/networkmanager-1.0 )
+	media-libs/alsa-lib
+	x11-libs/libXi
+	x11-libs/libXext
+	media-libs/fontconfig
+"
+# logind needed for power and session management, bug #464944
+# gnome-session-3.27.90 and gdm-3.27.9 adapt to A11yKeyboard component removal (moved to shell dealing with it)
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/dconf
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd )
+	!<gnome-base/gnome-session-3.27.90
+	!<gnome-base/gdm-3.27.90
+"
+# rfkill requires linux/rfkill.h, thus linux-headers dep, not os-headers. If this package wants to work on other kernels, we need to make rfkill conditional instead
+DEPEND="${COMMON_DEPEND}
+	sys-kernel/linux-headers
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	x11-base/xorg-proto
+	${PYTHON_DEPS}
+	test? (
+		$(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+		$(python_gen_any_dep 'dev-python/dbusmock[${PYTHON_USEDEP}]')
+		gnome-base/gnome-session )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+# Tests go a bit better in 3.26, but still fail some for me; revisit with 3.30+ (incompatible build system python needs until then as well)
+#RESTRICT="!test? ( test )"
+
+PATCHES=(
+	# Translation updates from gnome-3-30 branch
+	# Allow disabling udev and networkmanager on Linux
+	# Make colord and wacom optional
+	"${WORKDIR}"/patches/
+)
+
+python_check_deps() {
+	if use test; then
+		has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" &&
+		has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		#-Dnssdb_dir # TODO: Is the default /etc/pki/nssdb path correct for our nss?
+		-Dudev_dir="$(get_udevdir)"
+		-Dalsa=true
+		$(meson_use udev gudev)
+		$(meson_use colord)
+		$(meson_use cups)
+		$(meson_use networkmanager network_manager)
+		-Drfkill=true
+		$(meson_use smartcard)
+		$(meson_use input_devices_wacom wacom)
+		$(meson_use wayland)
+		-Dexperimental_suspend_then_hibernate=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}