[gentoo-commits] repo/gentoo:master commit in: games-puzzle/world-of-goo-demo/

[James Le Cuirot]

commit:     53e57f052f7a0f65f82c2a2bb27e1fe4686c9123
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 28 22:23:30 2020 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Tue Apr 28 22:32:54 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53e57f05

games-puzzle/world-of-goo-demo: Use Slackbuilds mirror, EAPI 7

I tried to add USE=bundled-libs but the ancient Vorbis libraries clash
with system Vorbis libraries pulled in via PulseAudio.

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 .../world-of-goo-demo-1.41-r2.ebuild               | 69 ----------------------
 .../world-of-goo-demo-1.41-r3.ebuild               | 52 ++++++++++++++++
 2 files changed, 52 insertions(+), 69 deletions(-)

diff --git a/games-puzzle/world-of-goo-demo/world-of-goo-demo-1.41-r2.ebuild b/games-puzzle/world-of-goo-demo/world-of-goo-demo-1.41-r2.ebuild
deleted file mode 100644
index 83b418f1b56..00000000000
--- a/games-puzzle/world-of-goo-demo/world-of-goo-demo-1.41-r2.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit eutils
-
-DESCRIPTION="A puzzle game with a strong emphasis on physics"
-HOMEPAGE="http://2dboy.com/"
-
-if [[ ${PN} == *-demo ]] ; then
-	MY_PN="WorldOfGooDemo"
-	SRC_URI="${MY_PN}.${PV}.tar.gz"
-else
-	MY_PN="WorldOfGoo"
-	SRC_URI="${MY_PN}Setup.${PV}.tar.gz"
-fi
-
-LICENSE="2dboy-EULA"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-RESTRICT="bindist fetch strip"
-
-RDEPEND="
-	media-libs/libsdl[sound,opengl,video]
-	media-libs/sdl-mixer[vorbis]
-	sys-libs/glibc
-	virtual/opengl
-	virtual/glu
-	>=sys-devel/gcc-3.4
-"
-DEPEND=""
-
-S="${WORKDIR}/${MY_PN}"
-dir="/opt/${PN}"
-
-QA_PREBUILT="
-	${dir:1}/${MY_PN%Demo}.bin32
-	${dir:1}/${MY_PN%Demo}.bin64
-"
-
-pkg_nofetch() {
-	if [[ ${PN} == *-demo ]] ; then
-		elog "To download the demo, visit http://worldofgoo.com/dl2.php?lk=demo"
-		elog "and download ${A} and place it into your DISTDIR directory."
-	else
-		elog "Download ${A} from ${HOMEPAGE} and place it into your DISTDIR directory."
-	fi
-}
-
-src_install() {
-	exeinto "${dir}"
-	doexe ${MY_PN%Demo}*
-
-	make_wrapper ${PN} "${dir}"/${MY_PN%Demo}
-
-	insinto "${dir}"
-	doins -r icons properties res
-	newicon icons/scalable.svg ${PN}.svg
-
-	if [[ ${PN} == *-demo ]] ; then
-		make_desktop_entry ${PN} "World of Goo (Demo)"
-	else
-		make_desktop_entry ${PN} "World of Goo"
-	fi
-
-	dodoc linux-issues.txt
-	HTML_DOCS="readme.html" einstalldocs
-}

diff --git a/games-puzzle/world-of-goo-demo/world-of-goo-demo-1.41-r3.ebuild b/games-puzzle/world-of-goo-demo/world-of-goo-demo-1.41-r3.ebuild
new file mode 100644
index 00000000000..c25a8830d83
--- /dev/null
+++ b/games-puzzle/world-of-goo-demo/world-of-goo-demo-1.41-r3.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop eutils xdg
+
+MY_PN="WorldOfGooDemo"
+
+DESCRIPTION="A puzzle game with a strong emphasis on physics (demo version)"
+HOMEPAGE="https://2dboy.com/"
+SRC_URI="mirror://sourceforge/slackbuildsdirectlinks/worldofgoo/${MY_PN}.${PV}.tar.gz"
+
+LICENSE="2dboy-EULA"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	media-libs/libsdl[opengl,sound,video]
+	media-libs/sdl-mixer[vorbis]
+	>=sys-devel/gcc-3.4
+	sys-libs/glibc
+	virtual/opengl
+	virtual/glu
+"
+
+dir="/opt/${PN}"
+S="${WORKDIR}/${MY_PN}"
+QA_PREBUILT="${dir#/}/*"
+
+src_install() {
+	exeinto "${dir}"
+	newexe ${MY_PN%Demo}.bin$(usex amd64 64 32) ${MY_PN%Demo}.bin
+	make_wrapper ${PN} ./${MY_PN%Demo}.bin "${dir}"
+
+	insinto "${dir}"
+	doins -r icons/ properties/ res/
+
+	local icon size
+	for icon in icons/*.{png,svg}; do
+		size=${icon##*/}
+		size=${size%%[x.]*}
+		newicon -s "${size}" "${icon}" "${PN}.${icon##*.}"
+	done
+
+	make_desktop_entry ${PN} "World of Goo (Demo)"
+
+	dodoc linux-issues.txt
+	docinto html
+	dodoc readme.html
+}