[gentoo-commits] repo/gentoo:master commit in: media-gfx/gthumb/

[Matt Turner]

commit:     45c5278ff6b428560aaccc0371a28d0f0c42ac43
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 20 02:09:40 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Apr 20 02:15:27 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45c5278f

media-gfx/gthumb: Version bump to 3.10.3

Closes: https://bugs.gentoo.org/768060
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/gthumb/Manifest             |  1 +
 media-gfx/gthumb/gthumb-3.10.3.ebuild | 96 +++++++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/media-gfx/gthumb/Manifest b/media-gfx/gthumb/Manifest
index ad4f326204f..5028bd7bbb0 100644
--- a/media-gfx/gthumb/Manifest
+++ b/media-gfx/gthumb/Manifest
@@ -1 +1,2 @@
 DIST gthumb-3.10.2.tar.xz 7582448 BLAKE2B 29c6e74706e0f78c4a641841861f9e4d996c5baa7e9a26e12352e6c124402bad24af1ee45871f413de4935abe53109ffad484ed8d853c131cfa438714e4226b5 SHA512 3b4d23a744e0663a0358d41697b1b01ec2faa3f12fc29853c82de8109dec5ef66c3827ed6e0efb97147e34ab9643b42daedc3ee7babe03f486ba589323604b74
+DIST gthumb-3.10.3.tar.xz 7582472 BLAKE2B 1e8274720428db05d4e14bb6a37ff55a74fe009ea551bda6fe75506f7187e03685903c2743fb6e66a33da73c974188528afad866c568bb14cc6f05749e08af7c SHA512 2d157644c6efbf4f4ab31c525a4eecc69fbdf31003f922d5fdf8866ca6bbb44e5b8bd7f809be12de41178ddcef30bb49029ea06eb4feb8398a6aa1b052c6ae38

diff --git a/media-gfx/gthumb/gthumb-3.10.3.ebuild b/media-gfx/gthumb/gthumb-3.10.3.ebuild
new file mode 100644
index 00000000000..79d24ac86c0
--- /dev/null
+++ b/media-gfx/gthumb/gthumb-3.10.3.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="Image viewer and browser for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/gthumb"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="cdr colord exif gnome-keyring gstreamer http lcms raw slideshow svg tiff webp"
+
+RDEPEND="
+	>=dev-libs/glib-2.54.0:2
+	>=x11-libs/gtk+-3.16.0:3
+	exif? ( >=media-gfx/exiv2-0.21:= )
+	slideshow? (
+		>=media-libs/clutter-1.12.0:1.0
+		>=media-libs/clutter-gtk-1:1.0
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-plugins/gst-plugins-gtk:1.0
+	)
+	raw? ( >=media-libs/libraw-0.14:= )
+	http? (
+		>=net-libs/libsoup-2.42.0:2.4
+		>=dev-libs/json-glib-0.15.0
+		>=net-libs/webkit-gtk-1.10.0:4
+	)
+	gnome-keyring? ( >=app-crypt/libsecret-0.11 )
+	cdr? ( >=app-cdr/brasero-3.2.0 )
+	svg? ( >=gnome-base/librsvg-2.34:2 )
+	webp? ( >=media-libs/libwebp-0.2.0:= )
+	lcms? ( >=media-libs/lcms-2.6:2 )
+	colord? (
+		>=x11-misc/colord-1.3
+		>=media-libs/lcms-2.6:2
+	)
+
+	sys-libs/zlib
+	virtual/jpeg:0=
+	tiff? ( media-libs/tiff:= )
+	media-libs/libpng:0=
+	>=gnome-base/gsettings-desktop-schemas-0.1.4
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	dev-util/itstool
+	sys-devel/bison
+	sys-devel/flex
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Drun-in-place=false
+		$(meson_use exif exiv2)
+		$(meson_use slideshow clutter)
+		$(meson_use gstreamer)
+		-Dlibchamplain=false # Upstream still doesn't seem to consider this ready
+		$(meson_use colord)
+		$(meson_use tiff libtiff)
+		$(meson_use webp libwebp)
+		$(meson_use raw libraw)
+		$(meson_use svg librsvg)
+		$(meson_use gnome-keyring libsecret)
+		$(meson_use http webservices)
+		$(meson_use cdr libbrasero)
+	)
+
+	# colord pulls in lcms2 anyway, so enable lcms with USE="colord -lcms"; some of upstream HAVE_COLORD code depends on HAVE_LCMS2
+	if use lcms || use colord; then
+		emesonargs+=( -Dlcms2=true )
+	else
+		emesonargs+=( -Dlcms2=false )
+	fi
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}