[gentoo-commits] gentoo-x86 commit in app-text/txt2tags: ChangeLog txt2tags-2.4.ebuild

[Christian Faulhammer (opfer)]

opfer       07/09/21 17:57:13

  Modified:             ChangeLog
  Added:                txt2tags-2.4.ebuild
  Log:
  version bump, fixing bug 181035 by Pablo Nehab-Hess <natunobilis@××××××××.org>
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.27                 app-text/txt2tags/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/txt2tags/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/txt2tags/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/txt2tags/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/txt2tags/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	20 Aug 2007 16:15:26 -0000	1.26
+++ ChangeLog	21 Sep 2007 17:57:13 -0000	1.27
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/txt2tags
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/txt2tags/ChangeLog,v 1.26 2007/08/20 16:15:26 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/txt2tags/ChangeLog,v 1.27 2007/09/21 17:57:13 opfer Exp $
+
+*txt2tags-2.4 (21 Sep 2007)
+
+  21 Sep 2007; Christian Faulhammer <opfer@g.o> +txt2tags-2.4.ebuild:
+  version bump, fixing bug 181035 by Pablo Nehab-Hess <natunobilis@××××××××.org>
 
   20 Aug 2007; Fabian Groffen <grobian@g.o> txt2tags-2.3.ebuild,
   txt2tags-2.3-r1.ebuild:



1.1                  app-text/txt2tags/txt2tags-2.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/txt2tags/txt2tags-2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/txt2tags/txt2tags-2.4.ebuild?rev=1.1&content-type=text/plain

Index: txt2tags-2.4.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/txt2tags/txt2tags-2.4.ebuild,v 1.1 2007/09/21 17:57:13 opfer Exp $

inherit eutils elisp-common

DESCRIPTION="A tool for generating marked up documents (HTML, SGML, ...) from a plain text file with markup"
HOMEPAGE="http://txt2tags.sourceforge.net/"
SRC_URI="mirror://sourceforge/txt2tags/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="emacs tk"

DEPEND="virtual/python
	tk? ( dev-lang/tk )
	emacs? ( virtual/emacs )"

SITEFILE="51${PN}-gentoo.el"

pkg_setup() {
	# need to test if the tk support in python is working
	if use tk; then
		if ! built_with_use dev-lang/python tk; then
			eerror "You have requested tk, but your build of Python"
			eerror "doesn't support import _tkinter. You may need to"
			eerror "remerge dev-lang/python, or build ${P}"
			eerror "with USE=\"-tk\""
			die "rebuild python with USE=tk"
		fi
	fi
}

src_compile() {
	if use emacs; then
		elisp-compile extras/txt2tags-mode.el || die "elisp-compile failed"
	fi
}

src_install() {
	dobin txt2tags

	dodoc README TODO ChangeLog*
	insinto /usr/share/doc/${PF}
	doins doc/*.{pdf,t2t}
	# samples go into "samples" doc directory
	docinto samples
	dodoc samples/sample.*
	docinto samples/css
	dodoc samples/css/*
	docinto samples/img
	dodoc samples/img/*
	docinto samples/module
	dodoc samples/module/*
	# extras go into "extras" doc directory
	docinto extras
	dodoc extras/*
	newman doc/manpage.man txt2tags.1

	# make .po files
	for pofile in "${S}"/po/*.po; do
		msgfmt -o ${pofile%%.po}.mo ${pofile}
	done
	domo po/*.mo

	# emacs support
	if use emacs; then
		elisp-install ${PN} extras/txt2tags-mode.{el,elc}
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}



-- 
gentoo-commits@g.o mailing list