[gentoo-commits] gentoo-x86 commit in dev-python/graph-tool: graph-tool-2.2.35.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     14/10/04 07:46:18

  Modified:             ChangeLog
  Added:                graph-tool-2.2.35.ebuild
  Log:
  bump; add py3.4
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.14                 dev-python/graph-tool/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graph-tool/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graph-tool/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graph-tool/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/graph-tool/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	1 Apr 2014 07:41:41 -0000	1.13
+++ ChangeLog	4 Oct 2014 07:46:18 -0000	1.14
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/graph-tool
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/ChangeLog,v 1.13 2014/04/01 07:41:41 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/ChangeLog,v 1.14 2014/10/04 07:46:18 idella4 Exp $
+
+*graph-tool-2.2.35 (04 Oct 2014)
+
+  04 Oct 2014; Ian Delaney <idella4@g.o> +graph-tool-2.2.35.ebuild:
+  bump; add py3.4
 
 *graph-tool-2.2.31 (01 Apr 2014)
 
@@ -68,4 +73,3 @@
   04 Jan 2013; Tim Harder <radhermit@g.o> +graph-tool-2.2.19.ebuild,
   +graph-tool-9999.ebuild, +metadata.xml:
   Initial import, ebuild by me.
-



1.1                  dev-python/graph-tool/graph-tool-2.2.35.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graph-tool/graph-tool-2.2.35.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graph-tool/graph-tool-2.2.35.ebuild?rev=1.1&content-type=text/plain

Index: graph-tool-2.2.35.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/graph-tool-2.2.35.ebuild,v 1.1 2014/10/04 07:46:18 idella4 Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )

inherit check-reqs eutils toolchain-funcs python-r1

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://git.skewed.de/graph-tool"
	inherit git-2
else
	SRC_URI="http://downloads.skewed.de/${PN}/${P}.tar.bz2"
	KEYWORDS="~amd64 ~x86"
fi

DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
HOMEPAGE="http://graph-tool.skewed.de/"

LICENSE="GPL-3"
SLOT="0"
IUSE="+cairo openmp"

CDEPEND="${PYTHON_DEPS}
	>=dev-libs/boost-1.46.0[python,${PYTHON_USEDEP}]
	dev-libs/expat
	dev-python/numpy[${PYTHON_USEDEP}]
	sci-libs/scipy[${PYTHON_USEDEP}]
	>=sci-mathematics/cgal-3.5
	cairo? (
		dev-cpp/cairomm
		dev-python/pycairo[${PYTHON_USEDEP}]
	)"
RDEPEND="${CDEPEND}
	dev-python/matplotlib[${PYTHON_USEDEP}]"
DEPEND="${CDEPEND}
	dev-cpp/sparsehash
	virtual/pkgconfig"

# most machines don't have enough ram for parallel builds
MAKEOPTS="${MAKEOPTS} -j1"

# bug 453544
CHECKREQS_DISK_BUILD="6G"

pkg_pretend() {
	if use openmp ; then
		tc-has-openmp || die "Please switch to an openmp compatible compiler"
	fi
	check-reqs_pkg_pretend
}

src_prepare() {
	>py-compile
	python_copy_sources
}

src_configure() {
	python_parallel_foreach_impl run_in_build_dir \
		econf \
			--disable-static \
			--disable-optimization \
			$(use_enable openmp) \
			$(use_enable cairo)
}

src_compile() {
	python_parallel_foreach_impl run_in_build_dir default
}

src_install() {
	python_parallel_foreach_impl run_in_build_dir default
	prune_libtool_files --modules

	# remove unwanted extra docs
	rm -r "${ED}"/usr/share/doc/${PN} || die
}

run_in_build_dir() {
	pushd "${BUILD_DIR}" > /dev/null
	"$@"
	popd > /dev/null
}