[gentoo-commits] gentoo-x86 commit in sci-misc/mendeleydesktop: ChangeLog mendeleydesktop-1.7.1.ebuild mendeleydesktop-1.6.ebuild

[Angelo Arrifano (miknix)]

miknix      12/11/28 22:50:12

  Modified:             ChangeLog
  Added:                mendeleydesktop-1.7.1.ebuild
  Removed:              mendeleydesktop-1.6.ebuild
  Log:
  Version bump. #444890
  
  (Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key 0720FC74)

Revision  Changes    Path
1.8                  sci-misc/mendeleydesktop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	11 Sep 2012 18:17:52 -0000	1.7
+++ ChangeLog	28 Nov 2012 22:50:12 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for sci-misc/mendeleydesktop
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog,v 1.7 2012/09/11 18:17:52 miknix Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog,v 1.8 2012/11/28 22:50:12 miknix Exp $
+
+*mendeleydesktop-1.7.1 (28 Nov 2012)
+
+  28 Nov 2012; Angelo Arrifano <miknix@g.o> -mendeleydesktop-1.6.ebuild,
+  +mendeleydesktop-1.7.1.ebuild:
+  Version bump. #444890
 
   11 Sep 2012; Angelo Arrifano <miknix@g.o> mendeleydesktop-1.6.ebuild:
   Fix 'use' function invocation on global ebuild scope. #434634



1.1                  sci-misc/mendeleydesktop/mendeleydesktop-1.7.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/mendeleydesktop-1.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/mendeleydesktop-1.7.1.ebuild?rev=1.1&content-type=text/plain

Index: mendeleydesktop-1.7.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-misc/mendeleydesktop/mendeleydesktop-1.7.1.ebuild,v 1.1 2012/11/28 22:50:12 miknix Exp $

EAPI="4"

inherit eutils multilib

MY_P_AMD64="${P}-linux-x86_64"
MY_P_X86="${P}-linux-i486"

DESCRIPTION="A free research management tool for desktop and web"
HOMEPAGE="http://www.mendeley.com/"
SRC_URI="amd64? ( ${MY_P_AMD64}.tar.bz2 )
	x86? ( ${MY_P_X86}.tar.bz2 )
	amd64-linux? ( ${MY_P_AMD64}.tar.bz2 )
	x86-linux? ( ${MY_P_X86}.tar.bz2 )"

LICENSE="Mendeley-EULA"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RESTRICT="fetch"

DEPEND=""
RDEPEND=">=x11-libs/qt-core-4.6:4
	>=x11-libs/qt-gui-4.6:4
	>=x11-libs/qt-svg-4.6:4
	>=x11-libs/qt-webkit-4.6:4
	>=x11-libs/qt-xmlpatterns-4.6:4"

QA_PRESTRIPPED="
	/opt/mendeleydesktop/$(get_libdir)/mendeleydesktop/libexec/.*
	/opt/mendeleydesktop/$(get_libdir)/lib.*so.*"

pkg_nofetch() {
	elog "Please download ${A} from:"
	elog "http://www.mendeley.com/download-mendeley-desktop/"
	elog "and move it to ${DISTDIR}"
}

src_unpack() {
	unpack ${A}

	cd "${WORKDIR}"

	if use amd64 || use amd64-linux ; then
		mv -f "${MY_P_AMD64}" "${P}"
	else
		mv -f "${MY_P_X86}" "${P}"
	fi
}

src_prepare() {
	# remove bundled Qt libraries
	rm -rf lib/mendeleydesktop/plugins \
		|| die "failed to remove plugin directory"
	rm -rf lib/qt || die "failed to remove qt libraries"

	# force use of system Qt libraries
	sed -i "s:sys\.argv\.count(\"--force-system-qt\") > 0:True:" \
		bin/mendeleydesktop || die "failed to patch startup script"

	# fix library paths
	sed -i \
		-e "s:lib/mendeleydesktop:$(get_libdir)/mendeleydesktop:g" \
		-e "s:MENDELEY_BASE_PATH + \"/lib/\":MENDELEY_BASE_PATH + \"/$(get_libdir)/\":g" \
		bin/mendeleydesktop || die "failed to patch library path"
}

src_install() {
	# install menu
	domenu share/applications/${PN}.desktop

	# install application icons
	insinto /usr/share/icons
	doins -r share/icons/hicolor

	# install default icon
	insinto /usr/share/pixmaps
	doins share/icons/hicolor/48x48/apps/${PN}.png

	# install documentation, but no license file
	dodoc share/doc/${PN}/FAQ.pdf
	dodoc share/doc/${PN}/Readme.txt

	# install binary
	into /opt/${PN}
	dobin bin/*

	# install libraries
	dolib.so lib/lib*.so*

	# install programs
	exeinto /opt/mendeleydesktop/$(get_libdir)/mendeleydesktop/libexec
	doexe lib/mendeleydesktop/libexec/*

	# install shared files
	insinto /opt/${PN}/share
	doins -r share/mendeleydesktop

	# make symbolic to known location
	dosym /opt/${PN}/bin/${PN} /opt/bin/${PN}
}