[gentoo-commits] gentoo-x86 commit in media-video/jubler: ChangeLog jubler-3.9.6.ebuild

[Serkan Kaba (serkan)]

serkan      08/10/29 20:22:21

  Modified:             ChangeLog
  Added:                jubler-3.9.6.ebuild
  Log:
  Version bump that works with newer ffmpeg. Fixes bug #218091, #242946. Thanks to Luca Barbato <lu_zero@g.o>, Alexis Ballier <aballier@g.o> for help.
  (Portage version: 2.2_rc12/cvs/Linux 2.6.25-gentoo-r7 x86_64)

Revision  Changes    Path
1.21                 media-video/jubler/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/jubler/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	18 Jul 2008 22:53:23 -0000	1.20
+++ ChangeLog	29 Oct 2008 20:22:21 -0000	1.21
@@ -1,6 +1,15 @@
 # ChangeLog for media-video/jubler
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/jubler/ChangeLog,v 1.20 2008/07/18 22:53:23 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/jubler/ChangeLog,v 1.21 2008/10/29 20:22:21 serkan Exp $
+
+*jubler-3.9.6 (29 Oct 2008)
+
+  29 Oct 2008; Serkan Kaba <serkan@g.o>
+  +files/jubler-3.9.6-ffmpegfix.patch, +files/jubler-3.9.6.patch,
+  +jubler-3.9.6.ebuild:
+  Version bump that works with newer ffmpeg. Fixes bug #218091, #242946.
+  Thanks to Luca Barbato <lu_zero@g.o>, Alexis Ballier
+  <aballier@g.o> for help.
 
   18 Jul 2008; Petteri Räty <betelgeuse@g.o> jubler-3.4.1.ebuild,
   jubler-3.9.0.ebuild:



1.1                  media-video/jubler/jubler-3.9.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/jubler-3.9.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/jubler-3.9.6.ebuild?rev=1.1&content-type=text/plain

Index: jubler-3.9.6.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/jubler/jubler-3.9.6.ebuild,v 1.1 2008/10/29 20:22:21 serkan Exp $

inherit gnome2 eutils java-pkg-2 java-ant-2 toolchain-funcs

MY_PN=${PN/#j/J}
DESCRIPTION="Java subtitle editor"
HOMEPAGE="http://www.jubler.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-src-${PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="mplayer nls spell"

RDEPEND=">=virtual/jre-1.5
	>=media-video/ffmpeg-0.4.9_p20080326
	mplayer? ( media-video/mplayer )
	spell?
	(
		app-text/aspell
		>=dev-java/zemberek-2.0
	)"

DEPEND=">=virtual/jdk-1.5
	media-video/ffmpeg
	app-text/docbook-sgml-utils
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_PN}-${PV}

pkg_setup() {
	if use spell && ! built_with_use dev-java/zemberek linguas_tr; then
		die "Zemberek should be built with Turkish language support"
	fi
	if use mplayer && ! built_with_use media-video/mplayer srt; then
		msg="media-video/mplayer needs to be built with the srt use flag"
		eerror ${msg}
		die ${msg}
	fi
	java-pkg-2_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}.patch"
	epatch "${FILESDIR}/${P}-ffmpegfix.patch"
	chmod +x resources/installers/linux/iconinstall
}

src_compile() {
	java-pkg_filter-compiler ecj-3.2
	eant $(use nls && echo i18n) jar faq || die "eant failed"
	cp -v dist/help/jubler-faq.html build/classes/help || die "cp failed"
	cd resources/ffdecode || die
	CC=$(tc-getCC) NOSTRIP=true emake linuxdyn || die "make failed"
}

src_install() {
	java-pkg_dojar dist/Jubler.jar
	use spell && java-pkg_register-dependency zemberek zemberek2-cekirdek.jar
	use spell && java-pkg_register-dependency zemberek zemberek2-tr.jar
	java-pkg_doso resources/ffdecode/libffdecode.so
	doicon resources/installers/linux/jubler.png
	domenu resources/installers/linux/jubler.desktop

	DESTDIR="${D}" eant linuxdesktopintegration
	rm -vr "${D}/usr/share/menu" || die

	java-pkg_dolauncher jubler --main com.panayotis.jubler.Main
	doman resources/installers/linux/jubler.1
	insinto /usr/share/jubler/help
	doins dist/help/*
}

pkg_preinst() {
	gnome2_pkg_preinst
	java-pkg-2_pkg_preinst
}