[gentoo-commits] gentoo-x86 commit in net-print/hplip: ChangeLog hplip-2.7.9.ebuild

[Denis Dupeyron (calchan)]

calchan     07/09/30 14:14:14

  Modified:             ChangeLog
  Added:                hplip-2.7.9.ebuild
  Log:
  Version bump. Reworked minimal installation to fix bug #193671, thanks to Jakub Moc for his suggestions and Dan Ost for reporting and testing.
  (Portage version: 2.1.3.11)

Revision  Changes    Path
1.77                 net-print/hplip/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-print/hplip/ChangeLog?rev=1.77&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-print/hplip/ChangeLog?rev=1.77&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-print/hplip/ChangeLog?r1=1.76&r2=1.77

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v
retrieving revision 1.76
retrieving revision 1.77
diff -u -r1.76 -r1.77
--- ChangeLog	29 Sep 2007 20:31:08 -0000	1.76
+++ ChangeLog	30 Sep 2007 14:14:13 -0000	1.77
@@ -1,6 +1,12 @@
 # ChangeLog for net-print/hplip
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.76 2007/09/29 20:31:08 calchan Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.77 2007/09/30 14:14:13 calchan Exp $
+
+*hplip-2.7.9 (30 Sep 2007)
+
+  30 Sep 2007; Denis Dupeyron <calchan@g.o> +hplip-2.7.9.ebuild:
+  Version bump. Reworked minimal installation to fix bug #193671, thanks to
+  Jakub Moc for his suggestions and Dan Ost for reporting and testing.
 
 *hplip-2.7.7-r3 (29 Sep 2007)
 



1.1                  net-print/hplip/hplip-2.7.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-print/hplip/hplip-2.7.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-print/hplip/hplip-2.7.9.ebuild?rev=1.1&content-type=text/plain

Index: hplip-2.7.9.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-2.7.9.ebuild,v 1.1 2007/09/30 14:14:13 calchan Exp $

inherit linux-info

DESCRIPTION="HP Linux Imaging and Printing System. Includes net-print/hpijs, scanner drivers and service tools."
HOMEPAGE="http://hplip.sourceforge.net/"
SRC_URI="mirror://sourceforge/hplip/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="X doc fax minimal parport ppds scanner snmp"

DEPEND="!net-print/hpijs
	!net-print/hpoj
	virtual/ghostscript
	>=media-libs/jpeg-6b
	net-print/foomatic-filters
	!minimal? ( dev-libs/openssl
		>=net-print/cups-1.2
		dev-libs/libusb
		snmp? ( net-analyzer/net-snmp ) )"

RDEPEND="${DEPEND}
	!minimal? ( !<sys-fs/udev-114
		fax? ( dev-python/reportlab )
		scanner? ( X? ( >=media-gfx/xsane-0.89 )
			!X? ( >=media-gfx/sane-frontends-1.0.9 ) )
		X? ( >=dev-python/PyQt-3.14 ) )"

CONFIG_CHECK="PARPORT"
ERROR_PARPORT="Please make sure Device Drivers -> Parallel port support is enabled in your kernel"

pkg_setup() {
	if ! use ppds ; then
		ewarn "Not installing built-in PPD files, which is probably not what you want."
		ewarn "You need USE=ppds if you want to install them."
	fi
	if use minimal ; then
		ewarn "Installing hpijs driver only, make sure you know what you are doing."
	else
		use parport && linux-info_pkg_setup
	fi

	# avoid collisions with cups-1.2 compat symlinks
	if [ -e ${ROOT}/usr/lib/cups/backend/hp ] && [ -e ${ROOT}/usr/libexec/cups/backend/hp ]; then
		rm -f ${ROOT}/usr/libexec/cups/backend/hp{,fax};
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i -e "s:\$(doc_DATA)::" Makefile.in || die "Patching Makefile.in failed"
	sed -i -e "s/'skipstone']/'skipstone', 'epiphany']/" \
		-e "s/'skipstone': ''}/'skipstone': '', 'epiphany': '--new-window'}/" \
		base/utils.py  || die "Patching base/utils.py failed"

	# bug 98428
	sed -i -e "s:/usr/bin/env python:/usr/bin/python:g" hpssd.py || die "Patching hpssd.py failed"

	# Force recognition of Gentoo distro by hp-check
	sed -i \
		-e "s:file('/etc/issue', 'r').read():'Gentoo':" \
		installer/core_install.py || die "sed core_install.py"

	# bug 186906, makes udev-rules work also for kernel-2.6.22
	sed -i -e "s/usb_device/usb|usb_device/" -e "s/SYSFS/ATTRS/g" \
		data/rules/55-hpmud.rules || die "Patching 55-hpmud.rules failed"
}

src_compile() {
	econf \
		--disable-cups11-build \
		--with-cupsbackenddir=$(cups-config --serverbin)/backend \
		$(use_enable minimal hpijs-only-build) \
		$(use_enable doc doc-build) \
		$(use_enable snmp network-build) \
		$(use_enable parport pp-build) \
		$(use_enable scanner scan-build) \
		$(use_enable X gui-build) \
		$(use_enable fax fax-build) \
		$(use_enable ppds foomatic-ppd-install) \
		--disable-foomatic-xml-install \
		|| die "econf failed"
	emake || die "Compilation failed"
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "emake install failed"

	# bug 106035
	use X || rm -Rf "${D}"/usr/share/applications

	use minimal && rm -rf "${D}"/usr/lib
}

pkg_preinst() {
	if ! use minimal && use scanner ; then
		insinto /etc/sane.d
		[ -e /etc/sane.d/dll.conf ] && cp /etc/sane.d/dll.conf .
		[ -e ${ROOT}/etc/sane.d/dll.conf ] && cp ${ROOT}/etc/sane.d/dll.conf .
		grep -q hpaio dll.conf || echo hpaio >> dll.conf
		doins dll.conf
	fi
}

pkg_postinst() {
	elog "You should run hp-setup as root if you are installing hplip for the first time, and may also"
	elog "need to run it if you are upgrading from an earlier version."
	elog
	elog "This release doesn't use an init script anymore, so you should probably do a"
	elog "'rc-update del hplip' if you are updating."
}



-- 
gentoo-commits@g.o mailing list