[gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-modules: ChangeLog virtualbox-modules-3.2.12.ebuild virtualbox-modules-3.2.8.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    10/12/03 13:58:16

  Modified:             ChangeLog
  Added:                virtualbox-modules-3.2.12.ebuild
  Removed:              virtualbox-modules-3.2.8.ebuild
  Log:
  Version bump. Removed old.
  
  (Portage version: 2.2.0_alpha6/cvs/Linux x86_64)

Revision  Changes    Path
1.71                 app-emulation/virtualbox-modules/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog?rev=1.71&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog?rev=1.71&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog?r1=1.70&r2=1.71

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v
retrieving revision 1.70
retrieving revision 1.71
diff -u -r1.70 -r1.71
--- ChangeLog	12 Oct 2010 13:51:52 -0000	1.70
+++ ChangeLog	3 Dec 2010 13:58:16 -0000	1.71
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/virtualbox-modules
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v 1.70 2010/10/12 13:51:52 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v 1.71 2010/12/03 13:58:16 polynomial-c Exp $
+
+*virtualbox-modules-3.2.12 (03 Dec 2010)
+
+  03 Dec 2010; Lars Wendler <polynomial-c@g.o>
+  -virtualbox-modules-3.2.8.ebuild, +virtualbox-modules-3.2.12.ebuild:
+  Version bump. Removed old.
 
 *virtualbox-modules-3.2.10 (12 Oct 2010)
 



1.1                  app-emulation/virtualbox-modules/virtualbox-modules-3.2.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-3.2.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-3.2.12.ebuild?rev=1.1&content-type=text/plain

Index: virtualbox-modules-3.2.12.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-3.2.12.ebuild,v 1.1 2010/12/03 13:58:16 polynomial-c Exp $

# XXX: the tarball here is just the kernel modules split out of the binary
#      package that comes from virtualbox-bin

EAPI=2

inherit eutils linux-mod

MY_P=vbox-kernel-module-src-${PV}
DESCRIPTION="Kernel Modules for Virtualbox"
HOMEPAGE="http://www.virtualbox.org/"
SRC_URI="http://dev.gentoo.org/~polynomial-c/virtualbox/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="!=app-emulation/virtualbox-ose-9999"

S=${WORKDIR}

BUILD_TARGETS="all"
BUILD_TARGET_ARCH="${ARCH}"
MODULE_NAMES="vboxdrv(misc:${S}) vboxnetflt(misc:${S}) vboxnetadp(misc:${S})"

pkg_setup() {
	linux-mod_pkg_setup
	BUILD_PARAMS="KERN_DIR=${KV_DIR} KERNOUT=${KV_OUT_DIR}"
	enewgroup vboxusers
}

src_prepare() {
	if kernel_is -ge 2 6 33 ; then
		# evil patch for new kernels - header moved
		grep -lR linux/autoconf.h *  | xargs sed -i -e 's:<linux/autoconf.h>:<generated/autoconf.h>:'
	fi
}

src_install() {
	linux-mod_src_install

	# udev rule for vboxdrv
	dodir /etc/udev/rules.d
	echo '#SUBSYSTEM=="usb_device", GROUP="vboxusers", MODE="0644"' \
	> "${D}/etc/udev/rules.d/10-virtualbox.rules"
	echo '#SUBSYSTEM=="usb", ENV{DEVTYPE}=="usb_device", GROUP="vboxusers", MODE="0644"' \
	>> "${D}/etc/udev/rules.d/10-virtualbox.rules"
}

pkg_postinst() {
	linux-mod_pkg_postinst
	elog "Starting with the 3.x release new kernel modules were added,"
	elog "be sure to load all the needed modules."
	elog ""
	elog "Please add \"vboxdrv\", \"vboxnetflt\" and \"vboxnetadp\" to:"
	if has_version sys-apps/openrc; then
		elog "/etc/conf.d/modules"
	else
		elog "/etc/modules.autoload.d/kernel-${KV_MAJOR}.${KV_MINOR}"
	fi
	elog ""
	elog "If you are experiencing problems on your guests"
	elog "with USB support and app-emulation/virtualbox-bin,"
	elog "uncomment the udev rules placed in:"
	elog ""
	elog "/etc/udev/rules.d/10-virtualbox.rules"
	elog ""
}