[gentoo-commits] gentoo-x86 commit in net-libs/wvstreams: wvstreams-4.6.1-r1.ebuild ChangeLog wvstreams-4.6.1-r2.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/06/06 20:33:49

  Modified:             wvstreams-4.6.1-r1.ebuild ChangeLog
  Added:                wvstreams-4.6.1-r2.ebuild
  Log:
  Pass --localstatedir=/var to correct uniconfd.ini location. Use -fno-strict-aliasing since this package is not ready for aliasing. Fix compability with sys-devel/gcc >= 4.7 wrt #419563 and #419971 by Ioannis Galanomatis. inherit eutils for epatch
  
  (Portage version: 2.2.0_alpha109/cvs/Linux x86_64)

Revision  Changes    Path
1.9                  net-libs/wvstreams/wvstreams-4.6.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/wvstreams/wvstreams-4.6.1-r1.ebuild?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/wvstreams/wvstreams-4.6.1-r1.ebuild?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/wvstreams/wvstreams-4.6.1-r1.ebuild?r1=1.8&r2=1.9

Index: wvstreams-4.6.1-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/wvstreams/wvstreams-4.6.1-r1.ebuild,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- wvstreams-4.6.1-r1.ebuild	5 May 2012 02:54:29 -0000	1.8
+++ wvstreams-4.6.1-r1.ebuild	6 Jun 2012 20:33:49 -0000	1.9
@@ -1,9 +1,9 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/wvstreams/wvstreams-4.6.1-r1.ebuild,v 1.8 2012/05/05 02:54:29 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/wvstreams/wvstreams-4.6.1-r1.ebuild,v 1.9 2012/06/06 20:33:49 ssuominen Exp $
 
 EAPI=2
-inherit autotools toolchain-funcs versionator
+inherit autotools eutils toolchain-funcs versionator
 
 DESCRIPTION="A network programming library in C++"
 HOMEPAGE="http://alumnit.ca/wiki/?WvStreams"



1.144                net-libs/wvstreams/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/wvstreams/ChangeLog?rev=1.144&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/wvstreams/ChangeLog?rev=1.144&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/wvstreams/ChangeLog?r1=1.143&r2=1.144

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/wvstreams/ChangeLog,v
retrieving revision 1.143
retrieving revision 1.144
diff -u -r1.143 -r1.144
--- ChangeLog	5 May 2012 02:54:29 -0000	1.143
+++ ChangeLog	6 Jun 2012 20:33:49 -0000	1.144
@@ -1,6 +1,19 @@
 # ChangeLog for net-libs/wvstreams
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/wvstreams/ChangeLog,v 1.143 2012/05/05 02:54:29 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/wvstreams/ChangeLog,v 1.144 2012/06/06 20:33:49 ssuominen Exp $
+
+  06 Jun 2012; Samuli Suominen <ssuominen@g.o>
+  wvstreams-4.6.1-r1.ebuild:
+  inherit eutils for epatch
+
+*wvstreams-4.6.1-r2 (06 Jun 2012)
+
+  06 Jun 2012; Samuli Suominen <ssuominen@g.o>
+  +wvstreams-4.6.1-r2.ebuild, +files/wvstreams-4.6.1-gcc47.patch:
+  Pass --localstatedir=/var to correct uniconfd.ini location. Use
+  -fno-strict-aliasing since this package is not ready for aliasing. Fix
+  compability with sys-devel/gcc >= 4.7 wrt #419563 and #419971 by Ioannis
+  Galanomatis.
 
   05 May 2012; Jeff Horelick <jdhore@g.o> wvstreams-4.6.1-r1.ebuild:
   dev-util/pkgconfig -> virtual/pkgconfig



1.1                  net-libs/wvstreams/wvstreams-4.6.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/wvstreams/wvstreams-4.6.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/wvstreams/wvstreams-4.6.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: wvstreams-4.6.1-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/wvstreams/wvstreams-4.6.1-r2.ebuild,v 1.1 2012/06/06 20:33:49 ssuominen Exp $

EAPI=4
inherit autotools eutils flag-o-matic toolchain-funcs versionator

DESCRIPTION="A network programming library in C++"
HOMEPAGE="http://alumnit.ca/wiki/?WvStreams"
SRC_URI="http://wvstreams.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="pam doc +ssl +dbus debug"

#Tests fail if openssl is not compiled with -DPURIFY. Gentoo's isn't. FAIL!
RESTRICT="test"

#QA Fail: xplc is compiled as a part of wvstreams.
#It'll take a larger patching effort to get it extracted, since upstream integrated it
#more tightly this time. Probably for the better since upstream xplc seems dead.

RDEPEND="sys-libs/readline
	sys-libs/zlib
	dbus? ( >=sys-apps/dbus-1.4.20 )
	dev-libs/openssl:0
	pam? ( sys-libs/pam )
	virtual/c++-tr1-functional"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( app-doc/doxygen )"

DOCS="ChangeLog README*"

pkg_setup() {
	if has_version '>=sys-devel/gcc-4.1' && ! has_version '>=dev-libs/boost-1.34.1'
	then
		if ! version_is_at_least 4.1 "$(gcc-fullversion)"
		then
			eerror "This package requires the active gcc to be at least version 4.1"
			eerror "or >=dev-libs/boost-1.34.1 must be installed."
			die "Please activate >=sys-devel/gcc-4.1 with gcc-config."
		fi
	fi
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-parallel-make.patch \
		"${FILESDIR}"/${P}-openssl-1.0.0.patch \
		"${FILESDIR}"/${P}-glibc212.patch \
		"${FILESDIR}"/${P}-gcc47.patch

	eautoreconf
	pushd argp >/dev/null
	eautoreconf
	popd >/dev/null
}

src_configure() {
	append-flags -fno-strict-aliasing
	tc-export CXX

	econf \
		--localstatedir=/var \
		$(use_enable debug) \
		--disable-optimization \
		$(use_with dbus) \
		--with-openssl \
		$(use_with pam) \
		--without-tcl \
		--without-qt \
		--with-zlib \
		--without-valgrind
}

src_compile() {
	default

	if use doc; then
		doxygen || die
	fi
}

src_test() {
	emake test
}

src_install() {
	default

	if use doc; then
		#the list of files is too big for dohtml -r Docs/doxy-html/*
		cd Docs/doxy-html
		dohtml -r *
	fi
}