[gentoo-commits] gentoo-x86 commit in x11-wm/enlightenment: ChangeLog enlightenment-1.0.2.ebuild

[Mike Frysinger (vapier)]

vapier      10/02/10 04:56:39

  Modified:             ChangeLog
  Added:                enlightenment-1.0.2.ebuild
  Log:
  Version bump #303785 by Dennis Nezic.
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.128                x11-wm/enlightenment/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/enlightenment/ChangeLog?rev=1.128&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/enlightenment/ChangeLog?rev=1.128&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/enlightenment/ChangeLog?r1=1.127&r2=1.128

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/ChangeLog,v
retrieving revision 1.127
retrieving revision 1.128
diff -u -r1.127 -r1.128
--- ChangeLog	10 Feb 2010 04:55:52 -0000	1.127
+++ ChangeLog	10 Feb 2010 04:56:38 -0000	1.128
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/enlightenment
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/ChangeLog,v 1.127 2010/02/10 04:55:52 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/ChangeLog,v 1.128 2010/02/10 04:56:38 vapier Exp $
+
+*enlightenment-1.0.2 (10 Feb 2010)
+
+  10 Feb 2010; Mike Frysinger <vapier@g.o>
+  +enlightenment-1.0.2.ebuild:
+  Version bump #303785 by Dennis Nezic.
 
   10 Feb 2010; Mike Frysinger <vapier@g.o> enlightenment-1.0.1.ebuild:
   Mark ia64/sh stable #301308.



1.1                  x11-wm/enlightenment/enlightenment-1.0.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/enlightenment/enlightenment-1.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/enlightenment/enlightenment-1.0.2.ebuild?rev=1.1&content-type=text/plain

Index: enlightenment-1.0.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/enlightenment-1.0.2.ebuild,v 1.1 2010/02/10 04:56:38 vapier Exp $

EAPI="2"
if [[ ${PV} == *9999 ]] ; then
	ESVN_REPO_URI="http://svn.enlightenment.org/svn/e/trunk/E16/e"
	inherit subversion
	SRC_URI=""
	#KEYWORDS=""
	S=${WORKDIR}/e16/e
else
	SRC_URI="mirror://sourceforge/enlightenment/e16-${PV/_/-}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
	S=${WORKDIR}/e16-${PV/_pre?}
fi
inherit eutils

DESCRIPTION="Enlightenment Window Manager"
HOMEPAGE="http://www.enlightenment.org/"

LICENSE="BSD"
SLOT="0"
IUSE="doc dbus esd nls pango pulseaudio xcomposite xinerama xrandr"

RDEPEND="esd? ( >=media-sound/esound-0.2.19 )
	pulseaudio? ( media-sound/pulseaudio )
	dbus? ( sys-apps/dbus )
	pango? ( x11-libs/pango )
	=media-libs/freetype-2*
	>=media-libs/imlib2-1.3.0[X]
	x11-libs/libSM
	x11-libs/libICE
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXdamage
	x11-libs/libXxf86vm
	x11-libs/libXft
	xrandr? ( x11-libs/libXrandr )
	x11-libs/libXrender
	x11-misc/xbitmaps
	xinerama? ( x11-libs/libXinerama )
	xcomposite? ( x11-libs/libXcomposite )
	nls? ( virtual/libintl )
	virtual/libiconv"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	x11-proto/xextproto
	x11-proto/xf86vidmodeproto
	xinerama? ( x11-proto/xineramaproto )
	xcomposite? ( x11-proto/compositeproto )
	x11-proto/xproto
	nls? ( sys-devel/gettext )"
PDEPEND="doc? ( app-doc/edox-data )"

src_prepare() {
	if [[ ! -e configure ]] ; then
		eautopoint
		eautoreconf
	fi
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_enable dbus) \
		$(use_enable pulseaudio sound-pulse) \
		$(use_enable esd sound-esound) \
		$(use_enable pango) \
		$(use_enable xinerama) \
		$(use_enable xrandr) \
		$(use_enable xcomposite composite) \
		--disable-docs \
		--enable-zoom
}

src_install() {
	emake install DESTDIR="${D}" || die
	rmdir "${D}"/usr/share/doc/e16 || die #294456
	dodoc AUTHORS ChangeLog COMPLIANCE TODO
}