[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.7.0_pre2-r1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    09/09/04 13:05:24

  Modified:             ChangeLog
  Added:                mc-4.7.0_pre2-r1.ebuild
  Log:
  Fix wrong charset dialog placement. http://www.midnight-commander.org/ticket/1451.
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.166                app-misc/mc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.166&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.166&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?r1=1.165&r2=1.166

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v
retrieving revision 1.165
retrieving revision 1.166
diff -u -r1.165 -r1.166
--- ChangeLog	1 Sep 2009 14:43:46 -0000	1.165
+++ ChangeLog	4 Sep 2009 13:05:24 -0000	1.166
@@ -1,6 +1,13 @@
 # ChangeLog for app-misc/mc
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.165 2009/09/01 14:43:46 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.166 2009/09/04 13:05:24 ssuominen Exp $
+
+*mc-4.7.0_pre2-r1 (04 Sep 2009)
+
+  04 Sep 2009; Samuli Suominen <ssuominen@g.o>
+  +mc-4.7.0_pre2-r1.ebuild, +files/mc-4.7.0_pre2-horizontal_split.patch:
+  Fix wrong charset dialog placement.
+  http://www.midnight-commander.org/ticket/1451.
 
   01 Sep 2009; Jeroen Roovers <jer@g.o> mc-4.7.0_pre1.ebuild:
   Stable for HPPA (bug #281667).



1.1                  app-misc/mc/mc-4.7.0_pre2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0_pre2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0_pre2-r1.ebuild?rev=1.1&content-type=text/plain

Index: mc-4.7.0_pre2-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.7.0_pre2-r1.ebuild,v 1.1 2009/09/04 13:05:24 ssuominen Exp $

EAPI=2
MY_P=${P/_/-}
inherit eutils

DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="http://www.midnight-commander.org"
SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="chdir +edit gpm nls samba slang X"

RDEPEND=">=dev-libs/glib-2.6:2
	gpm? ( sys-libs/gpm )
	kernel_linux? ( sys-fs/e2fsprogs )
	samba? ( net-fs/samba )
	slang? ( >=sys-libs/slang-2 )
	!slang? ( sys-libs/ncurses )
	X? ( x11-libs/libX11
		x11-libs/libICE
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libSM )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${P}-horizontal_split.patch
}

src_configure() {
	local myscreen=ncurses

	use slang && myscreen=slang

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-vfs \
		$(use_enable kernel_linux vfs-undelfs) \
		--enable-charset \
		$(use_with X x) \
		$(use_with samba) \
		--with-configdir=/etc/samba \
		--with-codepagedir=/var/lib/samba/codepages \
		$(use_with gpm gpm-mouse) \
		--with-screen=${myscreen} \
		$(use_with edit)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS NEWS README

	if use chdir; then
		insinto /etc/profile.d
		doins "${FILESDIR}"/mc-chdir.sh
	fi
}