[gentoo-commits] gentoo-x86 commit in app-text/xdvik: ChangeLog xdvik-22.84.16.ebuild

[Alexis Ballier (aballier)]

aballier    09/10/03 09:32:31

  Modified:             ChangeLog
  Added:                xdvik-22.84.16.ebuild
  Log:
  version bump, drop cjk patches they cause more harm than good
  (Portage version: 2.2_rc42/cvs/Linux x86_64)

Revision  Changes    Path
1.64                 app-text/xdvik/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xdvik/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xdvik/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xdvik/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/xdvik/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	8 Feb 2009 11:07:00 -0000	1.63
+++ ChangeLog	3 Oct 2009 09:32:30 -0000	1.64
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/xdvik
-# Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/xdvik/ChangeLog,v 1.63 2009/02/08 11:07:00 aballier Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/xdvik/ChangeLog,v 1.64 2009/10/03 09:32:30 aballier Exp $
+
+*xdvik-22.84.16 (03 Oct 2009)
+
+  03 Oct 2009; Alexis Ballier <aballier@g.o> +xdvik-22.84.16.ebuild,
+  +files/xdvik-22.84.16-open-mode.patch:
+  version bump, drop cjk patches they cause more harm than good
 
 *xdvik-22.84.14-r1 (08 Feb 2009)
 



1.1                  app-text/xdvik/xdvik-22.84.16.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xdvik/xdvik-22.84.16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xdvik/xdvik-22.84.16.ebuild?rev=1.1&content-type=text/plain

Index: xdvik-22.84.16.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/xdvik/xdvik-22.84.16.ebuild,v 1.1 2009/10/03 09:32:30 aballier Exp $

inherit eutils flag-o-matic elisp-common toolchain-funcs

DESCRIPTION="DVI previewer for X Window System"
HOMEPAGE="http://xdvi.sourceforge.net/"
SRC_URI="mirror://sourceforge/xdvi/${P}.tar.gz"

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
SLOT="0"
LICENSE="GPL-2"
IUSE="motif neXt Xaw3d emacs"

RDEPEND=">=media-libs/t1lib-5.0.2
	x11-libs/libXmu
	x11-libs/libXp
	x11-libs/libXpm
	motif? ( x11-libs/openmotif )
	!motif? ( neXt? ( x11-libs/neXtaw )
		!neXt? ( Xaw3d? ( x11-libs/Xaw3d ) ) )
	virtual/latex-base
	!<app-text/texlive-2007"
DEPEND="${RDEPEND}"
TEXMF_PATH=/usr/share/texmf
S=${WORKDIR}/${P}/texk/xdvik

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-open-mode.patch"
}

src_compile() {
	cd "${WORKDIR}/${P}"

	tc-export CC AR RANLIB

	local toolkit

	if use motif ; then
		toolkit="motif"
	elif use neXt ; then
		toolkit="neXtaw"
	elif use Xaw3d ; then
		toolkit="xaw3d"
	else
		toolkit="xaw"
	fi

	econf --disable-multiplatform \
		--enable-t1lib \
		--enable-gf \
		--with-system-t1lib \
		--with-system-kpathsea \
		--with-kpathsea-include=/usr/include/kpathsea \
		--with-xdvi-x-toolkit="${toolkit}"

	cd "${S}"
	emake kpathsea_dir="/usr/include/kpathsea" texmf="${TEXMF_PATH}" || die
	use emacs && elisp-compile xdvi-search.el
}

src_install() {
	einstall kpathsea_dir="/usr/include/kpathsea" texmf="${D}${TEXMF_PATH}" || die "install failed"

	dodir /etc/texmf/xdvi /etc/X11/app-defaults
	mv "${D}${TEXMF_PATH}/xdvi/XDvi" "${D}etc/X11/app-defaults" || die "failed to move config file"
	dosym {/etc/X11/app-defaults,"${TEXMF_PATH}/xdvi"}/XDvi || die "failed to symlink config file"
	for i in $(find "${D}${TEXMF_PATH}/xdvi" -type f -maxdepth 1) ; do
		mv ${i} "${D}etc/texmf/xdvi" || die "failed to move $i"
		dosym {/etc/texmf,"${TEXMF_PATH}"}/xdvi/$(basename ${i}) || die "failed	to symlink $i"
	done

	dodoc BUGS FAQ README.* || die "dodoc failed"

	use emacs && elisp-install tex-utils *.el *.elc

	doicon "${FILESDIR}/${PN}.png"
	make_desktop_entry xdvi "XDVI" xdvik "Graphics;Viewer"
	echo "MimeType=application/x-dvi;" >> "${D}"usr/share/applications/xdvi-"${PN}".desktop
}

pkg_postinst() {
	if use emacs; then
		elog "Add"
		elog "	(add-to-list 'load-path \"${SITELISP}/tex-utils\")"
		elog "	(require 'xdvi-search)"
		elog "to your ~/.emacs file"
	fi
}