[gentoo-commits] gentoo-x86 commit in dev-util/qt-creator: ChangeLog qt-creator-1.2.0-r1.ebuild

[Markos Chandras (hwoarang)]

hwoarang    09/06/28 17:06:24

  Modified:             ChangeLog
  Added:                qt-creator-1.2.0-r1.ebuild
  Log:
  Remove broken sed, review multilib support
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 dev-util/qt-creator/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/qt-creator/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/qt-creator/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/qt-creator/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/qt-creator/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	28 Jun 2009 00:18:02 -0000	1.17
+++ ChangeLog	28 Jun 2009 17:06:24 -0000	1.18
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/qt-creator
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/ChangeLog,v 1.17 2009/06/28 00:18:02 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/ChangeLog,v 1.18 2009/06/28 17:06:24 hwoarang Exp $
+
+*qt-creator-1.2.0-r1 (28 Jun 2009)
+
+  28 Jun 2009; Markos Chandras <hwoarang@g.o>
+  +qt-creator-1.2.0-r1.ebuild:
+  remove broken sed, fix multilib support using a more clean way. Thanks to
+  Davide Pesavento for all the help
 
 *qt-creator-1.2.0 (28 Jun 2009)
 



1.1                  dev-util/qt-creator/qt-creator-1.2.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/qt-creator/qt-creator-1.2.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/qt-creator/qt-creator-1.2.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: qt-creator-1.2.0-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/qt-creator-1.2.0-r1.ebuild,v 1.1 2009/06/28 17:06:24 hwoarang Exp $

EAPI="2"

inherit qt4 multilib

MY_PN="${PN/-/}"
MY_P="${P}-src"

DESCRIPTION="Lightweight IDE for C++ development centering around Qt"
HOMEPAGE="http://labs.qtsoftware.com/page/Projects/Tools/QtCreator"
SRC_URI="http://download.qtsoftware.com/${MY_PN}/${MY_P}.zip"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="bineditor bookmarks +cmake debug +debugger +designer doc examples fakevim git kde perforce qtscript subversion"

DEPEND=">=x11-libs/qt-assistant-4.5.0_rc1
	>=x11-libs/qt-gui-4.5.0_rc1[dbus,qt3support]"

RDEPEND="${DEPEND}
	>=x11-libs/qt-sql-4.5.0_rc1
	>=x11-libs/qt-svg-4.5.0_rc1
	>=x11-libs/qt-test-4.5.0_rc1
	>=x11-libs/qt-webkit-4.5.0_rc1
	!kde? ( || ( >=x11-libs/qt-phonon-4.5.0_rc1 media-sound/phonon ) )
	kde? ( media-sound/phonon )
	cmake? ( dev-util/cmake )
	debugger? ( sys-devel/gdb )
	examples? ( >=x11-libs/qt-demo-4.5.0_rc1 )
	git? ( dev-util/git )
	qtscript? ( >=x11-libs/qt-script-4.5.0_rc1 )
	subversion? ( dev-util/subversion )"

PLUGINS="bookmarks bineditor cmake debugger designer fakevim git perforce qtscript subversion"

PATCHES=(
	"${FILESDIR}/docs_gen.patch"
)

S="${WORKDIR}/${MY_P}"

LANGS="de es it ja ru"

for x in ${LANGS}; do
	IUSE="${IUSE} linguas_${x}"
done

src_prepare() {
	qt4_src_prepare

	# bug 263087
	for plugin in ${PLUGINS};do
		if ! use ${plugin};then
			einfo "Disabling ${plugin} support"
			if [[ ${plugin} == "cmake" ]];then
				plugin="cmakeprojectmanager"
			elif [[ ${plugin} == "qtscript" ]];then
				plugin="qtscripteditor"
			fi
			sed -i "/plugin_${plugin}/s:^:#:" src/plugins/plugins.pro \
				|| die "Failed to disabled ${plugin} plugin"
		fi
	done

	if use perforce;then
		ewarn
		ewarn "You have enabled perforce plugin."
		ewarn "In order to use it, you need to manually"
		ewarn "download perforce client from http://www.perforce.com/perforce/downloads/index.html"
		ewarn
		ebeep 5
	fi
}

src_configure() {
	eqmake4 ${MY_PN}.pro IDE_LIBRARY_BASENAME="$(get_libdir)"
}

src_install() {
	emake INSTALL_ROOT="${D}/usr" install_subtargets || die "emake install failed"
	if use doc;then
		emake INSTALL_ROOT="${D}/usr" install_qch_docs || die "emake install qch_docs failed"
	fi
	make_desktop_entry qtcreator.bin QtCreator qtcreator_logo_48 \
		'Qt;Development;IDE' || die "make_desktop_entry failed"

	# install translations
	insinto /usr/share/${MY_PN}/translations/
	for x in ${LINGUAS};do
		for lang in ${LANGS};do
			if [[ ${x} == ${lang} ]];then
				doins share/${MY_PN}/translations/${MY_PN}_${x}.qm
			fi
		done
	done
}