[gentoo-commits] repo/gentoo:master commit in: app-misc/task/

[Sam James]

commit:     969dc791923bb646665807c09da907d68b0b3714
Author:     David Denoncin <ddenoncin <AT> gmail <DOT> com>
AuthorDate: Thu Nov 18 20:58:50 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Nov 22 09:27:21 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=969dc791

app-misc/task: add fish completions

Closes: https://bugs.gentoo.org/823978
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: David Denoncin <ddenoncin <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/22990
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-misc/task/task-2.6.1-r1.ebuild | 70 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)

diff --git a/app-misc/task/task-2.6.1-r1.ebuild b/app-misc/task/task-2.6.1-r1.ebuild
new file mode 100644
index 000000000000..d4f6942da292
--- /dev/null
+++ b/app-misc/task/task-2.6.1-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+inherit bash-completion-r1 cmake
+
+DESCRIPTION="Taskwarrior is a command-line todo list manager"
+HOMEPAGE="https://taskwarrior.org/"
+SRC_URI="https://github.com/GothenburgBitFactory/taskwarrior/releases/download/v${PV}/${P}.tar.gz
+	https://github.com/GothenburgBitFactory/taskwarrior/releases/download/v${PV}/tests-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
+IUSE="+sync"
+
+DEPEND="
+	sync? ( net-libs/gnutls )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# move test directory into source directory
+	mv "${WORKDIR}"/test "${WORKDIR}"/${P} || die
+
+	cmake_src_prepare
+
+	# don't automatically install scripts
+	sed -i '/scripts/d' CMakeLists.txt || die
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DENABLE_SYNC=$(usex sync)
+		-DTASK_DOCDIR=share/doc/${PF}
+		-DTASK_RCDIR=share/${PN}/rc
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${WORKDIR}"/"${P}"_build || die
+
+	emake test
+}
+
+src_install() {
+	cmake_src_install
+
+	newbashcomp scripts/bash/task.sh task
+
+	# vim syntax
+	rm scripts/vim/README || die
+	insinto /usr/share/vim/vimfiles
+	doins -r scripts/vim/*
+
+	# zsh-completions
+	insinto /usr/share/zsh/site-functions
+	doins scripts/zsh/*
+
+	# fish-completions
+	insinto /usr/share/fish/completions
+	doins scripts/fish/*
+
+	exeinto "/usr/share/${PN}/scripts"
+	doexe scripts/add-ons/*
+}