[gentoo-commits] gentoo-x86 commit in www-apps/blohg: blohg-0.13.ebuild ChangeLog blohg-0.12.ebuild

[Rafael Martins (rafaelmartins)]

rafaelmartins    14/06/10 01:04:15

  Modified:             ChangeLog
  Added:                blohg-0.13.ebuild
  Removed:              blohg-0.12.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.32                 www-apps/blohg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/blohg/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/blohg/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/blohg/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/blohg/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	9 Jun 2014 03:33:49 -0000	1.31
+++ ChangeLog	10 Jun 2014 01:04:15 -0000	1.32
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/blohg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/blohg/ChangeLog,v 1.31 2014/06/09 03:33:49 rafaelmartins Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/blohg/ChangeLog,v 1.32 2014/06/10 01:04:15 rafaelmartins Exp $
+
+*blohg-0.13 (10 Jun 2014)
+
+  10 Jun 2014; Rafael G. Martins <rafaelmartins@g.o> +blohg-0.13.ebuild,
+  -blohg-0.12.ebuild:
+  version bump
 
   09 Jun 2014; Rafael G. Martins <rafaelmartins@g.o> blohg-9999.ebuild:
   ported 9999 to distutils-r1, fixed deps



1.1                  www-apps/blohg/blohg-0.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/blohg/blohg-0.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/blohg/blohg-0.13.ebuild?rev=1.1&content-type=text/plain

Index: blohg-0.13.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/blohg/blohg-0.13.ebuild,v 1.1 2014/06/10 01:04:15 rafaelmartins Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )

GIT_ECLASS=""
if [[ ${PV} = *9999* ]]; then
	GIT_ECLASS="git-r3"
	EGIT_REPO_URI="git://github.com/rafaelmartins/blohg.git
		https://github.com/rafaelmartins/blohg"
fi

inherit distutils-r1 ${GIT_ECLASS}

DESCRIPTION="A Mercurial (or Git) based blogging engine."
HOMEPAGE="http://blohg.org/ http://pypi.python.org/pypi/blohg"

SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
if [[ ${PV} = *9999* ]]; then
	SRC_URI=""
	KEYWORDS=""
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="doc git +mercurial test"

REQUIRED_USE="|| ( git mercurial )
	test? ( git mercurial )"

RDEPEND="
	=dev-python/click-2.0
	=dev-python/docutils-0.11*
	>=dev-python/flask-0.10.1
	>=dev-python/flask-babel-0.7
	>=dev-python/frozen-flask-0.7
	>=dev-python/jinja-2.5.2
	dev-python/pyyaml
	dev-python/setuptools
	dev-python/pygments
	git? ( =dev-python/pygit2-0.20* )
	mercurial? ( >=dev-vcs/mercurial-1.6 )"

DEPEND="${RDEPEND}
	doc? ( dev-python/sphinx )
	test? ( dev-python/mock )"

python_prepare_all() {
	if ! use git; then
		rm -rf blohg/vcs_backends/git || die 'rm failed'
	fi

	if ! use mercurial; then
		rm -rf blohg/vcs_backends/hg || die 'rm failed'
	fi

	distutils-r1_python_prepare_all
}

python_compile_all() {
	use doc && emake -C docs html
}

python_install_all() {
	use doc && HTML_DOCS=( docs/_build/html/. )
	distutils-r1_python_install_all
}

python_test() {
	esetup.py test
}

pkg_postinst() {
	local ver="${PV}"
	[[ ${PV} = *9999* ]] && ver="latest"

	elog "You may want to check the upgrade notes:"
	elog "http://docs.blohg.org/en/${ver}/upgrade/"
}