[gentoo-commits] gentoo-x86 commit in net-ftp/filezilla: filezilla-3.10.1.1.ebuild ChangeLog

[Bernard Cafarelli (voyageur)]

voyageur    15/02/03 00:08:59

  Modified:             ChangeLog
  Added:                filezilla-3.10.1.1.ebuild
  Log:
  Version bump, bug #538530
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

Revision  Changes    Path
1.120                net-ftp/filezilla/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/filezilla/ChangeLog?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/filezilla/ChangeLog?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/filezilla/ChangeLog?r1=1.119&r2=1.120

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-ftp/filezilla/ChangeLog,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- ChangeLog	20 Oct 2014 08:54:22 -0000	1.119
+++ ChangeLog	3 Feb 2015 00:08:59 -0000	1.120
@@ -1,6 +1,12 @@
 # ChangeLog for net-ftp/filezilla
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/filezilla/ChangeLog,v 1.119 2014/10/20 08:54:22 voyageur Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/filezilla/ChangeLog,v 1.120 2015/02/03 00:08:59 voyageur Exp $
+
+*filezilla-3.10.1.1 (02 Feb 2015)
+
+  02 Feb 2015; Bernard Cafarelli <voyageur@g.o>
+  +filezilla-3.10.1.1.ebuild:
+  Version bump, bug #538530
 
 *filezilla-3.9.0.6 (20 Oct 2014)
 



1.1                  net-ftp/filezilla/filezilla-3.10.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/filezilla/filezilla-3.10.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/filezilla/filezilla-3.10.1.1.ebuild?rev=1.1&content-type=text/plain

Index: filezilla-3.10.1.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-ftp/filezilla/filezilla-3.10.1.1.ebuild,v 1.1 2015/02/03 00:08:59 voyageur Exp $

EAPI=5

WX_GTK_VER="3.0"

inherit autotools eutils flag-o-matic multilib wxwidgets

MY_PV=${PV/_/-}
MY_P="FileZilla_${MY_PV}"

DESCRIPTION="FTP client with lots of useful features and an intuitive interface"
HOMEPAGE="http://filezilla-project.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}_src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~x86-macos"
IUSE="aqua dbus nls test"

RDEPEND=">=app-admin/eselect-wxwidgets-0.7-r1
	>=dev-db/sqlite-3.7
	>=dev-libs/tinyxml-2.6.1-r1[stl]
	net-dns/libidn
	>=net-libs/gnutls-3.1.12
	aqua? ( >=x11-libs/wxGTK-3.0.2.0-r1:3.0[aqua] )
	!aqua? ( >=x11-libs/wxGTK-3.0.2.0-r1:3.0[X] x11-misc/xdg-utils )
	dbus? ( sys-apps/dbus )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	>=sys-devel/libtool-1.4
	nls? ( >=sys-devel/gettext-0.11 )
	test? ( dev-util/cppunit )"

S="${WORKDIR}"/${PN}-${MY_PV}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.7.4-debug.patch
	append-cppflags -DTIXML_USE_STL
	eautoreconf
}

src_configure() {
	econf $(use_with dbus) $(use_enable nls locales) \
		--with-tinyxml=system \
		--disable-autoupdatecheck
}

src_install() {
	emake DESTDIR="${D}" install

	doicon src/interface/resources/48x48/${PN}.png

	dodoc AUTHORS ChangeLog NEWS

	if use aqua ; then
		cat > "${T}/${PN}" <<-EOF
			#!${EPREFIX}/bin/bash
			open "${EPREFIX}"/Applications/FileZilla.app
		EOF
		rm "${ED}/usr/bin/${PN}" || die
		dobin "${T}/${PN}"
		insinto /Applications
		doins -r "${S}"/FileZilla.app
	fi
}