[gentoo-commits] repo/gentoo:master commit in: dev-python/statsmodels/

[Michał Górny]

commit:     07ae2d168a809cfd0be5475abf0e3b2b64484005
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  2 06:35:19 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Oct  2 07:50:42 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=07ae2d16

dev-python/statsmodels: Bump to 0.13.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/statsmodels/Manifest                  |  1 +
 dev-python/statsmodels/statsmodels-0.13.0.ebuild | 83 ++++++++++++++++++++++++
 2 files changed, 84 insertions(+)

diff --git a/dev-python/statsmodels/Manifest b/dev-python/statsmodels/Manifest
index 771b9aa85bf..97632e523cd 100644
--- a/dev-python/statsmodels/Manifest
+++ b/dev-python/statsmodels/Manifest
@@ -1 +1,2 @@
 DIST statsmodels-0.12.2.tar.gz 17470078 BLAKE2B 7b2a17fe350489888fd05d2275b597ec7cb0f32dcea97daa5c06a973fa53a7b3af40d494c735e30cd65deec9b5dd314c0513454a7c2d2c40e22fd6de3aeb40c8 SHA512 ae4872bc7300ef564407daa8b4076fd70fc180965622ed2173871579e063e2143e000540089923fe171dbb191b7dd872077d8ba6794fe23390331375ec7ce810
+DIST statsmodels-0.13.0.tar.gz 17766215 BLAKE2B 54894a1061bbd90154ea81d599c913119a90f89dd37055f3e6c69b23bc265a424c08a2e5cb2c88edc9a3a82fd69a236e6eaf73c08a8201c31b1cdc5cc9ea0bd5 SHA512 829e927d146f6587ef545c2a5668d9ba60e1493eb0deb79754029128d419a6811ace17572e3c324d738a1a36e69b8b85d92030b187c85fa5be49003806ba6145

diff --git a/dev-python/statsmodels/statsmodels-0.13.0.ebuild b/dev-python/statsmodels/statsmodels-0.13.0.ebuild
new file mode 100644
index 00000000000..4aa7914a265
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.13.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="https://www.statsmodels.org/stable/index.html"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+DEPEND="
+	>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.3[${PYTHON_USEDEP}]"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.25[${PYTHON_USEDEP}]
+	>=dev-python/patsy-0.5.2[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${DEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/ipykernel' \
+	'dev-python/jupyter_client' \
+	'dev-python/matplotlib' \
+	'dev-python/nbconvert' \
+	'dev-python/numpydoc'
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	sed -e 's:test_combine:_&:' \
+		-i statsmodels/imputation/tests/test_mice.py || die
+	sed -e 's:test_mixedlm:_&:' \
+		-i statsmodels/stats/tests/test_mediation.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x MKL_NUM_THREADS=1
+	local -x OMP_NUM_THREADS=1
+	local jobs=$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")
+
+	pushd "${BUILD_DIR}" >/dev/null || die
+	"${EPYTHON}" -c "
+import statsmodels
+statsmodels.test(extra_args=['-vv', '-n', '${jobs}'], exit=True)" \
+		|| die "tests fail with ${EPYTHON}"
+	popd >/dev/null || die
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}