[gentoo-commits] gentoo-x86 commit in sys-fs/multipath-tools: ChangeLog multipath-tools-0.4.8.ebuild

[Robin H. Johnson (robbat2)]

robbat2     08/06/20 23:57:19

  Modified:             ChangeLog
  Added:                multipath-tools-0.4.8.ebuild
  Log:
  Make multipath-tools work for early boot environments for both baselayout1 and baselayout2. Please read the postinst output if multipath is critical to your environment!
  (Portage version: 2.2_pre8/cvs/Linux 2.6.26-rc4-00103-g1beee8d x86_64)

Revision  Changes    Path
1.17                 sys-fs/multipath-tools/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -p -w -b -B -u -u -r1.16 -r1.17
--- ChangeLog	2 Feb 2008 06:09:46 -0000	1.16
+++ ChangeLog	20 Jun 2008 23:57:18 -0000	1.17
@@ -1,6 +1,16 @@
 # ChangeLog for sys-fs/multipath-tools
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/ChangeLog,v 1.16 2008/02/02 06:09:46 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/ChangeLog,v 1.17 2008/06/20 23:57:18 robbat2 Exp $
+
+*multipath-tools-0.4.8 (20 Jun 2008)
+
+  20 Jun 2008; Robin H. Johnson <robbat2@g.o>
+  +files/multipath-tools-0.4.8-build.patch, +files/init.d-multipath,
+  +files/multipath-start.sh, +files/multipath-stop.sh,
+  +multipath-tools-0.4.8.ebuild:
+  Make multipath-tools work for early boot environments for both baselayout1
+  and baselayout2. Please read the postinst output if multipath is critical
+  to your environment!
 
   02 Feb 2008; Christian Faulhammer <opfer@g.o>
   multipath-tools-0.4.7-r2.ebuild:



1.1                  sys-fs/multipath-tools/multipath-tools-0.4.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.8.ebuild?rev=1.1&content-type=text/plain

Index: multipath-tools-0.4.8.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.8.ebuild,v 1.1 2008/06/20 23:57:18 robbat2 Exp $

inherit eutils toolchain-funcs

DESCRIPTION="Device mapper target autoconfig"
HOMEPAGE="http://christophe.varoqui.free.fr/"
SRC_URI="http://christophe.varoqui.free.fr/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND=">=sys-fs/device-mapper-1.00.19-r1
	sys-fs/udev
	sys-fs/sysfsutils"
DEPEND="${RDEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-0.4.8-build.patch
	# Merged together
	#epatch "${FILESDIR}"/${PN}-0.4.7-udev-rules.patch
}

src_compile() {
	emake -j1 CC="$(tc-getCC)" || die "emake failed"
}

src_install() {
	dodir /sbin /usr/share/man/man8
	make DESTDIR="${D}" install || die "install failed"

	insinto /etc
	newins "${S}"/multipath.conf.annotated multipath.conf
	fperms 644 /etc/udev/rules.d/65-multipath.rules
	fperms 644 /etc/udev/rules.d/66-kpartx.rules
	# This is the monitoring daemon
	newinitd "${FILESDIR}"/rc-multipathd multipathd
	# This is the init script that fires the multipath addon for baselayout2
	newinitd "${FILESDIR}"/init.d-multipath multipath
	# Handle early-boot startup as well as shutdown of multipath devices
	insinto /lib/rcscripts/addons
	doins "${FILESDIR}"/multipath-start.sh
	doins "${FILESDIR}"/multipath-stop.sh

	dodoc multipath.conf.*
	dodoc AUTHOR ChangeLog FAQ README TODO
	docinto kpartx; dodoc kpartx/ChangeLog kpartx/README
}

pkg_preinst() {
	# The dev.d script was previously wrong and is now removed (the udev rules
	# file does the job instead), but it won't be removed from live systems due
	# to cfgprotect.
	# This should help out a little...
	if [[ -e ${ROOT}/etc/dev.d/block/multipath.dev ]] ; then
		mkdir -p "${D}"/etc/dev.d/block
		echo "# Please delete this file. It is obsoleted by /etc/udev/rules.d/65-multipath.rules" \
			> "${D}"/etc/dev.d/block/multipath.dev
	fi
}
pkg_postinst() {
	elog "If you need multipath on your system, you should ensure that a"
	elog "'multipath' entry is present in your RC_VOLUME_ORDER variable!"
	elog "If you use baselayout2, you must add 'multipath' into"
	elog "your boot runlevel!"
}



-- 
gentoo-commits@l.g.o mailing list