[gentoo-commits] gentoo-x86 commit in x11-libs/qt-declarative: metadata.xml ChangeLog qt-declarative-4.6.0.ebuild

[Dominik Kapusta (ayoy)]

ayoy        09/12/26 20:49:18

  Added:                metadata.xml ChangeLog qt-declarative-4.6.0.ebuild
  Log:
  Initial commit for Qt Declarative module (bug #297573)
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  x11-libs/qt-declarative/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-declarative/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-declarative/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>qt</herd>
	<use>
		<flag name='demos'>Install a set of demo applications</flag>
	</use>
</pkgmetadata>



1.1                  x11-libs/qt-declarative/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-declarative/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-declarative/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for x11-libs/qt-declarative
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-declarative/ChangeLog,v 1.1 2009/12/26 20:49:17 ayoy Exp $

*qt-declarative-4.6.0 (26 Dec 2009)

  26 Dec 2009; Dominik Kapusta <ayoy@g.o>
  +qt-declarative-4.6.0.ebuild, +metadata.xml:
  Initial commit for Qt Declarative module (bug #297573)




1.1                  x11-libs/qt-declarative/qt-declarative-4.6.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-declarative/qt-declarative-4.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-declarative/qt-declarative-4.6.0.ebuild?rev=1.1&content-type=text/plain

Index: qt-declarative-4.6.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-declarative/qt-declarative-4.6.0.ebuild,v 1.1 2009/12/26 20:49:17 ayoy Exp $

EAPI="2"

inherit qt4-r2

MY_P="qt-${PV}${PN#qt}"

DESCRIPTION="The Declarative module for the Qt toolkit"
HOMEPAGE="http://qt.nokia.com"
SRC_URI="http://get.qt.nokia.com/qml/${MY_P}.tar.gz"

LICENSE="|| ( LGPL-2.1 GPL-3 )"
SLOT="4"
KEYWORDS="~amd64 ~x86"
IUSE="debug demos examples"

DEPEND="~x11-libs/qt-core-${PV}
	~x11-libs/qt-gui-${PV}
	~x11-libs/qt-script-${PV}
	~x11-libs/qt-sql-${PV}
	~x11-libs/qt-webkit-${PV}
	~x11-libs/qt-xmlpatterns-${PV}"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# help qmlviewer and qmldebugger find the freshly compiled Declarative module
	echo "LIBS += -L\"${S}/src/declarative/.obj\"" \
		>> "${S}/tools/qmlviewer/qmlviewer.pro" \
		|| die "fixing LDFLAGS failed"
}

src_configure() {
	eqmake4 src/declarative/declarative.pro -o src/declarative/Makefile

	# running "eqmake4 tools/qmlviewer/qmlviewer.pro"
	# fails with some relative paths not being found
	# so we have to cd
	cd "${S}/tools/qmlviewer"
	eqmake4
}

src_compile() {
	emake -C src/declarative || die "compiling declarative module failed"
	emake -C tools/qmlviewer || die "compiling qmlviewer failed"
}

src_install() {
	emake INSTALL_ROOT="${D}" -C src/declarative install \
		|| die "installing declarative module failed"

	emake INSTALL_ROOT="${D}" -C tools/qmlviewer install \
		|| die "installing qmlviewer failed"

	dodoc README.html || die "dodoc failed"

	for feature in demos examples; do
		if use ${feature}; then
			insinto "/usr/share/${PN}/${feature}"
			doins -r "${feature}/declarative" || die "installing ${feature} failed"
		fi
	done
}