[gentoo-commits] repo/gentoo:master commit in: dev-util/systemtap/

[Sam James]

commit:     f34a5e36c7ec1608f4752d2eda545751da14846c
Author:     Alessandro Barbieri <lssndrbarbieri <AT> gmail <DOT> com>
AuthorDate: Wed Nov  3 17:56:35 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Nov  4 20:04:38 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f34a5e36

dev-util/systemtap: EAPI 8

bump python
autoreconf

Closes: https://bugs.gentoo.org/789795
Closes: https://bugs.gentoo.org/820029
Closes: https://bugs.gentoo.org/820155
Closes: https://bugs.gentoo.org/532570
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Alessandro Barbieri <lssndrbarbieri <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/22808
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/systemtap/systemtap-4.5-r1.ebuild | 117 +++++++++++++++++++++++++++++
 1 file changed, 117 insertions(+)

diff --git a/dev-util/systemtap/systemtap-4.5-r1.ebuild b/dev-util/systemtap/systemtap-4.5-r1.ebuild
new file mode 100644
index 00000000000..b11a0b1830c
--- /dev/null
+++ b/dev-util/systemtap/systemtap-4.5-r1.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit autotools linux-info python-single-r1
+
+DESCRIPTION="A linux trace/probe tool"
+HOMEPAGE="https://www.sourceware.org/systemtap"
+SRC_URI="https://www.sourceware.org/${PN}/ftp/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="libvirt selinux sqlite +ssl test zeroconf"
+
+CDEPEND="
+	${PYTHON_DEPS}
+
+	>=dev-libs/elfutils-0.142
+	dev-libs/json-c:=
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+
+	libvirt? ( >=app-emulation/libvirt-1.0.2 )
+	selinux? ( sys-libs/libselinux )
+	sqlite? ( dev-db/sqlite:3 )
+	ssl? (
+		dev-libs/nspr
+		dev-libs/nss
+	)
+	zeroconf? ( net-dns/avahi )
+"
+DEPEND="
+	${CDEPEND}
+	app-arch/cpio
+	app-text/xmlto
+	$(python_gen_cond_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	>=sys-devel/gettext-0.18.2
+
+	libvirt? ( dev-libs/libxml2 )
+"
+RDEPEND="
+	${CDEPEND}
+	acct-group/stapdev
+	acct-group/stapsys
+	acct-group/stapusr
+"
+BDEPEND="test? ( dev-util/dejagnu )"
+
+CONFIG_CHECK="~KPROBES ~RELAY ~DEBUG_FS"
+ERROR_KPROBES="${PN} requires support for KProbes Instrumentation (KPROBES) - this can be enabled in 'Instrumentation Support -> Kprobes'."
+ERROR_RELAY="${PN} works with support for user space relay support (RELAY) - this can be enabled in 'General setup -> Kernel->user space relay support (formerly relayfs)'."
+ERROR_DEBUG_FS="${PN} works best with support for Debug Filesystem (DEBUG_FS) - this can be enabled in 'Kernel hacking -> Debug Filesystem'."
+
+DOCS="AUTHORS HACKING NEWS README"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+PATCHES=(
+	"${FILESDIR}/${PN}-3.1-ia64.patch"
+)
+
+pkg_setup() {
+	linux-info_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	python_fix_shebang .
+
+	sed -i \
+		-e 's|-Werror||g' \
+		configure.ac \
+		Makefile.am \
+		stapbpf/Makefile.am \
+		stapdyn/Makefile.am \
+		staprun/Makefile.am \
+		testsuite/systemtap.unprivileged/unprivileged_probes.exp \
+		testsuite/systemtap.unprivileged/unprivileged_myproc.exp \
+		testsuite/systemtap.base/stmt_rel_user.exp \
+		testsuite/systemtap.base/sdt_va_args.exp \
+		testsuite/systemtap.base/sdt_misc.exp \
+		testsuite/systemtap.base/sdt.exp \
+		scripts/kprobes_test/gen_code.py \
+		|| die "Failed to clean up sources"
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-docs
+		--disable-grapher
+		--disable-refdocs
+		--disable-server
+		--enable-pie
+		--with-python3
+		--without-java
+		--without-openssl
+		--without-python2-probes
+		--without-rpm
+		$(use_enable libvirt virt)
+		$(use_enable sqlite)
+		$(use_with zeroconf avahi)
+		$(use_with ssl nss)
+		$(use_with selinux)
+	)
+	PYTHON3="${PYTHON}" econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	python_optimize
+}