[gentoo-commits] gentoo-x86 commit in net-libs/gnutls: ChangeLog gnutls-2.3.11.ebuild gnutls-2.2.2.ebuild gnutls-2.2.3.ebuild

[Daniel Black (dragonheart)]

dragonheart    08/06/01 05:11:12

  Modified:             ChangeLog
  Added:                gnutls-2.3.11.ebuild
  Removed:              gnutls-2.2.2.ebuild gnutls-2.2.3.ebuild
  Log:
  version bump + old version cleanout
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.155                net-libs/gnutls/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.155&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.155&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/gnutls/ChangeLog?r1=1.154&r2=1.155

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v
retrieving revision 1.154
retrieving revision 1.155
diff -u -r1.154 -r1.155
--- ChangeLog	21 May 2008 16:17:21 -0000	1.154
+++ ChangeLog	1 Jun 2008 05:11:12 -0000	1.155
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/gnutls
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.154 2008/05/21 16:17:21 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.155 2008/06/01 05:11:12 dragonheart Exp $
+
+*gnutls-2.3.11 (01 Jun 2008)
+
+  01 Jun 2008; Daniel Black <dragonheart@g.o> -gnutls-2.2.2.ebuild,
+  -gnutls-2.2.3.ebuild, +gnutls-2.3.11.ebuild:
+  version bump _ old version cleanout
 
   21 May 2008; Tobias Scherbaum <dertobi123@g.o> gnutls-2.2.5.ebuild:
   ppc stable, bug #222823



1.1                  net-libs/gnutls/gnutls-2.3.11.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/gnutls/gnutls-2.3.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/gnutls/gnutls-2.3.11.ebuild?rev=1.1&content-type=text/plain

Index: gnutls-2.3.11.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-2.3.11.ebuild,v 1.1 2008/06/01 05:11:12 dragonheart Exp $

inherit libtool autotools eutils

DESCRIPTION="A TLS 1.0 and SSL 3.0 implementation for the GNU project"
HOMEPAGE="http://www.gnutls.org/"
SRC_URI="http://www.gnu.org/software/gnutls/releases/${P}.tar.bz2"
#SRC_URI="mirror://gnu/gnutls/${P}.tar.bz2"

# GPL-3 for the gnutls-extras library and LGPL for the gnutls library.
LICENSE="LGPL-2.1 GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="zlib lzo doc nls guile bindist"

RDEPEND="dev-libs/libgpg-error
	>=dev-libs/libgcrypt-1.2.4
	>=dev-libs/libtasn1-0.3.4
	>=app-crypt/opencdk-0.6.4
	nls? ( virtual/libintl )
	guile? ( dev-scheme/guile )
	zlib? ( >=sys-libs/zlib-1.1 )
	!bindist? ( lzo? ( >=dev-libs/lzo-2 ) )"
DEPEND="${RDEPEND}
	sys-devel/libtool
	doc? ( dev-util/gtk-doc )
	nls? ( sys-devel/gettext )"

pkg_setup() {
	if use guile && ! built_with_use dev-scheme/guile networking; then
		eerror "You are trying to compile ${PN} package with USE=\"guile\""
		eerror "while dev-scheme/guile does not have USE=\"networking\""
		die
	fi
	if use lzo && use bindist; then
		ewarn "lzo support was disabled for binary distribution of gnutls"
		ewarn "due to licensing issues. See Bug 202381 for details."
		epause 5
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	elibtoolize # for sane .so versioning on FreeBSD
}

src_compile() {
	local myconf
	use bindist && myconf="--without-lzo" || myconf="$(use_with lzo)"
	econf  \
		--without-included-opencdk \
		$(use_with zlib) \
		$(use_enable nls) \
		$(use_enable guile) \
		$(use_enable doc gtk-doc) \
		${myconf}
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS ChangeLog NEWS \
		README THANKS doc/TODO

	if use doc ; then
		dodoc doc/README.autoconf doc/tex/gnutls.ps
		docinto examples
		dodoc doc/examples/*.c
	fi
}



-- 
gentoo-commits@l.g.o mailing list