[gentoo-commits] gentoo-x86 commit in dev-libs/openct: ChangeLog openct-0.6.18.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    09/09/26 19:42:09

  Modified:             ChangeLog
  Added:                openct-0.6.18.ebuild
  Log:
  Version bump.
  (Portage version: 14440-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.80                 dev-libs/openct/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/openct/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/openct/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/openct/ChangeLog?r1=1.79&r2=1.80

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog	23 Sep 2009 17:11:33 -0000	1.79
+++ ChangeLog	26 Sep 2009 19:42:09 -0000	1.80
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/openct
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v 1.79 2009/09/23 17:11:33 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v 1.80 2009/09/26 19:42:09 arfrever Exp $
+
+*openct-0.6.18 (26 Sep 2009)
+
+  26 Sep 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  +openct-0.6.18.ebuild:
+  Version bump.
 
   23 Sep 2009; Jeroen Roovers <jer@g.o> openct-0.6.17.ebuild:
   Stable for HPPA (bug #283061).



1.1                  dev-libs/openct/openct-0.6.18.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/openct/openct-0.6.18.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/openct/openct-0.6.18.ebuild?rev=1.1&content-type=text/plain

Index: openct-0.6.18.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/openct-0.6.18.ebuild,v 1.1 2009/09/26 19:42:09 arfrever Exp $

EAPI="2"

inherit eutils

DESCRIPTION="library for accessing smart card terminals"
HOMEPAGE="http://www.opensc-project.org/openct/"

SRC_URI="http://www.opensc-project.org/files/${PN}/${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"

LICENSE="LGPL-2.1"
SLOT="0"
IUSE="doc pcsc-lite usb"

RDEPEND="pcsc-lite? ( sys-apps/pcsc-lite )
		usb? ( virtual/libusb:0 )
		>=sys-fs/udev-096"

DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

pkg_setup() {
	enewgroup openct
	enewuser openctd
}

src_configure() {
	econf \
		--docdir="/usr/share/doc/${PF}" \
		--htmldir="/usr/share/doc/${PF}/html" \
		--localstatedir=/var \
		--with-udev="/$(get_libdir)/udev" \
		--enable-non-privileged \
		--with-daemon-user=openctd \
		--with-daemon-groups=usb \
		$(use_enable doc) \
		$(use_enable doc api-doc) \
		$(use_enable pcsc-lite pcsc) \
		$(use_enable usb)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	insinto /etc/udev/rules.d/
	newins etc/openct.udev 70-openct.rules || die "newins 70-openct.rules failed"

	diropts -m0750 -gopenct -oopenctd
	keepdir /var/run/openct

	newinitd "${FILESDIR}"/openct.rc openct
}

pkg_postinst() {
	elog
	elog "You need to edit /etc/openct.conf to enable serial readers."
	elog
	elog "You should add \"openct\" to your default runlevel. To do so"
	elog "type \"rc-update add openct default\"."
	elog
	elog "You need to be a member of the (newly created) group openct to"
	elog "access smart card readers connected to this system. Set users'"
	elog "groups with usermod -G.  root always has access."
	elog
}