[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-workspace/

[Andreas Sturmlechner]

commit:     5a00494857192e78b881d54d133afd7a247986ee
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Oct  1 06:28:19 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Oct  1 06:43:51 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5a004948

kde-plasma/plasma-workspace: 5.22.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-workspace/Manifest               |   1 +
 .../plasma-workspace-5.22.90.ebuild                | 206 +++++++++++++++++++++
 2 files changed, 207 insertions(+)

diff --git a/kde-plasma/plasma-workspace/Manifest b/kde-plasma/plasma-workspace/Manifest
index 0039ae12111..f8c003fcc39 100644
--- a/kde-plasma/plasma-workspace/Manifest
+++ b/kde-plasma/plasma-workspace/Manifest
@@ -1 +1,2 @@
 DIST plasma-workspace-5.22.5.tar.xz 8401412 BLAKE2B 3479549ffb302f8beca8f37853540bd71cc03a02183826435ec47ded0df69f4b19e103d8b6e2cd16af001a9c04a34e2f37a98a461f40fb8837ed7e7128a6fcba SHA512 753ba35c3f0c3a5affe10d3a6149f1ebca7ed51b0710c079606e33ceada94a50eee1c1bafbb465fcc194038915c33edef1d79e0865e5702aab7a334d6d508c47
+DIST plasma-workspace-5.22.90.tar.xz 8981860 BLAKE2B 505189ed45587b29756ca80d384fd6b21ee04a0821d2c23b041a6199f6998413b9a359dbfd855eebde3150cee45bb3c9a2e425b5035a8b78a7025dda9c4e5b4d SHA512 0f400cd6753bf3d793a2efd5fa75d45cbcac0fe43e2e783d3d06374422a1a59354e6ef986e0286915193c06a6d2beaf443cb028d598783e18115437d12768816

diff --git a/kde-plasma/plasma-workspace/plasma-workspace-5.22.90.ebuild b/kde-plasma/plasma-workspace/plasma-workspace-5.22.90.ebuild
new file mode 100644
index 00000000000..8ec178423e3
--- /dev/null
+++ b/kde-plasma/plasma-workspace/plasma-workspace-5.22.90.ebuild
@@ -0,0 +1,206 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.86.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma workspace"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="appstream +calculator +calendar +fontconfig geolocation gps screencast
++semantic-desktop systemd telemetry"
+
+REQUIRED_USE="gps? ( geolocation )"
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=dev-libs/wayland-1.15
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5=[jpeg,libinput]
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwayland-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kinit-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kpeople-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kunitconversion-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/prison-${KFMIN}:5[qml]
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-plasma/breeze-${PVCUT}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+	>=kde-plasma/layer-shell-qt-${PVCUT}:5
+	>=kde-plasma/libkscreen-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=media-libs/phonon-4.11.0
+	sys-libs/zlib
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libxcb
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	appstream? ( dev-libs/appstream[qt5] )
+	calculator? ( sci-libs/libqalculate:= )
+	calendar? ( >=kde-frameworks/kholidays-${KFMIN}:5 )
+	fontconfig? (
+		>=dev-qt/qtprintsupport-${QTMIN}:5
+		media-libs/fontconfig
+		x11-libs/libXft
+		x11-libs/xcb-util-image
+	)
+	geolocation? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
+	gps? ( sci-geosciences/gpsd )
+	screencast? (
+		>=dev-qt/qtgui-${QTMIN}:5=[egl]
+		media-libs/libglvnd
+		>=media-video/pipewire-0.3:=
+		x11-libs/libdrm
+	)
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+	telemetry? ( dev-libs/kuserfeedback:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/plasma-wayland-protocols-1.1.1
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-util/wayland-scanner-1.19.0
+	x11-base/xorg-proto
+	fontconfig? ( x11-libs/libXrender )
+"
+RDEPEND="${COMMON_DEPEND}
+	app-text/iso-codes
+	>=dev-qt/qdbus-${QTMIN}:5
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpaths-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5[widgets]
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	kde-apps/kio-extras:5
+	>=kde-frameworks/kdesu-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kquickcharts-${KFMIN}:5
+	>=kde-plasma/milou-${PVCUT}:5
+	>=kde-plasma/plasma-integration-${PVCUT}:5
+	x11-apps/xmessage
+	x11-apps/xprop
+	x11-apps/xrdb
+	x11-apps/xsetroot
+	systemd? ( sys-apps/dbus[user-session] )
+	!systemd? ( sys-apps/dbus )
+	!<kde-plasma/breeze-5.22.90:5
+	!<kde-plasma/plasma-desktop-5.21.90:5
+"
+BDEPEND="virtual/pkgconfig"
+PDEPEND=">=kde-plasma/kde-cli-tools-${PVCUT}:5"
+
+PATCHES=( "${FILESDIR}/${PN}-5.21.5-split-libkworkspace.patch" ) # downstream
+
+src_prepare() {
+	ecm_src_prepare
+
+	cmake_comment_add_subdirectory libkworkspace
+	# delete colliding libkworkspace translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
+	fi
+
+	# TODO: try to get a build switch upstreamed
+	if ! use screencast; then
+		sed -e "s/^pkg_check_modules.*PipeWire/#&/" -i CMakeLists.txt || die
+	fi
+
+	# KDE-bug: 433730
+	use calculator ||
+		cmake_run_in runners cmake_comment_add_subdirectory calculator
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_xembed-sni-proxy=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON
+		$(cmake_use_find_package appstream AppStreamQt)
+		$(cmake_use_find_package calendar KF5Holidays)
+		$(cmake_use_find_package fontconfig Fontconfig)
+		$(cmake_use_find_package geolocation KF5NetworkManagerQt)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+
+	use geolocation && mycmakeargs+=( $(cmake_use_find_package gps libgps) )
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# default startup and shutdown scripts
+	insinto /etc/xdg/plasma-workspace/env
+	doins "${FILESDIR}"/10-agent-startup.sh
+
+	insinto /etc/xdg/plasma-workspace/shutdown
+	doins "${FILESDIR}"/10-agent-shutdown.sh
+	fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
+	elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
+	elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
+}