[gentoo-commits] gentoo-x86 commit in www-apps/trac: trac-1.0.ebuild ChangeLog

[Dirkjan Ochtman (djc)]

djc         12/09/30 11:43:23

  Modified:             ChangeLog
  Added:                trac-1.0.ebuild
  Log:
  Version bump trac to 1.0 (bug 436026).
  
  (Portage version: 2.1.11.23/cvs/Linux x86_64)

Revision  Changes    Path
1.128                www-apps/trac/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/ChangeLog?rev=1.128&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/ChangeLog?rev=1.128&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/ChangeLog?r1=1.127&r2=1.128

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v
retrieving revision 1.127
retrieving revision 1.128
diff -u -r1.127 -r1.128
--- ChangeLog	2 Jul 2012 21:46:07 -0000	1.127
+++ ChangeLog	30 Sep 2012 11:43:23 -0000	1.128
@@ -1,6 +1,11 @@
 # ChangeLog for www-apps/trac
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.127 2012/07/02 21:46:07 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.128 2012/09/30 11:43:23 djc Exp $
+
+*trac-1.0 (30 Sep 2012)
+
+  30 Sep 2012; Dirkjan Ochtman <djc@g.o> +trac-1.0.ebuild:
+  Version bump to 1.0 (for bug 436026).
 
   02 Jul 2012; Johannes Huber <johu@g.o> trac-0.12.3.ebuild:
   Stable for x86, wrt bug #422241



1.1                  www-apps/trac/trac-1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/trac-1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/trac-1.0.ebuild?rev=1.1&content-type=text/plain

Index: trac-1.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/trac-1.0.ebuild,v 1.1 2012/09/30 11:43:23 djc Exp $

EAPI="4"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython"

inherit distutils user webapp

MY_PV=${PV/_beta/b}
MY_P=Trac-${MY_PV}

DESCRIPTION="Trac is a minimalistic web-based project management, wiki and bug/issue tracking system."
HOMEPAGE="http://trac.edgewall.com/ http://pypi.python.org/pypi/Trac"
SRC_URI="http://ftp.edgewall.com/pub/trac/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="cgi fastcgi i18n mysql postgres +sqlite subversion"
REQUIRED_USE="|| ( mysql postgres sqlite )"

RDEPEND="
	dev-python/setuptools
	dev-python/docutils
	dev-python/genshi
	dev-python/pygments
	dev-python/pytz
	i18n? ( >=dev-python/Babel-0.9.5 )
	cgi? ( virtual/httpd-cgi )
	fastcgi? ( virtual/httpd-fastcgi )
	mysql? ( dev-python/mysql-python )
	postgres? ( >=dev-python/psycopg-2 )
	sqlite? (
		>=dev-db/sqlite-3.3.4
		|| ( dev-lang/python:2.7[sqlite] dev-lang/python:2.6[sqlite] dev-lang/python:2.5[sqlite] >=dev-python/pysqlite-2.3.2 )
	)
	subversion? ( dev-vcs/subversion[python] )
	"
DEPEND="${RDEPEND}"

S="${WORKDIR}/${MY_P}"

WEBAPP_MANUAL_SLOT="yes"

pkg_setup() {
	python_pkg_setup
	webapp_pkg_setup

	enewgroup tracd
	enewuser tracd -1 -1 -1 tracd
}

src_test() {
	testing() {
		PYTHONPATH=. "$(PYTHON)" trac/test.py
	}
	python_execute_function testing

	if use i18n; then
		make check
	fi
}

# the default src_compile just calls setup.py build
# currently, this switches i18n catalog compilation based on presence of Babel

src_install() {
	webapp_src_preinst
	distutils_src_install

	# project environments might go in here
	keepdir /var/lib/trac

	# Use this as the egg-cache for tracd
	dodir /var/lib/trac/egg-cache
	keepdir /var/lib/trac/egg-cache
	fowners tracd:tracd /var/lib/trac/egg-cache

	# documentation
	dodoc -r contrib

	# tracd init script
	newconfd "${FILESDIR}"/tracd.confd tracd
	newinitd "${FILESDIR}"/tracd.initd tracd

	if use cgi; then
		cp cgi-bin/trac.cgi "${ED}${MY_CGIBINDIR}" || die
	fi
	if use fastcgi; then
		cp cgi-bin/trac.fcgi "${ED}${MY_CGIBINDIR}" || die
	fi

	for lang in en; do
		webapp_postinst_txt ${lang} "${FILESDIR}"/postinst-${lang}.txt
		webapp_postupgrade_txt ${lang} "${FILESDIR}"/postupgrade-${lang}.txt
	done

	webapp_src_install
}

pkg_postinst() {
	distutils_pkg_postinst
	webapp_pkg_postinst
}