[gentoo-commits] gentoo-x86 commit in net-print/cups-filters: cups-filters-9999.ebuild ChangeLog cups-filters-1.0.23-r1.ebuild cups-filters-1.0.23.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    12/08/23 21:18:15

  Modified:             cups-filters-9999.ebuild ChangeLog
  Added:                cups-filters-1.0.23-r1.ebuild
  Removed:              cups-filters-1.0.23.ebuild
  Log:
  Add configure option --with-pdftops=pdftops so pdf is rendered via poppler not ghostscript, bug 431406
  
  (Portage version: 2.2.0_alpha121/cvs/Linux x86_64)

Revision  Changes    Path
1.26                 net-print/cups-filters/cups-filters-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?r1=1.25&r2=1.26

Index: cups-filters-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- cups-filters-9999.ebuild	23 Aug 2012 21:14:07 -0000	1.25
+++ cups-filters-9999.ebuild	23 Aug 2012 21:18:14 -0000	1.26
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.25 2012/08/23 21:14:07 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.26 2012/08/23 21:18:14 dilfridge Exp $
 
 EAPI=4
 
@@ -52,6 +52,7 @@
 	econf \
 		$(use_enable static-libs static) \
 		--with-fontdir="fonts/conf.avail" \
+		--with-pdftops=pdftops \
 		--enable-imagefilters \
 		$(use_with jpeg) \
 		$(use_with png) \



1.35                 net-print/cups-filters/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	23 Aug 2012 21:14:07 -0000	1.34
+++ ChangeLog	23 Aug 2012 21:18:14 -0000	1.35
@@ -1,6 +1,14 @@
 # ChangeLog for net-print/cups-filters
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.34 2012/08/23 21:14:07 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.35 2012/08/23 21:18:14 dilfridge Exp $
+
+*cups-filters-1.0.23-r1 (23 Aug 2012)
+
+  23 Aug 2012; Andreas K. Huettel <dilfridge@g.o>
+  -cups-filters-1.0.23.ebuild, +cups-filters-1.0.23-r1.ebuild,
+  cups-filters-9999.ebuild:
+  Add configure option --with-pdftops=pdftops so pdf is rendered via poppler
+  not ghostscript, bug 431406
 
   23 Aug 2012; Andreas K. Huettel <dilfridge@g.o>
   cups-filters-9999.ebuild:



1.1                  net-print/cups-filters/cups-filters-1.0.23-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-1.0.23-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-1.0.23-r1.ebuild?rev=1.1&content-type=text/plain

Index: cups-filters-1.0.23-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-1.0.23-r1.ebuild,v 1.1 2012/08/23 21:18:15 dilfridge Exp $

EAPI=4

GENTOO_DEPEND_ON_PERL=no

inherit base perl-module

if [[ "${PV}" == "9999" ]] ; then
	inherit autotools bzr
	EBZR_REPO_URI="http://bzr.linuxfoundation.org/openprinting/cups-filters"
	KEYWORDS=""
else
	SRC_URI="http://www.openprinting.org/download/${PN}/${P}.tar.xz"
	KEYWORDS="~amd64 ~hppa ~mips ~x86"
fi
DESCRIPTION="Cups PDF filters"
HOMEPAGE="http://www.linuxfoundation.org/collaborate/workgroups/openprinting/pdfasstandardprintjobformat"

LICENSE="MIT GPL-2"
SLOT="0"
IUSE="jpeg perl png static-libs tiff"

RDEPEND="
	app-text/ghostscript-gpl
	app-text/poppler[cxx,jpeg?,lcms,tiff?,xpdf-headers(+)]
	app-text/qpdf
	media-libs/fontconfig
	media-libs/freetype:2
	media-libs/lcms:2
	>net-print/cups-1.5.9999
	!<=net-print/cups-1.5.9999
	sys-devel/bc
	sys-libs/zlib
	jpeg? ( virtual/jpeg )
	perl? ( dev-lang/perl )
	png? ( media-libs/libpng )
	tiff? ( media-libs/tiff )
"
DEPEND="${RDEPEND}"

src_prepare() {
	base_src_prepare
	if [[ "${PV}" == "9999" ]]; then
		eautoreconf
	fi
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		--with-fontdir="fonts/conf.avail" \
		--with-pdftops=pdftops \
		--enable-imagefilters \
		$(use_with jpeg) \
		$(use_with png) \
		$(use_with tiff) \
		--without-php \
		--docdir=/usr/share/doc/${PF}
}

src_compile() {
	default

	if use perl; then
		pushd "${S}/scripting/perl" > /dev/null
		perl-module_src_prep
		perl-module_src_compile
		popd > /dev/null
	fi
}

src_install() {
	default

	if use perl; then
		pushd "${S}/scripting/perl" > /dev/null
		perl-module_src_install
		fixlocalpod
		popd > /dev/null
	fi

	find "${ED}" -name '*.la' -exec rm -f {} +
}