[gentoo-commits] proj/kde:master commit in: kde-plasma/libkworkspace/

[Andreas Sturmlechner]

commit:     e5016526c9fac18cf5278541a427c04ef2941b74
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri May 14 20:32:25 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri May 14 20:38:50 2021 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=e5016526

kde-plasma/libkworkspace: 5.21.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../libkworkspace/libkworkspace-5.21.90.ebuild     | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/kde-plasma/libkworkspace/libkworkspace-5.21.90.ebuild b/kde-plasma/libkworkspace/libkworkspace-5.21.90.ebuild
new file mode 100644
index 0000000000..d5de9a8d1e
--- /dev/null
+++ b/kde-plasma/libkworkspace/libkworkspace-5.21.90.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KDE_ORG_NAME="plasma-workspace"
+KFMIN=5.82.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Workspace library to interact with the Plasma session manager"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kinit-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+"
+DEPEND="${RDEPEND}
+	>=kde-plasma/kwin-${PVCUT}:5
+"
+
+S="${S}/${PN}"
+
+PATCHES=( "${FILESDIR}/${PN}-5.19.80-standalone.patch" )
+
+src_prepare() {
+	# delete colliding libkworkspace translations, let ecm_src_prepare do its magic
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find ../po -type f -name "*po" -and -not -name "libkworkspace*" -delete || die
+		rm -rf po/*/docs || die
+		cp -a ../po ./ || die
+	fi
+	ecm_src_prepare
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		cat >> CMakeLists.txt <<- _EOF_ || die
+			ki18n_install(po)
+		_EOF_
+	fi
+
+	sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" \
+		-i CMakeLists.txt || die "Failed to prepare CMakeLists.txt"
+}