Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Vlastimil Babka (caster)" <caster@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in dev-java/sun-jre-bin: ChangeLog sun-jre-bin-1.6.0.34.ebuild
Date: Thu, 23 Aug 2012 20:15:45
Message-Id: 20120823201534.BE3CC204BC@flycatcher.gentoo.org
1 caster 12/08/23 20:15:34
2
3 Modified: ChangeLog
4 Added: sun-jre-bin-1.6.0.34.ebuild
5 Log:
6 Version bump, bug #431492.
7
8 (Portage version: 2.2.0_alpha116/cvs/Linux x86_64)
9
10 Revision Changes Path
11 1.219 dev-java/sun-jre-bin/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/sun-jre-bin/ChangeLog?rev=1.219&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/sun-jre-bin/ChangeLog?rev=1.219&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/sun-jre-bin/ChangeLog?r1=1.218&r2=1.219
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/dev-java/sun-jre-bin/ChangeLog,v
20 retrieving revision 1.218
21 retrieving revision 1.219
22 diff -u -r1.218 -r1.219
23 --- ChangeLog 3 Aug 2012 13:53:49 -0000 1.218
24 +++ ChangeLog 23 Aug 2012 20:15:34 -0000 1.219
25 @@ -1,6 +1,12 @@
26 # ChangeLog for dev-java/sun-jre-bin
27 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/dev-java/sun-jre-bin/ChangeLog,v 1.218 2012/08/03 13:53:49 ago Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/dev-java/sun-jre-bin/ChangeLog,v 1.219 2012/08/23 20:15:34 caster Exp $
30 +
31 +*sun-jre-bin-1.6.0.34 (23 Aug 2012)
32 +
33 + 23 Aug 2012; Vlastimil Babka <caster@g.o>
34 + +sun-jre-bin-1.6.0.34.ebuild:
35 + Version bump, bug #431492.
36
37 03 Aug 2012; Agostino Sarubbo <ago@g.o>
38 sun-jre-bin-1.6.0.33-r1.ebuild:
39
40
41
42 1.1 dev-java/sun-jre-bin/sun-jre-bin-1.6.0.34.ebuild
43
44 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/sun-jre-bin/sun-jre-bin-1.6.0.34.ebuild?rev=1.1&view=markup
45 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/sun-jre-bin/sun-jre-bin-1.6.0.34.ebuild?rev=1.1&content-type=text/plain
46
47 Index: sun-jre-bin-1.6.0.34.ebuild
48 ===================================================================
49 # Copyright 1999-2012 Gentoo Foundation
50 # Distributed under the terms of the GNU General Public License v2
51 # $Header: /var/cvsroot/gentoo-x86/dev-java/sun-jre-bin/sun-jre-bin-1.6.0.34.ebuild,v 1.1 2012/08/23 20:15:34 caster Exp $
52
53 EAPI="4"
54
55 inherit java-vm-2 eutils prefix versionator
56
57 # This URIs need to be updated when bumping!
58 JRE_URI="http://www.oracle.com/technetwork/java/javase/downloads/jre6-downloads-1637595.html"
59
60 MY_PV="$(get_version_component_range 2)u$(get_version_component_range 4)"
61 S_PV="$(replace_version_separator 3 '_')"
62
63 X86_AT="jre-${MY_PV}-linux-i586.bin"
64 AMD64_AT="jre-${MY_PV}-linux-x64.bin"
65 IA64_AT="jre-${MY_PV}-linux-ia64.bin"
66
67 DESCRIPTION="Oracle's Java SE Runtime Environment"
68 HOMEPAGE="http://www.oracle.com/technetwork/java/javase/"
69 SRC_URI="
70 amd64? ( ${AMD64_AT} )
71 x86? ( ${X86_AT} )"
72 # ia64? ( ${IA64_AT} )
73
74 LICENSE="Oracle-BCLA-JavaSE"
75 SLOT="1.6"
76 KEYWORDS="~amd64 ~x86"
77
78 IUSE="X alsa jce nsplugin pax_kernel"
79
80 RESTRICT="fetch strip"
81
82 RDEPEND="
83 X? (
84 x11-libs/libXext
85 x11-libs/libXi
86 x11-libs/libXrender
87 x11-libs/libXtst
88 x11-libs/libX11
89 )
90 alsa? ( media-libs/alsa-lib )
91 jce? ( dev-java/sun-jce-bin:1.6 )
92 !prefix? ( sys-libs/glibc )"
93 # scanelf won't create a PaX header, so depend on paxctl to avoid fallback
94 # marking. #427642
95 DEPEND="
96 pax_kernel? ( sys-apps/paxctl )"
97
98 S="${WORKDIR}/jre${S_PV}"
99
100 pkg_nofetch() {
101 if use x86; then
102 AT=${X86_AT}
103 elif use amd64; then
104 AT=${AMD64_AT}
105 elif use ia64; then
106 AT=${IA64_AT}
107 fi
108
109 einfo "Due to Oracle no longer providing the distro-friendly DLJ bundles, the package"
110 einfo "has become fetch restricted again. Alternatives are switching to"
111 einfo "dev-java/icedtea-bin:6 or the source-based dev-java/icedtea:6"
112 einfo ""
113 einfo "Please download ${AT} from:"
114 einfo "${JRE_URI}"
115 einfo "and move it to ${DISTDIR}"
116 }
117
118 src_unpack() {
119 sh "${DISTDIR}"/${A} -noregister || die "Failed to unpack"
120 }
121
122 src_compile() {
123 # This needs to be done before CDS - #215225
124 java-vm_set-pax-markings "${S}"
125
126 # see bug #207282
127 einfo "Creating the Class Data Sharing archives"
128 if use x86; then
129 bin/java -client -Xshare:dump || die
130 fi
131 # limit heap size for large memory on x86 #405239
132 # this is a workaround and shouldn't be needed.
133 bin/java -server -Xmx64m -Xshare:dump || die
134 }
135
136 src_install() {
137 local dest="/opt/${P}"
138 local ddest="${ED}${dest}"
139
140 # We should not need the ancient plugin for Firefox 2 anymore, plus it has
141 # writable executable segments
142 if use x86; then
143 rm -vf lib/i386/libjavaplugin_oji.so \
144 lib/i386/libjavaplugin_nscp*.so
145 rm -vrf plugin/i386
146 fi
147 # Without nsplugin flag, also remove the new plugin
148 local arch=${ARCH};
149 use x86 && arch=i386;
150 if ! use nsplugin; then
151 rm -vf lib/${arch}/libnpjp2.so \
152 lib/${arch}/libjavaplugin_jni.so
153 fi
154
155 dodir "${dest}"
156 cp -pPR bin lib man "${ddest}" || die
157
158 # Remove empty dirs we might have copied
159 find "${D}" -type d -empty -exec rmdir {} + || die
160
161 dodoc COPYRIGHT README
162
163 if use jce; then
164 dodir "${dest}"/lib/security/strong-jce
165 mv "${ddest}"/lib/security/US_export_policy.jar \
166 "${ddest}"/lib/security/strong-jce || die
167 mv "${ddest}"/lib/security/local_policy.jar \
168 "${ddest}"/lib/security/strong-jce || die
169 dosym /opt/sun-jce-bin-1.6.0/jre/lib/security/unlimited-jce/US_export_policy.jar \
170 "${dest}"/lib/security/US_export_policy.jar
171 dosym /opt/sun-jce-bin-1.6.0/jre/lib/security/unlimited-jce/local_policy.jar \
172 "${dest}"/lib/security/local_policy.jar
173 fi
174
175 if use nsplugin; then
176 install_mozilla_plugin "${dest}"/lib/${arch}/libnpjp2.so
177 fi
178
179 # Install desktop file for the Java Control Panel.
180 # Using ${PN}-${SLOT} to prevent file collision with jre and or other slots.
181 # make_desktop_entry can't be used as ${P} would end up in filename.
182 newicon lib/desktop/icons/hicolor/48x48/apps/sun-jcontrol.png \
183 sun-jcontrol-${PN}-${SLOT}.png || die
184 sed -e "s#Name=.*#Name=Java Control Panel for Oracle JDK ${SLOT} (${PN})#" \
185 -e "s#Exec=.*#Exec=${dest}/bin/jcontrol#" \
186 -e "s#Icon=.*#Icon=sun-jcontrol-${PN}-${SLOT}.png#" \
187 lib/desktop/applications/sun_java.desktop > \
188 "${T}"/jcontrol-${PN}-${SLOT}.desktop || die
189 domenu "${T}"/jcontrol-${PN}-${SLOT}.desktop
190
191 # http://docs.oracle.com/javase/6/docs/technotes/guides/intl/fontconfig.html
192 rm "${ddest}"/lib/fontconfig.* || die
193 cp "${FILESDIR}"/fontconfig.Gentoo.properties-r1 "${T}"/fontconfig.properties || die
194 eprefixify "${T}"/fontconfig.properties
195 insinto "${dest}"/lib/
196 doins "${T}"/fontconfig.properties
197
198 set_java_env "${FILESDIR}/${VMHANDLE}.env-r1"
199 java-vm_revdep-mask
200 }
201
202 QA_TEXTRELS_x86="
203 opt/${P}/lib/i386/client/libjvm.so
204 opt/${P}/lib/i386/motif21/libmawt.so
205 opt/${P}/lib/i386/server/libjvm.so"
206 QA_FLAGS_IGNORED="
207 /opt/${P}/bin/java
208 /opt/${P}/bin/java_vm
209 /opt/${P}/bin/javaws
210 /opt/${P}/bin/keytool
211 /opt/${P}/bin/orbd
212 /opt/${P}/bin/pack200
213 /opt/${P}/bin/policytool
214 /opt/${P}/bin/rmid
215 /opt/${P}/bin/rmiregistry
216 /opt/${P}/bin/servertool
217 /opt/${P}/bin/tnameserv
218 /opt/${P}/bin/unpack200
219 /opt/${P}/lib/jexec"
220 for java_system_arch in amd64 i386; do
221 QA_FLAGS_IGNORED+="
222 /opt/${P}/lib/${java_system_arch}/headless/libmawt.so
223 /opt/${P}/lib/${java_system_arch}/jli/libjli.so
224 /opt/${P}/lib/${java_system_arch}/libawt.so
225 /opt/${P}/lib/${java_system_arch}/libcmm.so
226 /opt/${P}/lib/${java_system_arch}/libdcpr.so
227 /opt/${P}/lib/${java_system_arch}/libdeploy.so
228 /opt/${P}/lib/${java_system_arch}/libdt_socket.so
229 /opt/${P}/lib/${java_system_arch}/libfontmanager.so
230 /opt/${P}/lib/${java_system_arch}/libhprof.so
231 /opt/${P}/lib/${java_system_arch}/libinstrument.so
232 /opt/${P}/lib/${java_system_arch}/libioser12.so
233 /opt/${P}/lib/${java_system_arch}/libj2gss.so
234 /opt/${P}/lib/${java_system_arch}/libj2pcsc.so
235 /opt/${P}/lib/${java_system_arch}/libj2pkcs11.so
236 /opt/${P}/lib/${java_system_arch}/libjaas_unix.so
237 /opt/${P}/lib/${java_system_arch}/libjava_crw_demo.so
238 /opt/${P}/lib/${java_system_arch}/libjavaplugin_jni.so
239 /opt/${P}/lib/${java_system_arch}/libjava.so
240 /opt/${P}/lib/${java_system_arch}/libjawt.so
241 /opt/${P}/lib/${java_system_arch}/libJdbcOdbc.so
242 /opt/${P}/lib/${java_system_arch}/libjdwp.so
243 /opt/${P}/lib/${java_system_arch}/libjpeg.so
244 /opt/${P}/lib/${java_system_arch}/libjsig.so
245 /opt/${P}/lib/${java_system_arch}/libjsoundalsa.so
246 /opt/${P}/lib/${java_system_arch}/libjsound.so
247 /opt/${P}/lib/${java_system_arch}/libmanagement.so
248 /opt/${P}/lib/${java_system_arch}/libmlib_image.so
249 /opt/${P}/lib/${java_system_arch}/libnative_chmod_g.so
250 /opt/${P}/lib/${java_system_arch}/libnative_chmod.so
251 /opt/${P}/lib/${java_system_arch}/libnet.so
252 /opt/${P}/lib/${java_system_arch}/libnio.so
253 /opt/${P}/lib/${java_system_arch}/libnpjp2.so
254 /opt/${P}/lib/${java_system_arch}/libnpt.so
255 /opt/${P}/lib/${java_system_arch}/librmi.so
256 /opt/${P}/lib/${java_system_arch}/libsplashscreen.so
257 /opt/${P}/lib/${java_system_arch}/libunpack.so
258 /opt/${P}/lib/${java_system_arch}/libverify.so
259 /opt/${P}/lib/${java_system_arch}/libzip.so
260 /opt/${P}/lib/${java_system_arch}/motif21/libmawt.so
261 /opt/${P}/lib/${java_system_arch}/native_threads/libhpi.so
262 /opt/${P}/lib/${java_system_arch}/server/libjvm.so
263 /opt/${P}/lib/${java_system_arch}/xawt/libmawt.so"
264 done
Report Message
Find on MARC Find on Google Groups