[gentoo-commits] gentoo-x86 commit in www-client/chromium-bin: ChangeLog chromium-bin-9999.ebuild chromium-bin-0_p20951.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    09/07/17 15:37:55

  Modified:             ChangeLog chromium-bin-9999.ebuild
  Added:                chromium-bin-0_p20951.ebuild
  Log:
  Version bump, more options and video/audio HTML5 tags support
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.15                 www-client/chromium-bin/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium-bin/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium-bin/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium-bin/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium-bin/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	10 Jul 2009 17:13:12 -0000	1.14
+++ ChangeLog	17 Jul 2009 15:37:55 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/chromium-bin
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium-bin/ChangeLog,v 1.14 2009/07/10 17:13:12 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium-bin/ChangeLog,v 1.15 2009/07/17 15:37:55 voyageur Exp $
+
+*chromium-bin-0_p20951 (17 Jul 2009)
+
+  17 Jul 2009; Bernard Cafarelli <voyageur@g.o>
+  +chromium-bin-0_p20951.ebuild, chromium-bin-9999.ebuild:
+  Version bump, more options and video/audio HTML5 tags support
 
 *chromium-bin-0_p20377 (10 Jul 2009)
 



1.12                 www-client/chromium-bin/chromium-bin-9999.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium-bin/chromium-bin-9999.ebuild?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium-bin/chromium-bin-9999.ebuild?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium-bin/chromium-bin-9999.ebuild?r1=1.11&r2=1.12

Index: chromium-bin-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium-bin/chromium-bin-9999.ebuild,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- chromium-bin-9999.ebuild	30 Jun 2009 11:40:28 -0000	1.11
+++ chromium-bin-9999.ebuild	17 Jul 2009 15:37:55 -0000	1.12
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium-bin/chromium-bin-9999.ebuild,v 1.11 2009/06/30 11:40:28 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium-bin/chromium-bin-9999.ebuild,v 1.12 2009/07/17 15:37:55 voyageur Exp $
 
 EAPI="2"
 inherit eutils multilib
@@ -35,6 +35,14 @@
 
 QA_EXECSTACK="opt/chromium.org/chrome-linux/chrome"
 
+# Ogg/Theora/Vorbis-only FFmpeg binaries
+QA_TEXTRELS="opt/chromium.org/chrome-linux/libavcodec.so.52
+	opt/chromium.org/chrome-linux/libavformat.so.52
+	opt/chromium.org/chrome-linux/libavutil.so.50"
+QA_PRESTRIPPED="opt/chromium.org/chrome-linux/libavcodec.so.52
+	opt/chromium.org/chrome-linux/libavformat.so.52
+	opt/chromium.org/chrome-linux/libavutil.so.50"
+
 pkg_setup() {
 	# This is a binary x86 package
 	has_multilib_profile && ABI="x86"
@@ -91,7 +99,7 @@
 	dosym ${NSS_DIR}/libssl3.so ${CHROMIUM_HOME}/lib/libssl3.so.1d
 
 	# Create chromium-bin wrapper
-	make_wrapper chromium-bin ./chrome ${CHROMIUM_HOME}/chrome-linux ${CHROMIUM_HOME}/lib
+	make_wrapper chromium-bin ./chrome ${CHROMIUM_HOME}/chrome-linux ${CHROMIUM_HOME}/lib:${CHROMIUM_HOME}/chrome-linux
 	newicon "${FILESDIR}"/chromium.png ${PN}.png
 	make_desktop_entry chromium-bin "Chromium" ${PN}.png "Network;WebBrowser"
 }



1.1                  www-client/chromium-bin/chromium-bin-0_p20951.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium-bin/chromium-bin-0_p20951.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium-bin/chromium-bin-0_p20951.ebuild?rev=1.1&content-type=text/plain

Index: chromium-bin-0_p20951.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium-bin/chromium-bin-0_p20951.ebuild,v 1.1 2009/07/17 15:37:55 voyageur Exp $

EAPI="2"
inherit eutils multilib

# Latest revision id can be found at
# http://build.chromium.org/buildbot/snapshots/chromium-rel-linux/LATEST
MY_PV="${PV/0\_p}"

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://code.google.com/chromium/"
SRC_URI="http://build.chromium.org/buildbot/snapshots/chromium-rel-linux/${MY_PV}/chrome-linux.zip -> ${PN}-${MY_PV}.zip"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~x86"
IUSE=""

