[gentoo-commits] gentoo-x86 commit in x11-themes/qtcurve: metadata.xml qtcurve-1.8.17.ebuild Manifest ChangeLog

[Ben de Groot (yngwin)]

yngwin      13/11/03 08:17:51

  Added:                metadata.xml qtcurve-1.8.17.ebuild Manifest
                        ChangeLog
  Log:
  Version bump. New upstream merged gtk-engines-qtcurve and qtcurve-qt4 into one package. Dropped deprecated mozilla option. Fixes bug #489978.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x2B2474AD43CE296E!)

Revision  Changes    Path
1.10                 x11-themes/qtcurve/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/metadata.xml?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/metadata.xml?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/metadata.xml?r1=1.9&r2=1.10




1.1                  x11-themes/qtcurve/qtcurve-1.8.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/qtcurve-1.8.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/qtcurve-1.8.17.ebuild?rev=1.1&content-type=text/plain

Index: qtcurve-1.8.17.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-themes/qtcurve/qtcurve-1.8.17.ebuild,v 1.1 2013/11/03 08:17:51 yngwin Exp $

EAPI=5
KDE_REQUIRED="optional"
inherit cmake-utils kde4-base

DESCRIPTION="A set of widget styles for Qt and GTK2"
HOMEPAGE="https://github.com/QtCurve/qtcurve-qt4"

if [[ ${PV} == *9999* ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/QtCurve/qtcurve.git"
	KEYWORDS=""
else
	SRC_URI="https://github.com/QtCurve/${PN}/archive/${PV}.tar.gz  -> ${P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="+X gtk kde nls +qt4 qt5 windeco"
REQUIRED_USE="gtk? ( X )
	windeco? ( kde X )
	|| ( gtk qt4 qt5 )"

RDEPEND="X? ( x11-libs/libxcb
		x11-libs/libX11 )
	gtk? ( x11-libs/gtk+:2 )
	qt4? ( dev-qt/qtdbus:4
		dev-qt/qtgui:4
		dev-qt/qtsvg:4
	)
	qt5? ( dev-qt/qtdbus:5
		dev-qt/qtgui:5
		dev-qt/qtsvg:5
	)
	kde? ( $(add_kdebase_dep systemsettings)
		windeco? ( $(add_kdebase_dep kwin) )
	)
	!x11-themes/gtk-engines-qtcurve"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	nls? ( sys-devel/gettext )"

DOCS=( AUTHORS ChangeLog.md README.md TODO.md )

pkg_setup() {
	use kde && kde4-base_pkg_setup
}

src_configure() {
	local mycmakeargs
	mycmakeargs=(
		$(cmake-utils_use_enable gtk GTK2)
		$(cmake-utils_use_enable qt4 QT4)
		$(cmake-utils_use_enable qt5 QT5)
		$(cmake-utils_use X QTC_ENABLE_X11 )
		$(cmake-utils_use kde QTC_QT4_ENABLE_KDE )
		$(cmake-utils_use windeco QTC_QT4_ENABLE_KWIN )
		$(cmake-utils_use nls QTC_INSTALL_PO )
	)
	cmake-utils_src_configure
}



1.84                 x11-themes/qtcurve/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/Manifest?rev=1.84&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/Manifest?rev=1.84&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/Manifest?r1=1.83&r2=1.84




1.76                 x11-themes/qtcurve/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/ChangeLog?rev=1.76&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/ChangeLog?rev=1.76&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/qtcurve/ChangeLog?r1=1.75&r2=1.76