[gentoo-commits] gentoo-x86 commit in media-gfx/digikam: metadata.xml ChangeLog digikam-2.0.0.ebuild digikam-2.0.0_rc.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    11/07/29 19:28:45

  Modified:             metadata.xml ChangeLog
  Added:                digikam-2.0.0.ebuild
  Removed:              digikam-2.0.0_rc.ebuild
  Log:
  Version bump; remove old
  
  (Portage version: 2.1.10.7/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 media-gfx/digikam/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/metadata.xml?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/metadata.xml?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/metadata.xml?r1=1.11&r2=1.12

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/digikam/metadata.xml,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- metadata.xml	27 Jul 2011 20:51:56 -0000	1.11
+++ metadata.xml	29 Jul 2011 19:28:45 -0000	1.12
@@ -9,5 +9,9 @@
 	<flag name="themedesigner">Build the digikam theme designer</flag>
 	<flag name="thumbnails">Enable thumbnails database support</flag>
 	<flag name="video">Pull in mplayerthumbs to enable video thumbnails</flag>
+	<flag name="linguas_ha">Hausa translation</flag>
+	<flag name="linguas_mi">Maori translation</flag>
+	<flag name="linguas_tt">?? translation</flag>
+	<flag name="linguas_ven">Venda translation</flag>
 </use>
 </pkgmetadata>



1.190                media-gfx/digikam/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?rev=1.190&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?rev=1.190&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?r1=1.189&r2=1.190

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v
retrieving revision 1.189
retrieving revision 1.190
diff -u -r1.189 -r1.190
--- ChangeLog	27 Jul 2011 20:51:56 -0000	1.189
+++ ChangeLog	29 Jul 2011 19:28:45 -0000	1.190
@@ -1,6 +1,15 @@
 # ChangeLog for media-gfx/digikam
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.189 2011/07/27 20:51:56 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.190 2011/07/29 19:28:45 dilfridge Exp $
+
+*digikam-2.0.0 (29 Jul 2011)
+
+  29 Jul 2011; Andreas K. Huettel <dilfridge@g.o>
+  -digikam-2.0.0_rc.ebuild, +digikam-2.0.0.ebuild,
+  -files/digikam-2.0.0_rc-officialpgf.patch,
+  -files/digikam-2.0.0_rc-officialpgf2.patch,
+  -files/digikam-2.0.0_rc-oldpgf.patch, metadata.xml:
+  Version bump; remove old
 
 *digikam-2.0.0_rc (27 Jul 2011)
 



1.1                  media-gfx/digikam/digikam-2.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/digikam-2.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/digikam-2.0.0.ebuild?rev=1.1&content-type=text/plain

Index: digikam-2.0.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/digikam-2.0.0.ebuild,v 1.1 2011/07/29 19:28:45 dilfridge Exp $

EAPI=4

KDE_LINGUAS="ar az be bg bn br bs ca cs csb cy da de el en_GB eo es et eu fa fi fo fr fy ga
gl ha he hi hr hsb hu id is it ja ka kk km ko ku lb lo lt lv mi mk mn ms mt nb nds ne nl nn
nso oc pa pl pt pt_BR ro ru rw se sk sl sq sr ss sv ta te tg th tr tt uk uz ven vi wa xh
zh_CN zh_HK zh_TW zu"

KDE_HANDBOOK="optional"
CMAKE_MIN_VERSION="2.8"
KDE_MINIMAL="4.7"

inherit kde4-base

MY_P="${PN}-${PV/_/-}"

DESCRIPTION="Digital photo management application for KDE"
HOMEPAGE="http://www.digikam.org/"
[[ ${PV} != *9999* ]] && SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2
	handbook? ( FDL-1.2 )"
KEYWORDS="~amd64 ~x86"
SLOT="4"
IUSE="addressbook debug doc gphoto2 mysql semantic-desktop themedesigner +thumbnails video"

CDEPEND="
	$(add_kdebase_dep kdelibs semantic-desktop)
	$(add_kdebase_dep libkdcraw)
	$(add_kdebase_dep libkexiv2)
	$(add_kdebase_dep libkipi)
	$(add_kdebase_dep marble plasma)
	$(add_kdebase_dep solid)
	media-libs/jasper
	media-libs/lcms:0
	>=media-libs/lensfun-0.2.5
	>=media-libs/libkface-${PV}
	>=media-libs/libkgeomap-${PV}
	media-libs/liblqr
	>=media-libs/libpgf-6.11.28
	media-libs/libpng
	media-libs/tiff
	virtual/jpeg
	x11-libs/qt-gui[qt3support]
	|| ( >=sci-libs/clapack-3.2.1-r6 sci-libs/lapack-atlas )
	|| ( x11-libs/qt-sql[mysql] x11-libs/qt-sql[sqlite] )
	addressbook? ( $(add_kdebase_dep kdepimlibs) )
	gphoto2? ( media-libs/libgphoto2 )
	mysql? ( virtual/mysql )
"
RDEPEND="${CDEPEND}
	$(add_kdebase_dep kreadconfig)
	media-plugins/kipi-plugins
	video? (
		|| (
			$(add_kdebase_dep mplayerthumbs)
			$(add_kdebase_dep ffmpegthumbs)
		)
	)
"
DEPEND="${CDEPEND}
	sys-devel/gettext
	doc? ( app-doc/doxygen )
"

S="${WORKDIR}/${MY_P}/core"

src_prepare() {
	# just to make absolutely sure
	rm -rf "${WORKDIR}/${MY_P}/extra" || die

	# prepare the handbook
	mv "${WORKDIR}/${MY_P}/doc/${PN}" doc || die
	echo "add_subdirectory( digikam )" > doc/CMakeLists.txt
	echo "add_subdirectory( showfoto )" >> doc/CMakeLists.txt

	# prepare the translations
	mv "${WORKDIR}/${MY_P}/po" po || die
	find po -name "kipiplugin_*.po" -exec rm {} +

	echo "add_subdirectory( po )" >> CMakeLists.txt

	kde4-base_src_prepare

	if use handbook; then
		echo "add_subdirectory( doc )" >> CMakeLists.txt
	fi
}

src_configure() {
	local backend

	use semantic-desktop && backend="Nepomuk" || backend="None"
	# LQR = only allows to choose between bundled/external
	local mycmakeargs=(
		-DFORCED_UNBUNDLE=ON
		-DWITH_LQR=ON
		-DWITH_LENSFUN=ON
		-DGWENVIEW_SEMANTICINFO_BACKEND=${backend}
		$(cmake-utils_use_with addressbook KdepimLibs)
		-DWITH_MarbleWidget=ON
		$(cmake-utils_use_enable gphoto2 GPHOTO2)
		$(cmake-utils_use_with gphoto2)
		$(cmake-utils_use_with semantic-desktop Soprano)
		$(cmake-utils_use_enable themedesigner)
		$(cmake-utils_use_enable thumbnails THUMBS_DB)
		$(cmake-utils_use_enable mysql INTERNALMYSQL)
		$(cmake-utils_use_enable debug DEBUG_MESSAGES)
	)

	kde4-base_src_configure
}

src_compile() {
	local mytargets="all"
	use doc && mytargets+=" doc"

	kde4-base_src_compile ${mytargets}
}

src_install() {
	kde4-base_src_install

	if use doc; then
		# install the api documentation
		insinto /usr/share/doc/${PF}/html
		doins -r ${CMAKE_BUILD_DIR}/api/html/*
	fi
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if use doc; then
		elog "The digikam api documentation has been installed at /usr/share/doc/${PF}/html"
	fi
}