[gentoo-commits] proj/sci:master commit in: sys-apps/ndctl/

[Aisha Tammy]

commit:     81f8ab3b49717b74c069f788664ab489119360e6
Author:     Aisha Tammy <gentoo <AT> aisha <DOT> cc>
AuthorDate: Sat Oct 10 14:04:27 2020 +0000
Commit:     Aisha Tammy <gentoo <AT> aisha <DOT> cc>
CommitDate: Sat Oct 10 14:04:27 2020 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=81f8ab3b

sys-apps/ndctl: version bump to 70.1

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Aisha Tammy <gentoo <AT> aisha.cc>

 sys-apps/ndctl/ndctl-70.1.ebuild | 60 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/sys-apps/ndctl/ndctl-70.1.ebuild b/sys-apps/ndctl/ndctl-70.1.ebuild
new file mode 100644
index 000000000..60cc559bf
--- /dev/null
+++ b/sys-apps/ndctl/ndctl-70.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools bash-completion-r1 linux-info systemd
+
+DESCRIPTION="utility for managing the nvdimm sub-system in the linux kernel"
+HOMEPAGE="https://pmem.io"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pmem/ndctl"
+else
+	SRC_URI="https://github.com/pmem/ndctl/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/json-c
+	sys-apps/keyutils
+	sys-apps/kmod
+	sys-apps/util-linux
+	virtual/udev
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/asciidoc
+	app-text/xmlto
+	virtual/pkgconfig
+"
+
+CONFIG_CHECK="~BLK_DEV_RAM_DAX ~FS_DAX ~X86_PMEM_LEGACY ~LIBNVDIMM ~BLK_DEV_PMEM \
+~ARCH_HAS_PMEM_API ~TRANSPARENT_HUGEPAGE ~MEMORY_HOTPLUG ~MEMORY_HOTREMOVE \
+~ZONE_DEVICE ~FS_DAX_PMD"
+
+src_prepare() {
+	"${S}"/git-version-gen
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+	  --disable-asciidoctor \
+	  --without-bash \
+	  --without-systemd \
+	  --with-keyutils
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dobashcomp contrib/${PN}
+	systemd_dounit ${PN}/ndctl-monitor.service
+}