[gentoo-commits] gentoo-x86 commit in app-backup/dar: ChangeLog dar-2.4.2.ebuild

[Matsuu Takuto (matsuu)]

matsuu      11/12/04 01:11:23

  Modified:             ChangeLog
  Added:                dar-2.4.2.ebuild
  Log:
  Version bumped, bug #387501.
  
  (Portage version: 2.1.10.29/cvs/Linux x86_64)

Revision  Changes    Path
1.43                 app-backup/dar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/dar/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/dar/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/dar/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/dar/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	7 Jun 2011 23:34:19 -0000	1.42
+++ ChangeLog	4 Dec 2011 01:11:22 -0000	1.43
@@ -1,6 +1,11 @@
 # ChangeLog for app-backup/dar
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/dar/ChangeLog,v 1.42 2011/06/07 23:34:19 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/dar/ChangeLog,v 1.43 2011/12/04 01:11:22 matsuu Exp $
+
+*dar-2.4.2 (04 Dec 2011)
+
+  04 Dec 2011; MATSUU Takuto <matsuu@g.o> +dar-2.4.2.ebuild:
+  Version bumped, bug #387501.
 
 *dar-2.4.0 (07 Jun 2011)
 



1.1                  app-backup/dar/dar-2.4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/dar/dar-2.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/dar/dar-2.4.2.ebuild?rev=1.1&content-type=text/plain

Index: dar-2.4.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/dar/dar-2.4.2.ebuild,v 1.1 2011/12/04 01:11:22 matsuu Exp $

EAPI="3"
inherit confutils eutils flag-o-matic

DESCRIPTION="A full featured backup tool, aimed for disks (floppy,CDR(W),DVDR(W),zip,jazz etc.)"
HOMEPAGE="http://dar.linux.free.fr/"
SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="acl dar32 dar64 doc gcrypt lzo nls static static-libs"

RESTRICT="test" # need to be run as root

RDEPEND=">=sys-libs/zlib-1.2.3
	>=app-arch/bzip2-1.0.2
	acl? (
		static? ( sys-apps/attr[static-libs] )
		!static? ( sys-apps/attr )
	)
	gcrypt? ( dev-libs/libgcrypt )
	lzo? ( dev-libs/lzo )
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	doc? ( app-doc/doxygen )"

pkg_setup() {
	confutils_use_conflict dar32 dar64
}

src_configure() {
	local myconf="--disable-upx"

	# Bug 103741
	filter-flags -fomit-frame-pointer

	use acl || myconf="${myconf} --disable-ea-support"
	use dar32 && myconf="${myconf} --enable-mode=32"
	use dar64 && myconf="${myconf} --enable-mode=64"
	use doc || myconf="${myconf} --disable-build-html"
	# use examples && myconf="${myconf} --enable-examples"
	use gcrypt || myconf="${myconf} --disable-libgcrypt-linking"
	use lzo || myconf="${myconf} --disable-liblzo2-linking"
	use nls || myconf="${myconf} --disable-nls"
	if ! use static ; then
		myconf="${myconf} --disable-dar-static"
		if ! use static-libs ; then
			myconf="${myconf} --disable-static"
		fi
	fi

	econf ${myconf} || die
}

src_install() {
	emake DESTDIR="${D}" pkgdatadir=/usr/share/doc/${PF}/html install || die

	if ! use static-libs ; then
		find "${ED}" "(" -name '*.la' -o -name '*.a' ")" -delete || die
	fi

	dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die
}