[gentoo-commits] repo/gentoo:master commit in: dev-libs/libixion/

[Andreas Sturmlechner]

commit:     8e91432b94ebae639bffc6a160d4484c24f7ea7f
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 12 18:46:23 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Sep 12 20:56:22 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e91432b

dev-libs/libixion: 0.14.0 version bump without keywords

Package-Manager: Portage-2.3.49, Repoman-2.3.10

 dev-libs/libixion/Manifest               |  1 +
 dev-libs/libixion/libixion-0.14.0.ebuild | 55 ++++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/dev-libs/libixion/Manifest b/dev-libs/libixion/Manifest
index ee889944a60..b6136b93579 100644
--- a/dev-libs/libixion/Manifest
+++ b/dev-libs/libixion/Manifest
@@ -1 +1,2 @@
 DIST libixion-0.13.0.tar.xz 413756 BLAKE2B 04aef61a1cc691bb159d7e8131e2e47fe2590634adc93f2e5771ed106316eb1c92ee7c4aa05ba753a1751cb5e7c55cba9263515671a26f9bc9983a1cfcacceff SHA512 15784e947164d106e677c59ece53b3cd401d4f9433cc5331a35d3be8332ae4f20a469ca73b30b253433c86da4afde886dfb4ac23e46ed46376a7349e0276c3a0
+DIST libixion-0.14.0.tar.xz 427100 BLAKE2B 8f766a61d2dab2c1cd40fbd72bb3d0cad2dda1a9d4617f1bc5289237b29e8b4edab333819b3ca61dfbd9a9b22b2e5a956d5c12b0a9eab8f794cbd87a20237b4e SHA512 8681912fb1bebb4de1fdcb4f0589aa84a3e38cd21747c81a204a87594f67879732461f3c02b70d0bf5659af59c1af1fa17df425eba5946d22a8599bc8da9fd92

diff --git a/dev-libs/libixion/libixion-0.14.0.ebuild b/dev-libs/libixion/libixion-0.14.0.ebuild
new file mode 100644
index 00000000000..51e6e3935b8
--- /dev/null
+++ b/dev-libs/libixion/libixion-0.14.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
+
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+
+[[ ${PV} == 9999 ]] && GITECLASS="git-r3 autotools"
+inherit python-single-r1 ${GITECLASS}
+unset GITECLASS
+
+DESCRIPTION="General purpose formula parser & interpreter"
+HOMEPAGE="https://gitlab.com/ixion/ixion"
+[[ ${PV} == 9999 ]] || SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/0.14" # based on SONAME of libixion.so
+[[ ${PV} == 9999 ]] || \
+KEYWORDS=""
+# KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="debug python static-libs +threads"
+
+RDEPEND="
+	dev-libs/boost:=
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/mdds-1.4.1:1=
+"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable python) \
+		$(use_enable static-libs static) \
+		$(use_enable threads)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}