[gentoo-commits] repo/gentoo:master commit in: dev-games/tiled/

[Michael Palimaka]

commit:     589ecc23cbbdf84508256944ceb78ecca25c2b54
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Sat Sep  2 13:49:17 2017 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Sat Sep  2 13:54:06 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=589ecc23

dev-games/tiled: version bump 1.0.3

Package-Manager: Portage-2.3.6, Repoman-2.3.3

 dev-games/tiled/Manifest           |  1 +
 dev-games/tiled/tiled-1.0.3.ebuild | 63 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index d6b54ef21a0..5ff00966c95 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-1.0.2.tar.gz 6601753 SHA256 23dd9ec1c7437f03fbb45d05b0706d8ed9fa4327ac421c6446034ad5c9899d8c SHA512 d85a90cd515a0f7bcd63bd00452ab271e41c4c23ea78a3167024d4052ff83782eca81836874a9acc03ea304782e7ed4e6e377dadea8197874337e58c38dc305b WHIRLPOOL c72fbb2508438672a8b4995e4c2e88404e76b98df6e4522ad7bd4bf99aecde96e6ba267553d152ca89804d0ff4709d82d7205422325b98e09494425f69149d07
+DIST tiled-1.0.3.tar.gz 6601791 SHA256 3d0665bd988a877b7156842daeddd91fa17b1b473d2e5ebf8a62ffe2c9a047e2 SHA512 4f3c97a91794f86f04965a2332e04f51bc588f7bcfef402edb1092c4e58bb6ace9c90ea522a5fa15a46ca39c8249f62818b80be6d65c11a8d41092ead31cd4f7 WHIRLPOOL f69978ef073d1516157306839cab40c3414d5743f1f9c1cfa952fac0ec81cfef075cd8bebba3f3f84b7b9dfdef48ca069728d6c7c041587d42333d332f59a8e9

diff --git a/dev-games/tiled/tiled-1.0.3.ebuild b/dev-games/tiled/tiled-1.0.3.ebuild
new file mode 100644
index 00000000000..b2e4dcb64ab
--- /dev/null
+++ b/dev-games/tiled/tiled-1.0.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit gnome2-utils multilib python-single-r1 qmake-utils xdg
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="http://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-qt/qtcore-5.7:5
+	>=dev-qt/qtgui-5.7:5
+	>=dev-qt/qtnetwork-5.7:5
+	>=dev-qt/qtwidgets-5.7:5
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	eqmake5 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+
+	if use examples ; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}