[gentoo-commits] gentoo-x86 commit in dev-python/celementtree: celementtree-1.0.5-r2.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      13/03/26 19:01:51

  Modified:             ChangeLog
  Added:                celementtree-1.0.5-r2.ebuild
  Log:
  Migrate to distutils-r1. Switch examples to USE=examples (rather than USE=doc).
  
  (Portage version: 2.2.0_alpha169/cvs/Linux x86_64, signed Manifest commit with key 9627F456F9DA7643!)

Revision  Changes    Path
1.31                 dev-python/celementtree/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celementtree/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celementtree/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celementtree/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/celementtree/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	22 Feb 2012 08:57:01 -0000	1.30
+++ ChangeLog	26 Mar 2013 19:01:51 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/celementtree
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/celementtree/ChangeLog,v 1.30 2012/02/22 08:57:01 patrick Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/celementtree/ChangeLog,v 1.31 2013/03/26 19:01:51 mgorny Exp $
+
+*celementtree-1.0.5-r2 (26 Mar 2013)
+
+  26 Mar 2013; Michał Górny <mgorny@g.o> +celementtree-1.0.5-r2.ebuild:
+  Migrate to distutils-r1. Switch examples to USE=examples (rather than
+  USE=doc).
 
   22 Feb 2012; Patrick Lauer <patrick@g.o> celementtree-1.0.5-r1.ebuild:
   Restricting jython
@@ -129,4 +135,3 @@
   17 Jan 2005; Rob Cakebread <pythonhead@g.o> +metadata.xml,
   +celementtree-0.9.2.ebuild:
   Initial commit.
-



1.1                  dev-python/celementtree/celementtree-1.0.5-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celementtree/celementtree-1.0.5-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celementtree/celementtree-1.0.5-r2.ebuild?rev=1.1&content-type=text/plain

Index: celementtree-1.0.5-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/celementtree/celementtree-1.0.5-r2.ebuild,v 1.1 2013/03/26 19:01:51 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python{2_5,2_6,2_7} )

inherit distutils-r1

MY_P="cElementTree-${PV}-20051216"

DESCRIPTION="The cElementTree module is a C implementation of the ElementTree API"
HOMEPAGE="http://effbot.org/zone/celementtree.htm http://pypi.python.org/pypi/cElementTree"
SRC_URI="http://effbot.org/downloads/${MY_P}.tar.gz"

LICENSE="ElementTree"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris"
IUSE="examples"

RDEPEND=">=dev-python/elementtree-1.2[${PYTHON_USEDEP}]
	>=dev-libs/expat-1.95.8"
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]"

S="${WORKDIR}/${MY_P}"

python_prepare_all() {
	local PATCHES=(
		"${FILESDIR}/${P}-use_system_expat.patch"
		"${FILESDIR}/${P}-setuptools.patch"
	)
	distutils-r1_python_prepare_all
}

python_test() {
	"${PYTHON}" selftest.py || die "Tests fail with ${EPYTHON}"
}

python_install_all() {
	use examples && local EXAMPLES=( samples/. selftest.py )

	distutils-r1_python_install_all
}