[gentoo-commits] gentoo-x86 commit in www-client/midori: midori-0.5.5.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    13/10/05 08:33:01

  Modified:             ChangeLog
  Added:                midori-0.5.5.ebuild
  Log:
  Version bump wrt #486474 by "A. Person". Remove USE="nls" which only avoided sys-devel/gettext dependency despite dev-util/intltool being always required which has sys-devel/gettext as a dependency. Remove USE="gnome" since net-libs/libsoup-gnome is now required always.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.117                www-client/midori/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/ChangeLog?rev=1.117&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/ChangeLog?rev=1.117&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/ChangeLog?r1=1.116&r2=1.117

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v
retrieving revision 1.116
retrieving revision 1.117
diff -u -r1.116 -r1.117
--- ChangeLog	30 Aug 2013 22:49:16 -0000	1.116
+++ ChangeLog	5 Oct 2013 08:33:01 -0000	1.117
@@ -1,6 +1,14 @@
 # ChangeLog for www-client/midori
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.116 2013/08/30 22:49:16 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.117 2013/10/05 08:33:01 ssuominen Exp $
+
+*midori-0.5.5 (05 Oct 2013)
+
+  05 Oct 2013; Samuli Suominen <ssuominen@g.o> +midori-0.5.5.ebuild:
+  Version bump wrt #486474 by "A. Person". Remove USE="nls" which only avoided
+  sys-devel/gettext dependency despite dev-util/intltool being always required
+  which has sys-devel/gettext as a dependency. Remove USE="gnome" since net-libs
+  /libsoup-gnome is now required always.
 
   30 Aug 2013; Gilles Dartiguelongue <eva@g.o> midori-0.5.4.ebuild:
   Depend on libsoup-gnome again, clean up old revisions.



1.1                  www-client/midori/midori-0.5.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/midori-0.5.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/midori-0.5.5.ebuild?rev=1.1&content-type=text/plain

Index: midori-0.5.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.5.5.ebuild,v 1.1 2013/10/05 08:33:01 ssuominen Exp $

EAPI=5

MY_VALA_VERSION=0.20
VALA_MIN_API_VERSION=${MY_VALA_VERSION}
VALA_MAX_API_VERSION=${MY_VALA_VERSION}

PYTHON_COMPAT=( python2_7 )

unset _live_inherits

if [[ ${PV} == *9999* ]]; then
	EGIT_REPO_URI="git://git.xfce.org/apps/${PN}"
	_live_inherits=git-2
else
	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
	SRC_URI="http://www.${PN}-browser.org/downloads/${PN}_${PV}_all_.tar.bz2"
fi

inherit eutils fdo-mime gnome2-utils pax-utils python-any-r1 waf-utils vala ${_live_inherits}

DESCRIPTION="A lightweight web browser based on WebKitGTK+"
HOMEPAGE="http://www.midori-browser.org/"

LICENSE="LGPL-2.1 MIT"
SLOT="0"
IUSE="+deprecated doc +unique webkit2 zeitgeist"

RDEPEND=">=dev-db/sqlite-3.6.19:3
	>=dev-libs/glib-2.32.3
	dev-libs/libxml2
	>=net-libs/libsoup-2.34:2.4
	>=net-libs/libsoup-gnome-2.34:2.4
	>=x11-libs/libnotify-0.7
	x11-libs/libXScrnSaver
	deprecated? (
		>=net-libs/webkit-gtk-1.8.3:2
		>=x11-libs/gtk+-2.24:2
		unique? ( dev-libs/libunique:1 )
		)
	!deprecated? (
		>=app-crypt/gcr-3
		>=net-libs/webkit-gtk-1.10.2:3
		x11-libs/gtk+:3
		unique? ( dev-libs/libunique:3 )
		webkit2? ( >=net-libs/webkit-gtk-2 )
		)
	zeitgeist? ( >=dev-libs/libzeitgeist-0.3.14 )"
DEPEND="${RDEPEND}
	${PYTHON_DEPS}
	$(vala_depend)
	dev-util/intltool
	gnome-base/librsvg
	sys-devel/gettext
	doc? ( dev-util/gtk-doc )"

pkg_setup() {
	python-any-r1_pkg_setup

	DOCS=( AUTHORS ChangeLog HACKING README TODO TRANSLATE )
	HTML_DOCS=( data/faq.html data/faq.css )
}

src_unpack() {
	if [[ ${PV} == *9999* ]]; then
		git-2_src_unpack
	else
		default
	fi
}

src_prepare() {
	# Force disabled because we don't have this custom renamed in Portage
	sed -i -e 's:gcr-3-gtk2:&dIsAbLe:' wscript || die

	vala_src_prepare
}

src_configure() {
	export VALAC_VERSION=${MY_VALA_VERSION}

	strip-linguas -i po

	local myconf
	use deprecated || myconf="$(use_enable webkit2)"

	waf-utils_src_configure \
		--disable-docs \
		$(use_enable doc apidocs) \
		$(use_enable unique) \
		--disable-granite \
		$(use_enable !deprecated gtk3) \
		$(use_enable zeitgeist) \
		${myconf}
}

src_install() {
	waf-utils_src_install

	local jit_is_enabled
	if use deprecated; then
		has_version 'net-libs/webkit-gtk:2[jit]' && jit_is_enabled=yes
	else
		has_version 'net-libs/webkit-gtk:3[jit]' && jit_is_enabled=yes
	fi
	[[ ${jit_is_enabled} == yes ]] && pax-mark -m "${ED}"/usr/bin/${PN} #480290
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}