[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

[Michał Górny]

commit:     ac0156cde84aff67968fc9ae44ab2211fe891d06
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri May 14 07:55:48 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri May 14 08:14:24 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ac0156cd

dev-python/django: Bump to 3.2.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest            |  2 +
 dev-python/django/django-3.2.3.ebuild | 94 +++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 9b3bbca974b..96f55e96277 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -4,3 +4,5 @@ DIST Django-3.1.10.checksum.txt 2551 BLAKE2B 811e820ef036301ee1a6aafb2f74e5809ba
 DIST Django-3.1.10.tar.gz 9654073 BLAKE2B c3729b7007b0b8309fda111f7bd988c861fb1002da3683e972a01bcd2aecfc6b42e896f91297239cba2061106096226552c26eb50325ea5b50f5a5df3a191bfd SHA512 6dd3c7a5cd1b5cbeb6e62f72fa56fce260bd407a3ac659ddee893489efae7a6bea862ecc113da342a2ed4cffa39e564c55dd20792b5435f9f00fef5488579aad
 DIST Django-3.2.2.checksum.txt 2542 BLAKE2B 1a61ea4e8415d77b50d0dc227905596941a9cfed019c3442be1d7529d0b82204b08e15befdcccccd3a7a4625b762e99526b762053e9ec7c29068caa2dfe055a1 SHA512 eebb6e7172d85af3d6f65296d816f40cacd78c8270bd198d275c3c2844e9106ec517265490e7371d5df803d044ee1534a4eb836d2a279d395884c1ec7b9cb0f5
 DIST Django-3.2.2.tar.gz 9796920 BLAKE2B 09a720d169702f1d80b592e8a4c8e136b9b3c4539db44f8bcf3ef7d0e6bb678892b7ad4bbeac89fc887c9938cb35d8a9d3fee9a58e692f99c37e81f01615a6b4 SHA512 28d1d56cdf883f8fb5e438124be53dbefaa0045d1acf0b4b8b455a482422e2b88ffc5a3c8be2ee1b7d3c39fe29cfa854b44b438c3d43323483bd35e0d05f9e49
+DIST Django-3.2.3.checksum.txt 2543 BLAKE2B e15fd98b887e3e416d6636a84cfe08e23d920c3044c0382ff0821b47dced378fb89d05bd0e128b1237423be72ccdd1454f4a092b543f2325e1d3d1072e508ccf SHA512 7c898155e085f003dd9872cf266484d4d533d869df18aa5c431ca6bf9dee2682ef61921e3f31e43392c0539d2175a8000a37f371519ae485b38bda0eede54c67
+DIST Django-3.2.3.tar.gz 9798957 BLAKE2B b3b72fc405d13c63d6b12819390ee281319275350b38cbd7f8a2657f8ad39b7c4168b560d0c8db4a2f26231f6dccf5855bfa1259d6fb3d51fd1decc5e406d837 SHA512 a1f9f9661f1a851a00387007f5079615e70ad2357a3a99a1b4a77da6a31419b22fd9d321b8d9737092a02a3055df76cee2aa69404b804b392d94d3423d54b0f8

diff --git a/dev-python/django/django-3.2.3.ebuild b/dev-python/django/django-3.2.3.ebuild
new file mode 100644
index 00000000000..87dacd55b40
--- /dev/null
+++ b/dev-python/django/django-3.2.3.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=app-crypt/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}