AMD64_DEPEND="amd64? (
	|| ( www-plugins/adobe-flash[32bit]
		www-client/mozilla-firefox-bin
		net-libs/xulrunner-bin )
	>=app-emulation/emul-linux-x86-gtklibs-20081109
	app-emulation/emul-linux-x86-soundlibs
	)"

DEPEND="app-arch/unzip
	${AMD64_DEPEND}"
RDEPEND="media-fonts/corefonts
	>=sys-devel/gcc-4.2
	x86? ( >=dev-libs/nspr-4.7
		>=dev-libs/nss-3.12
		gnome-base/gconf
		x11-libs/pango )
	${AMD64_DEPEND}"

S=${WORKDIR}

QA_EXECSTACK="opt/chromium.org/chrome-linux/chrome"

# Ogg/Theora/Vorbis-only FFmpeg binaries
QA_TEXTRELS="opt/chromium.org/chrome-linux/libavcodec.so.52
	opt/chromium.org/chrome-linux/libavformat.so.52
	opt/chromium.org/chrome-linux/libavutil.so.50"
QA_PRESTRIPPED="opt/chromium.org/chrome-linux/libavcodec.so.52
	opt/chromium.org/chrome-linux/libavformat.so.52
	opt/chromium.org/chrome-linux/libavutil.so.50"

pkg_setup() {
	# This is a binary x86 package
	has_multilib_profile && ABI="x86"
}

src_install() {
	declare CHROMIUM_HOME=/opt/chromium.org

	dodir ${CHROMIUM_HOME}
	cp -R chrome-linux/ "${D}"${CHROMIUM_HOME} || die "Unable to install chrome-linux folder"

	# Plugins symlink
	dosym /usr/$(get_libdir)/nsbrowser/plugins ${CHROMIUM_HOME}/chrome-linux/plugins

	# Create symlinks for needed libraries
	dodir ${CHROMIUM_HOME}/lib
	if use x86; then
		NSS_DIR=../../../usr/$(get_libdir)/nss
		NSPR_DIR=../../../usr/$(get_libdir)/nspr
	elif use amd64; then
		# amd64: we still miss gconf
		if has_version www-client/mozilla-firefox-bin; then
			einfo "Using NSS/NSPR libraries from www-client/mozilla-firefox-bin"
			NSS_DIR=../../../opt/firefox
			NSPR_DIR=../../../opt/firefox
		elif has_version net-libs/xulrunner-bin; then
			einfo "Using NSS/NSPR libraries from net-libs/xulrunner-bin"
			NSS_DIR=../../../opt/xulrunner
			NSPR_DIR=../../../opt/xulrunner
		elif has_version www-plugins/adobe-flash; then
			einfo "Using NSS/NSPR libraries from www-plugins/adobe-flash"
			NSS_DIR=../../../opt/flash-libcompat
			NSPR_DIR=../../../opt/flash-libcompat
		else
			die "One of these packages is needed: www-client/mozilla-firefox-bin, net-libs/xulrunner-bin, www-plugins/adobe-flash[32bit]"
		fi

	fi

	dosym ${NSPR_DIR}/libnspr4.so ${CHROMIUM_HOME}/lib/libnspr4.so.0d
	dosym ${NSPR_DIR}/libplc4.so ${CHROMIUM_HOME}/lib/libplc4.so.0d
	dosym ${NSPR_DIR}/libplds4.so ${CHROMIUM_HOME}/lib/libplds4.so.0d
	dosym ${NSS_DIR}/libnss3.so ${CHROMIUM_HOME}/lib/libnss3.so.1d
	dosym ${NSS_DIR}/libnssutil3.so ${CHROMIUM_HOME}/lib/libnssutil3.so.1d
	dosym ${NSS_DIR}/libsmime3.so ${CHROMIUM_HOME}/lib/libsmime3.so.1d
	dosym ${NSS_DIR}/libssl3.so ${CHROMIUM_HOME}/lib/libssl3.so.1d

	# Create chromium-bin wrapper
	make_wrapper chromium-bin ./chrome ${CHROMIUM_HOME}/chrome-linux ${CHROMIUM_HOME}/lib:${CHROMIUM_HOME}/chrome-linux
	newicon "${FILESDIR}"/chromium.png ${PN}.png
	make_desktop_entry chromium-bin "Chromium" ${PN}.png "Network;WebBrowser"
}

pkg_postinst() {
	ewarn "This binary requires the C++ runtime from >=sys-devel/gcc-4.2"
	ewarn "If you get the \"version \`GLIBCXX_3.4.9' not found\" error message,"
	ewarn "switch your active gcc to a version >=4.2 with gcc-config"
}