[gentoo-commits] gentoo-x86 commit in net-misc/rsync: rsync-3.1.1.ebuild ChangeLog rsync-3.1.1_pre2.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    14/07/07 07:51:31

  Modified:             ChangeLog
  Added:                rsync-3.1.1.ebuild
  Removed:              rsync-3.1.1_pre2.ebuild
  Log:
  changelog
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.255                net-misc/rsync/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/ChangeLog?rev=1.255&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/ChangeLog?rev=1.255&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/ChangeLog?r1=1.254&r2=1.255

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/rsync/ChangeLog,v
retrieving revision 1.254
retrieving revision 1.255
diff -u -r1.254 -r1.255
--- ChangeLog	27 May 2014 07:32:45 -0000	1.254
+++ ChangeLog	7 Jul 2014 07:51:31 -0000	1.255
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/rsync
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/ChangeLog,v 1.254 2014/05/27 07:32:45 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/ChangeLog,v 1.255 2014/07/07 07:51:31 polynomial-c Exp $
+
+*rsync-3.1.1 (07 Jul 2014)
+
+  07 Jul 2014; Lars Wendler <polynomial-c@g.o> -rsync-3.1.1_pre2.ebuild,
+  +rsync-3.1.1.ebuild:
+  Version bump. Removed old.
 
   27 May 2014; Lars Wendler <polynomial-c@g.o> rsync-3.1.1_pre2.ebuild:
   rsync-3.1.1_pre2 no longer needs the patch from 3.1.0.



1.1                  net-misc/rsync/rsync-3.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/rsync-3.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/rsync-3.1.1.ebuild?rev=1.1&content-type=text/plain

Index: rsync-3.1.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/rsync-3.1.1.ebuild,v 1.1 2014/07/07 07:51:31 polynomial-c Exp $

EAPI="5"

inherit eutils flag-o-matic prefix systemd

DESCRIPTION="File transfer program to keep remote files into sync"
HOMEPAGE="http://rsync.samba.org/"
SRC_URI="http://rsync.samba.org/ftp/rsync/src/${P/_/}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="acl iconv ipv6 static xattr"

if [[ ${PV} = *pre* ]] ; then
	SRC_URI="http://rsync.samba.org/ftp/rsync/src-previews/${P/_/}.tar.gz"
	KEYWORDS=""
fi

LIB_DEPEND="acl? ( virtual/acl[static-libs(+)] )
	xattr? ( kernel_linux? ( sys-apps/attr[static-libs(+)] ) )
	>=dev-libs/popt-1.5[static-libs(+)]"
RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
	iconv? ( virtual/libiconv )"
DEPEND="${RDEPEND}
	static? ( ${LIB_DEPEND} )"

S=${WORKDIR}/${P/_/}

src_prepare() {
	epatch_user
}

src_configure() {
	use static && append-ldflags -static
	econf \
		--without-included-popt \
		$(use_enable acl acl-support) \
		$(use_enable xattr xattr-support) \
		$(use_enable ipv6) \
		$(use_enable iconv) \
		--with-rsyncd-conf="${EPREFIX}"/etc/rsyncd.conf
	touch proto.h-tstamp #421625
}

src_install() {
	emake DESTDIR="${D}" install
	newconfd "${FILESDIR}"/rsyncd.conf.d rsyncd
	newinitd "${FILESDIR}"/rsyncd.init.d-r1 rsyncd
	dodoc NEWS OLDNEWS README TODO tech_report.tex
	insinto /etc
	newins "${FILESDIR}"/rsyncd.conf-3.0.9-r1 rsyncd.conf

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/rsyncd.logrotate rsyncd

	insinto /etc/xinetd.d
	newins "${FILESDIR}"/rsyncd.xinetd-3.0.9-r1 rsyncd

	# Install the useful contrib scripts
	exeinto /usr/share/rsync
	doexe support/*
	rm -f "${ED}"/usr/share/rsync/{Makefile*,*.c}

	eprefixify "${ED}"/etc/{,xinetd.d}/rsyncd*

	systemd_dounit "${FILESDIR}/rsyncd.service"
}

pkg_postinst() {
	if egrep -qis '^[[:space:]]use chroot[[:space:]]*=[[:space:]]*(no|0|false)' \
		"${EROOT}"/etc/rsyncd.conf "${EROOT}"/etc/rsync/rsyncd.conf ; then
		ewarn "You have disabled chroot support in your rsyncd.conf.  This"
		ewarn "is a security risk which you should fix.  Please check your"
		ewarn "/etc/rsyncd.conf file and fix the setting 'use chroot'."
	fi
}