[gentoo-commits] gentoo-x86 commit in dev-db/mongodb: ChangeLog mongodb-2.6.1-r1.ebuild mongodb-2.6.1.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    14/05/26 08:03:45

  Modified:             ChangeLog
  Added:                mongodb-2.6.1-r1.ebuild
  Removed:              mongodb-2.6.1.ebuild
  Log:
  fix init script user and group execution
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

Revision  Changes    Path
1.92                 dev-db/mongodb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?rev=1.92&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?rev=1.92&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?r1=1.91&r2=1.92

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v
retrieving revision 1.91
retrieving revision 1.92
diff -u -r1.91 -r1.92
--- ChangeLog	14 May 2014 09:16:49 -0000	1.91
+++ ChangeLog	26 May 2014 08:03:45 -0000	1.92
@@ -1,6 +1,13 @@
 # ChangeLog for dev-db/mongodb
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v 1.91 2014/05/14 09:16:49 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v 1.92 2014/05/26 08:03:45 ultrabug Exp $
+
+*mongodb-2.6.1-r1 (26 May 2014)
+
+  26 May 2014; Ultrabug <ultrabug@g.o> -mongodb-2.6.1.ebuild,
+  +mongodb-2.6.1-r1.ebuild, files/mms-agent.initd-r2, files/mongodb.initd-r2,
+  files/mongos.initd-r2:
+  fix init script user and group execution
 
 *mongodb-2.6.1 (14 May 2014)
 



1.1                  dev-db/mongodb/mongodb-2.6.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/mongodb-2.6.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/mongodb-2.6.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: mongodb-2.6.1-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/mongodb-2.6.1-r1.ebuild,v 1.1 2014/05/26 08:03:45 ultrabug Exp $

EAPI=5
SCONS_MIN_VERSION="1.2.0"
CHECKREQS_DISK_BUILD="2400M"
CHECKREQS_DISK_USR="512M"
CHECKREQS_MEMORY="1024M"

inherit eutils flag-o-matic multilib scons-utils systemd user versionator check-reqs

MY_P=${PN}-src-r${PV/_rc/-rc}

DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
HOMEPAGE="http://www.mongodb.org"
SRC_URI="http://downloads.mongodb.org/src/${MY_P}.tar.gz
	mms-agent? ( http://dev.gentoo.org/~ultrabug/20140409-mms-monitoring-agent.zip )"

LICENSE="AGPL-3 Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="kerberos mms-agent ssl static-libs"

PDEPEND="mms-agent? ( dev-python/pymongo app-arch/unzip )"
RDEPEND="
	app-arch/snappy
	>=dev-cpp/yaml-cpp-0.5.1
	>=dev-libs/boost-1.50[threads(+)]
	>=dev-libs/libpcre-8.30[cxx]
	dev-libs/snowball-stemmer
	dev-util/google-perftools[-minimal]
	net-libs/libpcap
	ssl? ( >=dev-libs/openssl-1.0.1g )"
DEPEND="${RDEPEND}
	sys-libs/ncurses
	sys-libs/readline
	kerberos? ( dev-libs/cyrus-sasl[kerberos] )"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	enewgroup mongodb
	enewuser mongodb -1 -1 /var/lib/${PN} mongodb

	scons_opts="--variant-dir=build --cc=$(tc-getCC) --cxx=$(tc-getCXX)"
	scons_opts+=" --use-system-boost"
	scons_opts+=" --use-system-pcre"
	scons_opts+=" --use-system-snappy"
	scons_opts+=" --use-system-stemmer"
	scons_opts+=" --use-system-tcmalloc"
	scons_opts+=" --use-system-yaml"
	scons_opts+=" --usev8"

	if use prefix; then
		scons_opts+=" --cpppath=${EPREFIX}/usr/include"
		scons_opts+=" --libpath=${EPREFIX}/usr/$(get_libdir)"
	fi

	if use kerberos; then
		scons_opts+=" --use-sasl-client"
	fi

	if use ssl; then
		scons_opts+=" --ssl"
	fi
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-2.6.1-fix-scons.patch"

	# fix yaml-cpp detection
	sed -i -e "s/\[\"yaml\"\]/\[\"yaml-cpp\"\]/" SConstruct || die

	# bug #462606
	sed -i -e "s@\$INSTALL_DIR/lib@\$INSTALL_DIR/$(get_libdir)@g" src/SConscript.client || die

	# bug #482576
	sed -i -e "/-Werror/d" src/third_party/v8/SConscript || die
}

src_compile() {
	escons ${scons_opts} all
}

src_install() {
	escons ${scons_opts} --full --nostrip install --prefix="${ED}"/usr

	use static-libs || find "${ED}"/usr/ -type f -name "*.a" -delete

	for x in /var/{lib,log}/${PN}; do
		keepdir "${x}"
		fowners mongodb:mongodb "${x}"
	done

	doman debian/mongo*.1
	dodoc README docs/building.md

	newinitd "${FILESDIR}/${PN}.initd-r2" ${PN}
	newconfd "${FILESDIR}/${PN}.confd-r2" ${PN}
	newinitd "${FILESDIR}/${PN/db/s}.initd-r2" ${PN/db/s}
	newconfd "${FILESDIR}/${PN/db/s}.confd-r2" ${PN/db/s}

	insinto /etc
	newins "${FILESDIR}/${PN}.conf-r2" ${PN}.conf
	newins "${FILESDIR}/${PN/db/s}.conf-r2" ${PN/db/s}.conf

	systemd_dounit "${FILESDIR}/${PN}.service"

	insinto /etc/logrotate.d/
	newins "${FILESDIR}/${PN}.logrotate" ${PN}

	if use mms-agent; then
		local MY_PN="mms-agent"
		local MY_D="/opt/${MY_PN}"

		insinto /etc
		newins "${WORKDIR}/${MY_PN}/settings.py" mms-agent.conf
		rm "${WORKDIR}/${MY_PN}/settings.py"

		insinto ${MY_D}
		doins "${WORKDIR}/${MY_PN}/"*
		dosym /etc/mms-agent.conf ${MY_D}/settings.py

		fowners -R mongodb:mongodb ${MY_D}
		newinitd "${FILESDIR}/${MY_PN}.initd-r2" ${MY_PN}
	fi
}

pkg_preinst() {
	# wrt bug #461466
	if [[ "$(get_libdir)" == "lib64" ]]; then
		rmdir "${ED}"/usr/lib/ &>/dev/null
	fi
}

src_test() {
	escons ${scons_opts} test
	"${S}"/test --dbpath=unittest || die
}

pkg_postinst() {
	if [[ ${REPLACING_VERSIONS} < 2.6 ]]; then
		ewarn "!! IMPORTANT !!"
		ewarn " "
		ewarn "${PN} configuration files have changed !"
		ewarn " "
		ewarn "Make sure you migrate from /etc/conf.d/${PN} to the new YAML standard in /etc/${PN}.conf"
		ewarn "  http://docs.mongodb.org/manual/reference/configuration-options/"
		ewarn " "
		ewarn "Make sure you also follow the upgrading process :"
		ewarn "  http://docs.mongodb.org/master/release-notes/2.6-upgrade/"
		ewarn " "
		if use mms-agent; then
			ewarn "MMS Agent configuration file has been moved to :"
			ewarn "  /etc/mms-agent.conf"
		fi
	else
		if use mms-agent; then
			elog "Edit your MMS Agent configuration file :"
			elog "  /etc/mms-agent.conf"
		fi
	fi
}