[gentoo-commits] gentoo-x86 commit in media-gfx/rawtherapee: ChangeLog rawtherapee-4.0.11.ebuild

[Tim Harder (radhermit)]

radhermit    13/06/05 09:12:19

  Modified:             ChangeLog
  Added:                rawtherapee-4.0.11.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.14                 media-gfx/rawtherapee/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/rawtherapee/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/rawtherapee/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/rawtherapee/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/rawtherapee/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	30 Apr 2013 21:15:18 -0000	1.13
+++ ChangeLog	5 Jun 2013 09:12:19 -0000	1.14
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/rawtherapee
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/rawtherapee/ChangeLog,v 1.13 2013/04/30 21:15:18 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/rawtherapee/ChangeLog,v 1.14 2013/06/05 09:12:19 radhermit Exp $
+
+*rawtherapee-4.0.11 (05 Jun 2013)
+
+  05 Jun 2013; Tim Harder <radhermit@g.o> +rawtherapee-4.0.11.ebuild:
+  Version bump.
 
   30 Apr 2013; Tim Harder <radhermit@g.o> rawtherapee-4.0.10.ebuild:
   Fix libcanberra dep to require gtk support (bug #467904).



1.1                  media-gfx/rawtherapee/rawtherapee-4.0.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/rawtherapee/rawtherapee-4.0.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/rawtherapee/rawtherapee-4.0.11.ebuild?rev=1.1&content-type=text/plain

Index: rawtherapee-4.0.11.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/rawtherapee/rawtherapee-4.0.11.ebuild,v 1.1 2013/06/05 09:12:19 radhermit Exp $

EAPI=5

inherit cmake-utils toolchain-funcs

DESCRIPTION="A powerful cross-platform raw image processing program"
HOMEPAGE="http://www.rawtherapee.com/"
SRC_URI="http://rawtherapee.googlecode.com/files/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bzip2 doc openmp"

RDEPEND="bzip2? ( app-arch/bzip2 )
	>=dev-cpp/gtkmm-2.12:2.4
	>=dev-cpp/glibmm-2.16:2
	dev-libs/expat
	dev-libs/libsigc++:2
	media-libs/libcanberra[gtk]
	media-libs/tiff
	media-libs/libpng
	media-libs/libiptcdata
	media-libs/lcms:2
	sci-libs/fftw:3.0
	sys-libs/zlib
	virtual/jpeg"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	virtual/pkgconfig"

pkg_pretend() {
	if use openmp ; then
		tc-has-openmp || die "Please switch to an openmp compatible compiler"
	fi
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use openmp OPTION_OMP)
		$(cmake-utils_use_with bzip2 BZIP)
		-DDOCDIR=/usr/share/doc/${PF}
		-DCREDITSDIR=/usr/share/${PN}
		-DLICENCEDIR=/usr/share/${PN}
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	use doc && dodoc doc/RawTherapeeManual_en.pdf
}