[gentoo-commits] gentoo-x86 commit in x11-libs/qscintilla: qscintilla-2.8-r1.ebuild ChangeLog qscintilla-2.8.ebuild

[Davide Pesavento (pesa)]

pesa        13/12/30 02:02:46

  Modified:             ChangeLog
  Added:                qscintilla-2.8-r1.ebuild
  Removed:              qscintilla-2.8.ebuild
  Log:
  Remove pointless USE flag 'python'.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

Revision  Changes    Path
1.98                 x11-libs/qscintilla/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?rev=1.98&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?rev=1.98&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?r1=1.97&r2=1.98

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v
retrieving revision 1.97
retrieving revision 1.98
diff -u -r1.97 -r1.98
--- ChangeLog	24 Dec 2013 19:21:54 -0000	1.97
+++ ChangeLog	30 Dec 2013 02:02:46 -0000	1.98
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/qscintilla
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.97 2013/12/24 19:21:54 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.98 2013/12/30 02:02:46 pesa Exp $
+
+*qscintilla-2.8-r1 (30 Dec 2013)
+
+  30 Dec 2013; Davide Pesavento <pesa@g.o> +qscintilla-2.8-r1.ebuild,
+  -qscintilla-2.8.ebuild:
+  Remove pointless USE flag 'python'.
 
   24 Dec 2013; Davide Pesavento <pesa@g.o>
   -files/qscintilla-2.6.2-designer.patch, -qscintilla-2.6.2.ebuild:



1.1                  x11-libs/qscintilla/qscintilla-2.8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/qscintilla-2.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/qscintilla-2.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: qscintilla-2.8-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/qscintilla-2.8-r1.ebuild,v 1.1 2013/12/30 02:02:46 pesa Exp $

EAPI=5

inherit qt4-r2

MY_P=QScintilla-gpl-${PV}

DESCRIPTION="A Qt port of Neil Hodgson's Scintilla C++ editor class"
HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0/11"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc"

DEPEND="
	>=dev-qt/designer-4.8.5:4
	>=dev-qt/qtcore-4.8.5:4
	>=dev-qt/qtgui-4.8.5:4
"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}

PATCHES=(
	"${FILESDIR}/${PN}-2.7.1-designer.patch"
)

src_unpack() {
	qt4-r2_src_unpack

	# Sub-slot sanity check
	local subslot=${SLOT#*/}
	local version=$(sed -nre 's:.*VERSION\s*=\s*([0-9\.]+):\1:p' "${S}"/Qt4Qt5/qscintilla.pro)
	local major=${version%%.*}
	if [[ ${subslot} != ${major} ]]; then
		eerror
		eerror "Ebuild sub-slot (${subslot}) does not match QScintilla major version (${major})"
		eerror "Please update SLOT variable as follows:"
		eerror "    SLOT=\"${SLOT%%/*}/${major}\""
		eerror
		die "sub-slot sanity check failed"
	fi
}

src_configure() {
	pushd Qt4Qt5 > /dev/null
	einfo "Configuration of qscintilla"
	eqmake4 qscintilla.pro
	popd > /dev/null

	pushd designer-Qt4Qt5 > /dev/null
	einfo "Configuration of designer plugin"
	eqmake4 designer.pro
	popd > /dev/null
}

src_compile() {
	pushd Qt4Qt5 > /dev/null
	einfo "Building of qscintilla"
	emake
	popd > /dev/null

	pushd designer-Qt4Qt5 > /dev/null
	einfo "Building of designer plugin"
	emake
	popd > /dev/null
}

src_install() {
	pushd Qt4Qt5 > /dev/null
	einfo "Installation of qscintilla"
	emake INSTALL_ROOT="${D}" install
	popd > /dev/null

	pushd designer-Qt4Qt5 > /dev/null
	einfo "Installation of designer plugin"
	emake INSTALL_ROOT="${D}" install
	popd > /dev/null

	dodoc NEWS

	if use doc; then
		dohtml doc/html-Qt4Qt5/*
		insinto /usr/share/doc/${PF}
		doins -r doc/Scintilla
	fi
}