[gentoo-commits] gentoo-x86 commit in net-misc/x2goclient: ChangeLog x2goclient-4.0.5.0.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    15/07/29 16:23:44

  Modified:             ChangeLog
  Added:                x2goclient-4.0.5.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 00F7AB331B0F097F)

Revision  Changes    Path
1.42                 net-misc/x2goclient/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/x2goclient/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	27 May 2015 12:48:09 -0000	1.41
+++ ChangeLog	29 Jul 2015 16:23:44 -0000	1.42
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/x2goclient
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/x2goclient/ChangeLog,v 1.41 2015/05/27 12:48:09 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/x2goclient/ChangeLog,v 1.42 2015/07/29 16:23:44 voyageur Exp $
+
+*x2goclient-4.0.5.0 (29 Jul 2015)
+
+  29 Jul 2015; Bernard Cafarelli <voyageur@g.o>
+  +x2goclient-4.0.5.0.ebuild:
+  Version bump
 
 *x2goclient-4.0.4.0 (27 May 2015)
 



1.1                  net-misc/x2goclient/x2goclient-4.0.5.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/x2goclient-4.0.5.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/x2goclient-4.0.5.0.ebuild?rev=1.1&content-type=text/plain

Index: x2goclient-4.0.5.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/x2goclient/x2goclient-4.0.5.0.ebuild,v 1.1 2015/07/29 16:23:44 voyageur Exp $

EAPI=5
inherit eutils nsplugins qt4-r2

DESCRIPTION="The X2Go Qt client"
HOMEPAGE="http://www.x2go.org"
SRC_URI="http://code.x2go.org/releases/source/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ldap nsplugin"

DEPEND=">=net-libs/libssh-0.6.0_rc1
	net-print/cups
	dev-qt/qtcore:4[ssl]
	dev-qt/qtgui:4
	dev-qt/qtsvg:4
	x11-libs/libXpm
	ldap? ( net-nds/openldap )"
RDEPEND="${DEPEND}
	net-misc/nx"

CLIENT_BUILD=${WORKDIR}/${P}.client_build
PLUGIN_BUILD=${WORKDIR}/${P}.plugin_build

src_prepare() {
	if ! use ldap; then
		sed -e "s/-lldap//" -i x2goclient.pro || die
		sed -e "s/#define USELDAP//" -i src/x2goclientconfig.h || die
	fi

	mkdir -p "${CLIENT_BUILD}"
	use nsplugin && mkdir -p "${PLUGIN_BUILD}"
}

src_configure() {
	cd "${CLIENT_BUILD}"
	eqmake4 "${S}"/x2goclient.pro

	if use nsplugin;
	then
		cd "${PLUGIN_BUILD}"
		X2GO_CLIENT_TARGET=plugin eqmake4 "${S}"/x2goclient.pro
	fi
}

src_compile() {
	cd "${CLIENT_BUILD}"
	qt4-r2_src_compile

	if use nsplugin;
	then
		cd "${PLUGIN_BUILD}"
		qt4-r2_src_compile
	fi
}

src_install() {
	dobin "${CLIENT_BUILD}"/${PN}

	insinto /usr/share/pixmaps/x2goclient
	doins res/img/icons/${PN}.xpm

	domenu desktop/${PN}.desktop
	doman man/man?/*

	if use nsplugin;
	then
		# PLUGINS_DIR comes from nsplugins.eclass
		exeinto /usr/$(get_libdir)/${PLUGINS_DIR}
		doexe "${PLUGIN_BUILD}"/libx2goplugin.so
	fi

	emake DESTDIR="${D}" PREFIX=/usr install_pluginprovider
}